Question

我正在尝试以下方式在SMT-LIB中编码扩展的自然语言（我定义了类似于Maybe Integer的数据类型）：

; extended integers -- if first field is true, then the value is infinity
(declare-datatypes () ((IntX (mk-int-x (is-infty Bool) (not-infty Int)))))

; addition
(define-fun plus ((x IntX) (y IntX)) IntX
  (ite (or (is-infty x) (is-infty y))
           (mk-int-x true 0)
           (mk-int-x false (+ (not-infty x) (not-infty y)))))

(declare-fun x () IntX)
(assert (= x (plus x (mk-int-x false 1))))
; x = x+1 when x |-> infty
(get-model)
(exit)

我将如何在SBV中对此进行编码？我尝试了以下方法，但那只是使SBV崩溃了。我也莫名其妙地怀疑这样做是否可以满足我的要求，但是我对SBV的工作方式还不熟悉。

!/usr/bin/env stack
{- stack script
  --resolver nightly-2018-11-23
  --package sbv
  --package syb
-}

{-# LANGUAGE DeriveAnyClass #-}
{-# LANGUAGE DeriveDataTypeable #-}
{-# LANGUAGE LambdaCase #-}
{-# LANGUAGE ScopedTypeVariables #-}

import Data.Generics
import Data.SBV

data IntX = IntX (Maybe Integer) deriving (Eq, Ord, Data, Read, Show, SymWord, HasKind)

pretty :: IntX -> String
pretty = \case
  IntX Nothing -> "∞"
  IntX n -> show n

instance Num IntX where
  (+) (IntX x) (IntX y) = IntX $ (+) <$> x <*> y
  (*) (IntX x) (IntX y) = IntX $ (*) <$> x <*> y
  fromInteger = IntX . Just

ex1 = sat $ do
  x :: SBV IntX <- free "x"
  return $ x .== x + 1

main :: IO ()
main = print =<< ex1

~/temp ✘ ./sbv.hs
sbv.hs: SBV.SMT.SMTLib2.cvtExp.sh: impossible happened; can't translate: s0 + s1
CallStack (from HasCallStack):

  error, called at ./Data/SBV/SMT/SMTLib2.hs:681:13 in sbv-7.12-9AiNAYtrUhB8YA6mr6BTn4:Data.SBV.SMT.SMTLib2

Answer 1

这里的根本问题是您的代码正在混合Haskell的具体Maybe类型并将其视为符号对象。但是，您在SMT-Lib2中的实现方式方面是正确的：您基本上需要在SBV中编写相应的代码。

我将从：

开始

{-# LANGUAGE DeriveAnyClass  #-}
{-# LANGUAGE DeriveGeneric   #-}
{-# LANGUAGE NamedFieldPuns  #-}

import Data.SBV
import Data.SBV.Control
import GHC.Generics (Generic)

这只是样板；并且除非您要使用查询模式，否则不需要Data.SBV.Control导入，但是正如我们将看到的那样，它确实派上了用场。

第一件事是对IntX类型进行符号编码；就像您在SMTLib中所做的一样：

data SIntX = SIntX { isInf :: SBool
                   , xVal  :: SInteger
                   }
                   deriving (Generic, Mergeable)

instance Show SIntX where
  show (SIntX inf val) = case (unliteral inf, unliteral val) of
                           (Just True,  _)      -> "oo"
                           (Just False, Just n) -> show n
                           _                    -> "<symbolic>"

除了派生Generic和Mergeable以外，以上内容都不令人感到意外。它只是使SBV能够根据您的自然使用ite。还要注意Show实例在使用unliteral来区分具体值和符号值时要格外小心。

接下来，我们添加了一些便利功能，同样也没什么奇怪的：

inf :: SIntX
inf = SIntX { isInf = true, xVal = 0 }

nat :: SInteger -> SIntX
nat v = SIntX { isInf = false, xVal = v }

liftU :: (SInteger -> SInteger) -> SIntX -> SIntX
liftU op a = ite (isInf a) inf (nat (op (xVal a)))

liftB :: (SInteger -> SInteger -> SInteger) -> SIntX -> SIntX -> SIntX
liftB op a b = ite (isInf a ||| isInf b) inf (nat (xVal a `op` xVal b))

现在我们可以将IntX设为数字：

instance Num SIntX where
  (+)         = liftB (+)
  (*)         = liftB (*)
  negate      = liftU negate
  abs         = liftU abs
  signum      = liftU signum
  fromInteger = nat . literal

（请注意，此语义的意思是oo - oo = oo，这充其量是可疑的。但这不是重点。您可能必须显式定义-并按需要进行处理。类似的评论申请signum。）

由于您要测试是否相等，因此我们还必须定义其符号版本：

instance EqSymbolic SIntX where
  a .== b = ite (isInf a &&& isInf b) true
          $ ite (isInf a ||| isInf b) false
          $ xVal a .== xVal b

类似地，如果要比较，则必须定义一个OrdSymbolic实例；但想法还是一样。

我们需要一种创建符号扩展自然的方法。以下函数可以很好地完成此任务：

freeSIntX :: String -> Symbolic SIntX
freeSIntX nm = do i <- sBool    $ nm ++ "_isInf"
                  v <- sInteger $ nm ++ "_xVal"
                  return $ SIntX { isInf = i, xVal = v }

严格来说，您无需命名变量。（即，不需要nm参数。）但是我发现出于明显的原因总是为变量命名总是很有帮助的。

现在，我们可以编写您的示例了：

ex1 :: IO SatResult
ex1 = sat $ do x <- freeSIntX "x"
               return $ x .== x+1

运行此命令时，我得到：

*Main> ex1
Satisfiable. Model:
  x_isInf = True :: Bool
  x_xVal  =    0 :: Integer

我相信您正在寻找的是什么。

在处理大型程序时，能够更直接地提取IntX值并对其进行进一步编程是有益的。这是查询模式派上用场的时候。首先，一个助手：

data IntX = IntX (Maybe Integer) deriving Show

queryX :: SIntX -> Query IntX
queryX (SIntX {isInf, xVal}) = do
          b <- getValue isInf
          v <- getValue xVal
          return $ IntX $ if b then Nothing
                               else Just v

现在我们可以编码：

ex2 :: IO ()
ex2 = runSMT $ do x <- freeSIntX "x"
                  constrain $ x .== x+1

                  query $ do cs <- checkSat
                             case cs of
                               Unk   -> error "Solver said Unknown!"
                               Unsat -> error "Solver said Unsatisfiable!"
                               Sat   -> do v <- queryX x
                                           io $ print v

然后我们得到：

*Main> ex2
IntX Nothing

我希望这会有所帮助。我把所有这些代码都放在了要点上：https://gist.github.com/LeventErkok/facfd067b813028390c89803b3a0e887

在SBV中编码扩展的自然语言

1 个答案: