如何在LISP中不进行两次递归

Question

我正在尝试编写一个程序，该程序根据给定的数字返回 Pell数字序列。

例如(pellNumb 6)应该返回列表(0 1 2 5 12 29 70)

到目前为止，这是我的代码。 我可以计算数字，但不能跳过双递归。

(defun base (n)
  (if (= n 0)
      0
      (if (= n 1) 
          1))) 

(defun pellNumb (n)
  (if (or (= n 0) (= n 1))
      (base n)
      (let ((x (pellNumb (- n 2))))
        (setq y (+ (* 2 (pellNumb (- n 1))) x))
        (print y))))

(pellNumb 4)的输出为2 2 5 12，这是因为我将两次递归到(pellNumb 2)。

有没有一种方法可以跳过这些并将这些值存储在列表中？

谢谢！

Answer 1

获取第n个数字

是的，有一种方法-使用multiple values：

(defun pell-numbers (n)
  "Return the n-th Pell number, n-1 number is returned as the 2nd value.
See https://oeis.org/A000129, https://en.wikipedia.org/wiki/Pell_number"
  (check-type n (integer 0))
  (cond ((= n 0) (values 0 0))
        ((= n 1) (values 1 0))
        (t (multiple-value-bind (prev prev-1) (pell-numbers (1- n))
             (values (+ (* 2 prev) prev-1)
                     prev)))))
(pell-numbers 10)
==> 2378 ; 985

这是递归序列的标准技巧，该递归序列取决于多个先前的值，例如Fibonacci。

性能

请注意，您的两次递归意味着(pell-numbers n)具有指数（！）性能（计算需要O(2^n)时间），而我的单次递归是线性的（即O(n)）。 此外，斐波那契数具有方便的属性，允许logarithmic recursive implementation，即花费O(log(n))时间。

获取列表中最多n的所有数字

如果您需要第n号之前的所有数字，则需要一个简单的循环：

(defun pell-numbers-loop (n)
  (loop repeat n
    for cur = 1 then (+ (* 2 cur) prev)
    and prev = 0 then cur
    collect cur))
(pell-numbers-loop 10)
==> (1 2 5 12 29 70 169 408 985 2378)

如果您坚持递归：

(defun pell-numbers-recursive (n)
  (labels ((pnr (n)
             (cond ((= n 0) (list 0))
                   ((= n 1) (list 1 0))
                   (t (let ((prev (pnr (1- n))))
                        (cons (+ (* 2 (first prev)) (second prev))
                              prev))))))
    (nreverse (pnr n))))
(pell-numbers-recursive 10)
==> (0 1 2 5 12 29 70 169 408 985 2378)

请注意，递归是非尾递归的，因此循环版本可能更有效。

当然可以生成尾部递归版本：

(defun pell-numbers-tail (n)
  (labels ((pnt (i prev)
             (if (= i 0)
                 prev ; done
                 (pnt (1- i)
                      (cond ((null prev) (list 0)) ; n=0
                            ((null (cdr prev)) (cons 1 prev)) ; n=1
                            (t
                             (cons (+ (* 2 (or (first prev) 1))
                                      (or (second prev) 0))
                                   prev)))))))
    (nreverse (pnt (1+ n) ()))))
(pell-numbers-tail 10)
==> (0 1 2 5 12 29 70 169 408 985 2378)