Elixir，使用另一个模块的功能

时间：2018-11-30 14:00:03

标签： function elixir

我对编程和灵丹妙药非常陌生。所以我很努力地学习。但是我遇到了麻烦。我正在寻找如何在另一个模块中使用函数的方式。我正在构建将键值映射存储在内存中的Web服务器。为了使地图保持临时状态，Ive决定使用Agent。这是我的代码的一部分：

defmodule Storage do
  use Agent

  def start_link do
    Agent.start_link(fn -> %{} end, name: :tmp_storage)
  end

  def set(key, value) do
    Agent.update(:tmp_storage, fn map -> Map.put_new(map, key, value) end)
  end

  def get(key) do
    Agent.get(:tmp_storage, fn map -> Map.get(map, key) end)
  end
end

所以我试图将此功能放到Web服务器的路由上：

defmodule Storage_router do
  use Plug.Router
  use Plug.Debugger
  require Logger
  plug(Plug.Logger, log: :debug)
  plug(:match)
  plug(:dispatch)

  post "/storage/set" do
    with {:ok, _} <- Storage.set(key, value) do
      send_resp(conn, 200, "getting the value")
    else
      _ ->
        send_resp(conn, 404, "nothing")
    end
  end
end

我收到：

warning: variable "key" does not exist and is being expanded to "key()", please use parentheses to remove the ambiguity or change the variable name lib/storage_route.ex:12

warning: variable "value" does not exist and is being expanded to "value()", please use parentheses to remove the ambiguity or change the variable name lib/storage_route.ex:12

寻找任何建议\帮助

3 个答案:

答案 0 :(得分：5)

  

我对编程和灵丹妙药是个新手。

我认为开始用长生不老药学习编程并不明智。我将从python或ruby开始，然后在一两年后再尝试长生不老药。

您需要学习的第一件事是如何发布代码。搜索google，了解如何在stackoverflow上发布代码。然后，您必须将所有缩进排成一行。您是否正在使用计算机编程文本编辑器？如果没有，那么你必须得到一个。有很多免费的。我使用vim，它像计算机一样安装在Unix上。您可以通过在终端窗口中输入vimtutor来学习如何使用vim。

接下来，您的代码中出现语法错误：

 Agent.start_link(fn -> %{} end, name: :tmp_storage
    end)

应该是：

 Agent.start_link(fn -> %{} end, name: :tmp_storage)

您得到的警告是因为您的代码试图执行以下操作：

def show do
   IO.puts x
end

Elixir和其他阅读该代码的人都会问：“ x到底是什么？”变量x永远不会在任何地方分配值，因此变量x不存在，并且您不能输出不存在的内容。您在这里做同样的事情：

   with {:ok, _} <- Storage.set(key, value) do
     send_resp(conn, 200, "getting the value")
   else
     _->
      send_resp(conn, 404, "nothing")
   end

您调用函数：

Storage.set(key, value)

但是变量key和value从未被赋值，而长生不老药（以及其他阅读该代码的人）想知道，“键和值到底是什么？”

这是函数的工作方式：

b.ex：

defmodule MyFuncs do
  def show(x, y) do
    IO.puts x
    IO.puts y
  end
end

defmodule MyWeb do
  def go do
    height = 10
    width = 20

    MyFuncs.show(height, width)
  end
end

在iex中：

~/elixir_programs$ iex b.ex
Erlang/OTP 20 [erts-9.3] [source] [64-bit] [smp:4:4] [ds:4:4:10] [async-threads:10] [hipe] [kernel-poll:false]

Interactive Elixir (1.6.6) - press Ctrl+C to exit (type h() ENTER for help)

iex(1)> MyWeb.go
10
20
:ok
iex(2)>

因此，在您的代码中，您需要编写如下代码：

post "/storage/set" do
  key = "hello"
  value = 10

  with {:ok, _} <- Storage.set(key, value) do
    send_resp(conn, 200, "Server saved the key and value.")
  else
    _->
      send_resp(conn, 404, "nothing")
  end
end

但是，它将为每个发布请求存储相同的键/值。大概是您想要存储发送的内容在发布请求的正文中。您知道获取请求和发布请求之间的区别吗？一个get请求将数据添加到url的末尾，而一个post请求则将数据发送到“请求的主体”中，因此根据请求的类型，有不同的提取数据的过程。

您正在阅读什么教程？本教程：https://www.jungledisk.com/blog/2018/03/19/tutorial-a-simple-http-server-in-elixir/，向您展示如何从发布请求的正文中提取数据。发布请求正文中的数据只是一个字符串。如果字符串为JSON格式，则可以使用Poison.decode!()将字符串转换为长生不老药图，这将使您可以轻松提取与您感兴趣的键关联的值。例如：

  post "/storage/set" do
    {:ok, body_string, conn} = read_body(conn)
    body_map = Poison.decode!(body_string)

    IO.inspect(body_map) #This outputs to terminal window where server is running 

    message = get_in(body_map, ["message"])    
    send_resp(
      conn, 
      201,
      "Server received: #{message}\n"
    )
  end

然后，您可以在另一个终端窗口中使用以下curl命令向该路由发送发布请求：

$ curl -v -H 'Content-Type: application/json' "http://localhost:8085/storage/set" -d '{"message": "hello world" }'

（{-v =>详细输出，-H =>请求标头，-d =>数据）

现在，根据我上面的代码所说的错误，您应该对此行感到疑惑：

{:ok, body_string, conn} = read_body(conn)

该行呼叫：

read_body(conn)

，但是变量conn未被分配任何值。但是，Plug不可见地创建conn变量并为其分配值。

这是一个使用代理存储帖子请求数据的完整示例（遵循我上面链接的教程）：

simple_server
   config/
   lib/
       simple_server/
           application.ex
           router.ex
           storage.ex
   test/

一种长生不老药的约定是在lib/目录中有一个与您的项目同名的目录，在这种情况下，该目录将为simple_server，然后为您定义的模块提供反映目录结构的名称。因此，在router.ex中，您将定义一个名为SimpleServer.Router的模块，在storage.ex中，您将定义一个名为SimpleServer.Storage的模块。但是，模块名称中的.对elixir来说没有什么特别的，因此，如果您决定在文件F.R.O.G.S中命名模块lib/rocks.ex和代码，就不会出错。会很好。

router.ex：

defmodule SimpleServer.Router do
  use Plug.Router
  use Plug.Debugger

  require Logger

  plug(Plug.Logger, log: :debug)
  plug(:match)
  plug(:dispatch)

  get "/storage/:key" do
    resp_msg = case SimpleServer.Storage.get(key) do
      nil -> "The key #{key} doesn't exist!\n"
      val -> "The key #{key} has value #{val}.\n"
    end

    send_resp(conn, 200, resp_msg)
  end

  post "/storage/set" do
    {:ok, body_string, conn} = read_body(conn)
    body_map = Poison.decode!(body_string)

    IO.inspect(body_map) #This outputs to terminal window where server is running 

    Enum.each(
      body_map, 
      fn {key, val} -> SimpleServer.Storage.set(key,val) end
    )

    send_resp(
      conn, 
      201,
      "Server stored all key-value pairs\n"
    )
  end

  match _ do
    send_resp(conn, 404, "not found")
  end


end

上面代码中首先要注意的是路线：

get "/storage/:key" do

这将与以下路径匹配：

/storage/x

插件将创建一个名为key的变量，并为其分配值“ x”，如下所示：

 key = "x"

另外，请注意，在调用函数时：

width = 10
height = 20
show(width, height)

elixir查看函数定义：

def show(x, y) do
  IO.puts x
  IO.puts y
end

并将函数调用与def匹配，如下所示：

    show(width, height)
          |       |
          V       V
def show( x    ,  y) do
  ...
end

并执行任务：

 x = width
 y = height

然后，在函数内部可以使用x和y变量。在这一行：

    Enum.each(
      body_map, 

      #  | | | | |
      #  V V V V V

      fn {key, val} -> SimpleServer.Storage.set(key,val) end
    )

Elixir将调用匿名函数，传递key和val的值，如下所示：

func("x", "10")

因此，在匿名函数的主体中，您可以使用变量key和val：

SimpleServer.Storage.set(key,val)

因为变量key和val已被分配值。

storage.ex：

defmodule SimpleServer.Storage do
  use Agent

  def start_link(_args) do  #<*** Note the change here
    Agent.start_link(fn -> %{} end, name: :tmp_storage)
  end

  def set(key, value) do
    Agent.update(
      :tmp_storage, 
      fn(map) -> Map.put_new(map, key, value) end
    )
  end

  def get(key) do
    Agent.get(
      :tmp_storage, 
      fn(map) -> Map.get(map, key) end
    )
  end

end

application.ex：

defmodule SimpleServer.Application do
  # See https://hexdocs.pm/elixir/Application.html
  # for more information on OTP Applications
  @moduledoc false

  use Application

  def start(_type, _args) do
    # List all child processes to be supervised
    children = [
      Plug.Adapters.Cowboy.child_spec(scheme: :http, plug: SimpleServer.Router, options: [port: 8085]),

      {SimpleServer.Storage, []}
    ]

    # See https://hexdocs.pm/elixir/Supervisor.html
    # for other strategies and supported options
    opts = [strategy: :one_for_one, name: SimpleServer.Supervisor]
    Supervisor.start_link(children, opts)
  end
end

mix.exs：

defmodule SimpleServer.MixProject do
  use Mix.Project

  def project do
    [
      app: :simple_server,
      version: "0.1.0",
      elixir: "~> 1.6",
      start_permanent: Mix.env() == :prod,
      deps: deps()
    ]
  end

  # Run "mix help compile.app" to learn about applications.
  def application do
    [
      extra_applications: [:logger],
      mod: {SimpleServer.Application, []}
    ]
  end


  # Run "mix help deps" to learn about dependencies.
  defp deps do
    [
        {:poison, "~> 4.0"},
        {:plug_cowboy, "~> 2.0"}

      # {:dep_from_hexpm, "~> 0.3.0"},
      # {:dep_from_git, git: "https://github.com/elixir-lang/my_dep.git", tag: "0.1.0"},
    ]
  end
end

注意，如果您使用教程中指定的依赖项和版本，则会收到一些警告，包括警告：

~/elixir_programs/simple_server$ iex -S mix
...
...

12:48:57.767 [warn]  Setting Ranch options together 
with socket options is deprecated. Please use the new
map syntax that allows specifying socket options 
separately from other options.

...这是Plug的问题。这是我用来摆脱所有警告的依赖项和版本：

   {:poison, "~> 4.0"},
   {:plug_cowboy, "~> 2.0"}

此外，当您将应用程序列为依赖项时，您不再需要在:extra_applications列表中输入它。 Elixir将在启动您的应用程序之前自动启动所有列为依赖项的应用程序。参见:applications v. :extra_applications。

服务器启动后，您可以使用另一个终端窗口通过curl发送发布请求（或者可以使用其他程序）：

~$  curl -v -H 'Content-Type: application/json' "http://localhost:8085/storage/set" -d '{"x": "10", "y": "20" }

*   Trying 127.0.0.1...
* TCP_NODELAY set
* Connected to localhost (127.0.0.1) port 8085 (#0)
> POST /storage/set HTTP/1.1
> Host: localhost:8085
> User-Agent: curl/7.58.0
> Accept: */*
> Content-Type: application/json
> Content-Length: 23
> 
* upload completely sent off: 23 out of 23 bytes
< HTTP/1.1 201 Created
< server: Cowboy
< date: Fri, 30 Nov 2018 19:22:23 GMT
< content-length: 34
< cache-control: max-age=0, private, must-revalidate
< 
Server stored all key-value pairs
* Connection #0 to host localhost left intact

>行是请求，<行是响应。另外，在运行服务器的终端窗口中检查输出。

~$  curl -v http://localhost:8085/storage/z

*   Trying 127.0.0.1...
* TCP_NODELAY set
* Connected to localhost (127.0.0.1) port 8085 (#0)
> GET /storage/z HTTP/1.1
> Host: localhost:8085
> User-Agent: curl/7.58.0
> Accept: */*
> 
< HTTP/1.1 200 OK
< server: Cowboy
< date: Fri, 30 Nov 2018 19:22:30 GMT
< content-length: 25
< cache-control: max-age=0, private, must-revalidate
< 
The key z doesn't exist!
* Connection #0 to host localhost left intact

。

~$  curl -v http://localhost:8085/storage/x

*   Trying 127.0.0.1...
* TCP_NODELAY set
* Connected to localhost (127.0.0.1) port 8085 (#0)
> GET /storage/x HTTP/1.1
> Host: localhost:8085
> User-Agent: curl/7.58.0
> Accept: */*
> 
< HTTP/1.1 200 OK
< server: Cowboy
< date: Fri, 30 Nov 2018 19:22:37 GMT
< content-length: 24
< cache-control: max-age=0, private, must-revalidate
< 
The key x has value 10.
* Connection #0 to host localhost left intact

答案 1 :(得分：4)

我不确定您要完成的工作，但是错误告诉您传递到路由器key语句的value和with不是定义。 Elixir认为您正在尝试使用这些参数调用函数，因为它们未“绑定”到值。这就是为什么您看到warning: variable "value" does not exist and is being expanded to "value()"

我认为这并不是真正的答案，而可能更多是对您所看到的错误的解释。

答案 2 :(得分：3)

您需要将键/值参数从%Plug.Conn{}对象（conn）中拉出。在路由范围内尚未定义键/值变量。 conn对象仅可用，因为它是由Plug提供的post宏注入的。

我不太清楚您要提交给路由器的请求类型，但是我以JSON为例。您可以执行以下操作来手动解析连接中的主体：

with {:ok, raw_body} <- Plug.Conn.read_body(conn),
     {:ok, body} <- Poison.decode(raw_body) do
  key = Map.get(body, "key")
  value = map.get(body, "value")
  # ... other logic
end

但是，Plug项目为您提供了一个很好的便捷插件，您可以使用通用方法Plug.Parsers来解析请求正文。

要在路由器中实现此功能，只需将插头添加到路由器顶部（我认为是在Plug.Logger下方）：

plug Plug.Parsers, 
  parsers: [:urlencoded, :json]
  json_decoder: Poison,
  pass: ["text/*", "application/json"]

:urlencoded部分将解析您的查询参数，而:json部分将解析请求的正文。

然后在下面的路线中，您可以通过conn键中的:params对象获取键/值参数，如下所示：

%{params: params} = conn
key = Map.get(params, "key")
value = Map.get(params, "value")

另外，我应该注意，目前最好的JSON解码器是Jason，它基本上是Poison的直接替代品，但速度更快。

无论如何，阅读hexdocs确实可以帮助您解决这些问题，并且Plug项目具有出色的文档。我认为Elixir是一门很好的编程语言（尽管学习面向对象的范例也是必不可少的）。编码愉快！

相关问题
最新问题