Question

我有：

<Data>
  <DocumentCodebook>
    <C4505>
      <Item Value="1" ABSpriority="1" />
      <Item Value="2" ABSpriority="4" />
      <Item Value="3" ABSpriority="2" />
      <Item Value="4" ABSpriority="3"/>
    </C4505>
  <DocumentCodebook>
  <ApplicationData>
     <SelectedInsurance>
        <Insurance ProductId="2"/>
        <Insurance ProductId="3"/>
        <Insurance ProductId="1"/>
     </SelectedInsurance>
  </ApplicationData>
 </Data>

我需要获取在C4505中具有最高 @ABSpriority 的 Data / ApplicationData / SelectedInsurance / Insurance / @ ProductId 。 @Value与@ProductId类似。

对于此xml，结果为“ 2”。因为ProductId =“ 2”具有最高的ABSPriority =“ 4”（大于ProductId = 1和3）。

示例2

<Data>
  <DocumentCodebook>
    <C4505>
      <Item Value="1" ABSpriority="1" />
      <Item Value="2" ABSpriority="4" />
      <Item Value="3" ABSpriority="2" />
      <Item Value="4" ABSpriority="3"/>
    </C4505>
  <DocumentCodebook>
  <ApplicationData>
     <SelectedInsurance>
        <Insurance ProductId="1"/>
        <Insurance ProductId="4"/>
     </SelectedInsurance>
  </ApplicationData>
 </Data>

结果为“ 4”。 ProductId =“ 4”具有最高的ABSPriority =“ 3”。

Answer 1

首先，您应该使用 keys 来解决交叉引用。

现在，由于我们被告知XSLT 2.0在这里没有任何特殊的优势，因此我将使用XSLT 1.0还原为更原始的方法：

<xsl:stylesheet version="1.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes"/>
<xsl:strip-space elements="*"/>

<xsl:key name="item" match="Item" use="@Value" />

<xsl:template match="/Data">
    <result>
        <xsl:for-each select="ApplicationData/SelectedInsurance/Insurance">
            <xsl:sort select="key('item', @ProductId)/@ABSpriority" data-type="number" order="descending"/>
            <xsl:if test="position() = 1">
                <xsl:value-of select="@ProductId"/>
            </xsl:if>
        </xsl:for-each>
    </result>
</xsl:template>

</xsl:stylesheet>

请注意，这假设只有一个Insurance，其中ABSpriority最多。如果是平局，将仅返回文档顺序中的第一个。

Answer 2

给定一个节点序列S，以找到某个数量Q值最高的节点，做到这一点的“粗略”方法是

<xsl:variable name="max" selecy="max(S / Q)"/>
<xsl:for-each select="S[Q = $max]">...</xsl:for-each>

这不是很优雅，因为它涉及两次处理S。 Saxon具有一个高阶函数saxon：highest（）可以一次执行，但涉及扩展（以及高阶函数），因此它仅在该产品的商业版本中有效。

单次操作的另一种方法是递归。

<xsl:function name="f:highest">
  <xsl:param name="input" as="node()*"/>
  <xsl:param name="max-so-far"/>
  <xsl:param name="top-nodes"/>
  <xsl:choose>
    <xsl:when test="empty($input)">
      <xsl:sequence select="$top-nodes"/>
    </xsl:when>
    <xsl:when test="Q($input[1]) = $max-so-far">
      <xsl:sequence select="f:highest(remove($input, 1), $max-so-far, ($top-nodes, $input[1])"/>
    </xsl:when>
    <xsl:when test="Q($input[1]) > $max-so-far">
      <xsl:sequence select="f:highest(remove($input, 1), Q($input[1]), $input[1]"/>
    </xsl:when>
    <xsl:otherwise>
      <xsl:sequence select="f:highest(remove($input, 1), $max-so-far, $top-nodes"/>
    </xsl:otherwise>
</xsl:function>

这里Q（node）代表您正在节点上求值以获得感兴趣值的任何表达式，例如number($node/@ABSPriority)。

在XSLT 3.0中，您可以用等效的xsl：iterate循环替换递归函数。

Answer 3

我找到了解决方法。结果为 Insurance_Type 元素。

<xsl:variable name="ProductList">
    <xsl:for-each select="/Data/ApplicationData/SelectedInsurance/Insurance">
        <xsl:if test="position()!=1">
            <!--<xsl:value-of select=","/>-->
            <xsl:value-of select="&quot;,&quot;" />
        </xsl:if>
        <!--<xsl:value-of select="@ProductId"/>-->
        <xsl:value-of select="@ProductId" />
    </xsl:for-each>
</xsl:variable>
<xsl:variable name="MaxABS" select="max(/Data/DocumentCodebook/C4505/Item[contains($ProductList,@Value)]/@ABSpriority)" />
<xsl:element name="Types">
    <xsl:element name="Insurance_Type">
        <xsl:value-of select="/Data/DocumentCodebook/C4505/Item[@ABSpriority=$MaxABS]/@Value" />
    </xsl:element>
</xsl:element>

xPath，XSLT。通过另一个节点集中的属性获取最大值

3 个答案: