Question

如何使用EXTENSION2使用BAPI_OUTB_DELIVERY_CHANGE更新Z字段。

我尝试使用BAPI更新LIKP表中的某些Z字段以更新交货，但调用后未进行任何更改。

有人知道吗？

Answer 1

我找到了BAdI-SMOD_V50B0001。我做了一个增强的实现动作，并在方法EXIT_SAPLV50I_010（用于更改外向交货的用户出口BAPI）中设置以下代码。

METHOD if_ex_smod_v50b0001~exit_saplv50i_010.

CONSTANTS: lc_vbkok    TYPE char5  VALUE 'VBKOK',           "Enhance the structure for more z fields in LIKP
           lc_vbpok    TYPE char5  VALUE 'VBPOK',           "Enhance the structure for more z fields in LIPS
           lc_cs_vbkok TYPE char8  VALUE 'CS_VBKOK'.

DATA: lv_item TYPE posnr_vl.
FIELD-SYMBOLS: <lfs_fieldname> TYPE any.

LOOP AT extension2 INTO DATA(lw_extension2).

  CASE lw_extension2-param.
      "As a structure in row 0
    WHEN lc_vbkok. "Fields for LIKP
        ASSIGN (lc_cs_vbkok) TO FIELD-SYMBOL(<lfs_vbkok>).
        IF <lfs_vbkok> IS ASSIGNED.
          ASSIGN COMPONENT lw_extension2-field OF STRUCTURE <lfs_vbkok> TO <lfs_fieldname>.
          IF <lfs_fieldname> IS ASSIGNED.
            <lfs_fieldname> = lw_extension2-value.
          ENDIF.
        ENDIF.

      "As a table from row 1 to n
    WHEN lc_vbpok. "Fields for LIPS
        MOVE lw_extension2-row TO lv_item.
        READ TABLE ct_vbpok ASSIGNING FIELD-SYMBOL(<lfs_vbpok>) WITH KEY posnr_vl = lv_item.
        IF sy-subrc = 0.
          ASSIGN COMPONENT lw_extension2-field OF STRUCTURE <lfs_vbpok> TO <lfs_fieldname>.
          IF <lfs_fieldname> IS ASSIGNED.
            <lfs_fieldname> = lw_extension2-value.
          ENDIF.
        ENDIF.

  ENDCASE.

ENDLOOP.

ENDMETHOD.

使用appen结构增强结构VBKOK和LIKP，以添加新的z字段，并出于相同目的增强结构VBPOK和LIPS。

还要看一下LV50LF01程序，并且需要实现一个附加的增强点以保留这些值。

在此之后，我以为得到了它。

METHOD m_update_delivery.

DATA: lw_header_data    TYPE bapiobdlvhdrchg,
      lw_header_control TYPE bapiobdlvhdrctrlchg,
      lw_extension2     TYPE bapiext.

DATA: li_extension2 TYPE TABLE OF bapiext,
      li_return     TYPE TABLE OF bapiret2.

DATA: lv_delivery TYPE bapiobdlvhdrchg-deliv_numb.

lw_header_data-deliv_numb = p_w_output-delivery.
lw_header_control-deliv_numb = p_w_output-delivery.
lv_delivery = p_w_output-delivery.

lw_extension2-param = 'VBKOK'.
lw_extension2-field = 'ZZEXIDV'.

lw_extension2-value = p_w_output-value.
APPEND lw_extension2 TO li_extension2.

" Call BAPI to update delivery
CALL FUNCTION 'BAPI_OUTB_DELIVERY_CHANGE'
  EXPORTING
    header_data    = lw_header_data
    header_control = lw_header_control
    delivery       = lv_delivery
  TABLES
    extension2     = li_extension2
    return         = li_return.

READ TABLE li_return INTO DATA(lw_return)
                     WITH KEY type = c_e.
IF sy-subrc <> 0.
  COMMIT WORK AND WAIT.
ENDIF.

ENDMETHOD.

Answer 2

您需要在BAPI功能模块之后添加 BAPI_COMMIT 。

如何使用EXTENSION2使用BAPI_OUTB_DELIVERY_CHANGE更新Z字段

2 个答案: