Question

我想用一个单词标记字符串。我正在使用str：tokenize（），但似乎分隔符可能只是单个字符，即使分隔符由更多字符组成，tokenize（）也会在分隔符中搜索列出的字符。

例如

InputString : "first|second|third|@@|First|Second|Third  
Delimiter : |@@|  
str:tokenize(&InputString, '|@@|')

但这将返回6行而不是2行

由于要进行带有标记化“句子”的下一个操作，因此我需要将其放入每个容器中

str：tokenize（）在做什么？

Answer 1

您得到的结果符合str:tokenize函数的规范：

第二个参数是由多个字符组成的字符串。此字符串中的每个字符都用作分隔字符。的第一个参数给出的字符串在任何情况下都会被拆分这些字符。

您想要做的是在给定的 pattern 出现时拆分给定的字符串。为此，您需要使用str:split函数-如果您的处理器支持的话。

Answer 2

建议多谢。

我附上了符合我的需求的示例代码-可能会帮助某人节省时间。它需要元素并根据两个定界符对其进行解析，再加上绘制所有单元格（包括空单元格-甚至最后一个单元格都为空）。如果第二个单元格/列为空，则将跳过整行。

XML：

    <?xml version="1.0" encoding="UTF-8"?>
<catalog>
    <cd>
        <title>firs t|sec ond|third|@@|First|Second|Third</title>
        <artist>Bob Dylan</artist>
    </cd>
    <cd>
        <title>1||3|@@|4|5|6|@@|7|8|</title>
        <artist>Bob Dylan</artist>
    </cd>
    <cdd>
        <title>1|2|@@|3|4|@@||</title>
        <artist>Bob Dylan</artist>
    </cdd>
</catalog>

XSL：

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
    xmlns:str="http://exslt.org/strings"
    xmlns:exsl="http://exslt.org/common" exclude-result-prefixes="str exsl">
    <!-- Edit these parameters if necessary. -->
    <xsl:param name="rowDelimiter" select="'|@@|'"/>
    <xsl:param name="columnDelimiter" select="'|'"/>
    <!-- Edit these parameters if necessary. -->

    <xsl:template match="/">
        <html> 
            <body>
                <h2>My test</h2>
                <table border="1">
                    <tr bgcolor="#9acd32">
                        <th style="text-align:left">Title</th>
                    </tr>

                    <xsl:for-each select="catalog/cd">
                        <xsl:variable name="ercm_rows">
                            <xsl:call-template name="splitStringToRows">
                                <xsl:with-param name="list" select="title" />
                                <xsl:with-param name="delimiter" select="$rowDelimiter"/>
                            </xsl:call-template>
                        </xsl:variable>


                        <xsl:for-each select="exsl:node-set($ercm_rows)/ercm_row">
                                  <xsl:if test="./ercm_column[position()=2 != ''] and ./ercm_column[position()=2]/text()"> 
                            <tr>
                                <xsl:for-each select="./ercm_column">
                                    <td><xsl:value-of select="."/></td>
                                </xsl:for-each>
                            </tr>
                            </xsl:if> 
                        </xsl:for-each>

                    </xsl:for-each>
                </table>


            </body>
        </html>
    </xsl:template>

   <!--  ROWS SPLIT --> 
    <xsl:template name="splitStringToRows">
        <xsl:param name="list" />
        <xsl:param name="delimiter" />


        <xsl:variable name="newlist">
            <xsl:choose>
                <xsl:when test="contains($list, $delimiter)">
                    <xsl:value-of select="$list" />
                </xsl:when>
                <xsl:otherwise>
                    <xsl:value-of select="concat($list, $delimiter)"/>
                </xsl:otherwise>
            </xsl:choose>
        </xsl:variable>

        <xsl:variable name="first" select="substring-before($newlist, $delimiter)" />
        <xsl:variable name="remaining" select="substring-after($newlist, $delimiter)" />
        <ercm_row>
            <xsl:call-template name="splitStringToColumns">
                    <xsl:with-param name="list" select="$first" />
                    <xsl:with-param name="delimiter" select="$columnDelimiter"/>
                </xsl:call-template>
        </ercm_row>


        <xsl:if test="$remaining">
            <xsl:call-template name="splitStringToRows">
                <xsl:with-param name="list" select="$remaining" />
                <xsl:with-param name="delimiter" select="$rowDelimiter"/>
            </xsl:call-template>
        </xsl:if>
    </xsl:template>

    <!--  COLUMNS SPLIT -->
    <xsl:template name="splitStringToColumns">
        <xsl:param name="list" />
        <xsl:param name="delimiter" />

        <xsl:variable name="newlist">
            <xsl:choose>
                <xsl:when test="contains($list, $delimiter)">
                    <xsl:value-of select="$list" />
                </xsl:when>
                <xsl:otherwise>
                    <xsl:value-of select="concat($list, $delimiter)"/>
                </xsl:otherwise>
            </xsl:choose>
        </xsl:variable>

        <xsl:variable name="first" select="substring-before($newlist, $delimiter)" />
        <xsl:variable name="remaining" select="substring-after($newlist, $delimiter)" />
        <ercm_column>
              <xsl:value-of select="$first"/>
        </ercm_column>

        <!--    <xsl:if test="$remaining" > -->
        <xsl:if test="contains($list, $delimiter)" >
            <xsl:call-template name="splitStringToColumns">
                <xsl:with-param name="list" select="$remaining" />
                <xsl:with-param name="delimiter" select="$columnDelimiter"/>
            </xsl:call-template>
        </xsl:if>
    </xsl:template>



</xsl:stylesheet>

screenshot of Output vs XML

xsl并用一个词标记

2 个答案: