Question

我有一个xml：

<root>
 <child attrib1="1">
  <subChild>
   <name>subChild1</name>
  </subChild>
 </child>
 <child attrib1="2>
  <subChild2>
   <name>subChild2</name>
  </subChild2>
 </child>

我希望xslt生成如下的o / p，即xpath及其值：

/ root / child [@ attrib1 =“ 1] / subChild / name =” subChild1“
/ root / child [@ attrib1 =“ 2] / subChild2 / name =” subChild2“

Answer 1

如评论中所述，您的问题并不十分清楚。尝试将类似的内容作为起点：

XSLT 1.0

<xsl:stylesheet version="1.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="text" encoding="utf-8" />
<xsl:strip-space elements="*"/>

<xsl:template match="/">
    <xsl:for-each select="//text()">
        <xsl:apply-templates select="parent::*"/>
        <xsl:text>="</xsl:text>
        <xsl:value-of select="."/>
        <xsl:text>"&#10;</xsl:text>
    </xsl:for-each>
</xsl:template>

<xsl:template match="*">
    <xsl:apply-templates select="parent::*"/>
    <xsl:text>/</xsl:text>
    <xsl:value-of select="name()"/>
    <xsl:apply-templates select="@*"/>  
</xsl:template>

<xsl:template match="@*">
    <xsl:text>[@</xsl:text>
    <xsl:value-of select="name()"/>
    <xsl:text>="</xsl:text>
    <xsl:value-of select="."/>
    <xsl:text>"]</xsl:text>
</xsl:template>

</xsl:stylesheet>

Answer 2

参考我在xslt下尝试过的其他帖子，它会生成预期的o / p：

<xsl:stylesheet version="1.0"  xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:output omit-xml-declaration="yes" indent="yes"/>
    <xsl:strip-space elements="*"/>

    <xsl:variable name="vApos">'</xsl:variable>

    <xsl:template match="*[not(*)]">
    <xsl:if test="not(*)">
     <xsl:apply-templates select="ancestor-or-self::*" mode="path"/>
     <xsl:value-of select="concat('=',$vApos,.,$vApos)"/>
     <xsl:text>&#xA;</xsl:text>
    </xsl:if>
    </xsl:template>

    <xsl:template match="*" mode="path">
    <xsl:value-of select="concat('/',name())"/>
    <xsl:apply-templates select="@*" mode="path"/>
    </xsl:template>

    <xsl:template match="@*" mode="path">
    <xsl:value-of select="concat('[@',name(), '=',$vApos,.,$vApos,']')"/>
    </xsl:template>
    </xsl:stylesheet>

示例i / p xml：

<root id='1'>
    <elemA>one</elemA>
    <elemA attribute1='first' attribute2='second'>two</elemA>
    <elemB attribute='1'>three</elemB>
    <elemA >four</elemA>
    <elemC attribute='c'>
        <elemB attribute='2'>five</elemB>
        <elemB attribute='3'>five</elemB>
    </elemC>
</root>

输出：

/root[@id='1']/elemA='one'
/root[@id='1']/elemA[@attribute1='first'][@attribute2='second']='two'
/root[@id='1']/elemB[@attribute='1']='three'
/root[@id='1']/elemA='four'
/root[@id='1']/elemC[@attribute='c']/elemB[@attribute='2']='five'
/root[@id='1']/elemC[@attribute='c']/elemB[@attribute='3']='five'

使用XSLT从任何xml中提取具有所有值的所有文本节点的xpath

2 个答案: