Question

我正在将html表单转换为xml序列，我正在使用递归函数来实现此目的

所以param“list”的输入格式为

name=value&name=value&name=value

下面的模板可以正常运行并返回xml序列，如下所示

<name>value</name><name>value</name><name>value</name>

好的问题一些名称值对是特殊的，我想为它们添加一个属性，所以输出将是

<name>value</name><name attr="special">value</name><name>value</name>

所以为了做到这一点，我有一个带有特殊名称列表的外部xml文件，如下所示

<settings><google><option from="color"/><option from="size"/></google></settings>

因此，如果我们假设我有一个xsl变量$ SETTINGS连接到

上面的外部文档

<xsl:for-each select="$SETTINGS/google/option"></xsl:for-each>

应该是有2个孩子1的节点，称为颜色，另一个是

我想要做的是，如果其中一个名字= $ name添加属性

类似于<xsl:if test="$name = $SETTINGS/google/option/ckild name">

<xsl:template name="tokenize">

        <xsl:param name="list"/> 

        <xsl:variable name="seperator" select="'&amp;'"/>

        <xsl:variable name="first" select="substring-before(concat($list, $seperator), $seperator)"/>
        <xsl:variable name="butfirst" select="substring-after($list, $seperator)"/>

        <xsl:variable name="name" select="normalize-space(substring-before($first, '='))"/>
        <xsl:variable name="value" select="normalize-space(substring-after($first, '='))"/>

        <xsl:if test="string-length($name)>0 and string-length($value)>0">
            <xsl:element name="{$name}">
                <xsl:for-each select="$SETTINGS/google/option">
                        ----->   <xsl:if test="$name = $SETTINGS/google/option/ckild name">
                         <xsl:attribute name="option"/>
                                 </xsl:if>
                </xsl:for-each>
                <xsl:value-of select="$value"/>
            </xsl:element>
        </xsl:if>

        <xsl:if test="$butfirst">
            <xsl:call-template name="tokenize">
                <xsl:with-param name="list" select="$butfirst"/> 
                <xsl:with-param name="seperator" select="$seperator"/> 
            </xsl:call-template>
        </xsl:if>

    </xsl:template>

非常感谢蒂姆·道奇森

Answer 1

此样式表：

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:variable name="SETTINGS" select="/settings"/>
    <xsl:template match="/">
        <xsl:call-template name="tokenize">
            <xsl:with-param name="pString"
                 select="'color=blue&amp;name=value&amp;size=big'"/>
        </xsl:call-template>
    </xsl:template>
    <xsl:template name="tokenize">
        <xsl:param name="pString"/>
        <xsl:param name="pSeperator" select="'&amp;'"/>
        <xsl:choose>
            <xsl:when test="not($pString)"/>
            <xsl:when test="contains($pString,$pSeperator)">
                <xsl:call-template name="tokenize">
                    <xsl:with-param name="pString"
                         select="substring-before($pString, $pSeperator)"/>
                    <xsl:with-param name="pSeperator" select="$pSeperator"/>
                </xsl:call-template>
                <xsl:call-template name="tokenize">
                    <xsl:with-param name="pString"
                         select="substring-after($pString, $pSeperator)"/>
                    <xsl:with-param name="pSeperator" select="$pSeperator"/>
                </xsl:call-template>
            </xsl:when>
            <xsl:otherwise>
                <xsl:variable name="vName"
                     select="normalize-space(substring-before($pString,'='))"/>
                <xsl:variable name="vValue"
                     select="normalize-space(substring-after($pString,'='))"/>
                <xsl:if test="$vName and $vValue">
                    <xsl:element name="{$vName}">
                        <xsl:if test="$vName = $SETTINGS/google/option/@from">
                            <xsl:attribute name="attr">special</xsl:attribute>
                        </xsl:if>
                        <xsl:value-of select="$vValue"/>
                    </xsl:element>
                </xsl:if>
            </xsl:otherwise>
        </xsl:choose>
    </xsl:template>
</xsl:stylesheet>

使用此输入：

<settings>
    <google>
        <option from="color"/>
        <option from="size"/>
    </google>
</settings>

输出：

<color attr="special">blue</color>
<name>value</name>
<size attr="special">big</size>

注意：节点集比较

XSL如果需要帮助请

1 个答案: