捕获输出

Question

我试图通过Autohotkey将命令发送到Git Bash终端，但无法找到读取其输出的方法。有一个简单的方法吗？我正在发送这个

运行，C：\ Users \ Unknown \ AppData \ Local \ Programs \ Git \ git-bash.exe
睡觉2000

发送cd / c / Users / Unknown / Desktop / git / fw {Enter}

睡眠，1000

发送git log --pretty = format：'`％h'-n 1 {Enter}

答案是在终端上显示的提交号

我怎么读？

谢谢

Answer 1

捕获输出

要捕获命令的输出，可以使用以下RunWaitOne()函数之一。

选项1：：不使用临时文件，也无法隐藏命令窗口。（Source）

; From https://www.autohotkey.com/docs/commands/Run.htm#Examples
RunWaitOne(command) {
  shell := ComObjCreate("WScript.Shell")
  exec := shell.Exec(ComSpec " /C """ command """") ; change: added '"' around command
  return exec.StdOut.ReadAll()
}

选项2：使用临时文件，命令窗口被隐藏。（根据WTFPL发布）

RunWaitOne(command) {
  tmpFile := A_Temp . "\" . A_ScriptName . "_RunWaitOne.tmp"
  RunWait, % ComSpec . " /c """ . command . " > """ . tmpFile . """""",, Hide
  FileRead, result, %tmpFile%
  FileDelete, %tmpFile%
  return result
}

工作示例

我个人不喜欢路径中的硬编码，因此设置了以下答案以执行以下步骤：

在系统PATH环境变量上查找Git安装并将其存储为GIT_BIN_DIR
如果尚未找到安装，请在默认安装目录中查找一个并将其存储为GIT_BIN_DIR
如果找不到Git并退出，则显示错误消息。
将要调用的命令排队。
执行命令并将结果存储在变量result中。
显示结果

代码

代码在WTFPL下发布

; STEP 1: Try to find Git on PATH
EnvGet, E_PATH, PATH
GIT_BIN_DIR := ""
for i, path in StrSplit(E_PATH, ";")
{
  if (RegExMatch(path, "i)Git\\cmd$")) {
    SplitPath, path, , parent
    GIT_BIN_DIR := parent . "\bin"
    break
  }
}

; STEP 2: Fallback to default install directories.
if (GIT_BIN_DIR == "") {
  allUsersPath := A_ProgramFiles . "\Git\bin"
  currentUserPath := A_AppData . "\Programs\Git\bin"
  if (InStr(FileExist(currentUserPath), "D"))
    GIT_BIN_DIR := currentUserPath
  else if (InStr(FileExist(allUsersPath), "D"))
    GIT_BIN_DIR := allUsersPath
}

; STEP 3: Show error Git couldn't be found.
if (GIT_BIN_DIR == "") {
  MsgBox 0x1010,, Could not find Git's 'bin' directory
  ExitApp
}

; STEP 4 - Queue any commands.
; commands becomes "line1 & line2 & ..." thanks to the Join continuation section
commands := "
(Join`s&`s
cd /c/Users/Unknown/Desktop/git/fw
git log --pretty=format:'`%h' -n 1
)"

; STEP 5 - Execute the commands (Uses "Git\bin\sh.exe" so we can capture output)
result := RunWaitOne("""" . GIT_BIN_DIR . "\sh.exe"" --login -i -c """ . commands . """")

; STEP 6 - Show the result
MsgBox 0x1040,, % result

如何通过Autohotkey

1 个答案:

捕获输出

工作示例

代码