Question

我正在尝试使用Terraform基于特定AWS区域中的标签创建某些EBS卷的快照。我曾尝试根据标签过滤EBS卷。当在filter属性中仅指定一个标记值但对于多个值时，我可以获得清晰的EBS卷id输出，我得到以下错误：

data.aws_ebs_volume.ebs_volume：data.aws_ebs_volume.ebs_volume：您的查询返回了多个结果。请尝试更具体的搜索条件，或将most_recent属性设置为true。

下面是我的Terraform模板：

data "aws_ebs_volume" "ebs_volume" {
  filter {
    name   = "tag:Name"
    values = ["EBS1","EBS2","EBS3"]
  }
}
output "ebs_volume_id" {
  value = "${data.aws_ebs_volume.ebs_volume.id}"
}

resource "aws_ebs_snapshot" "ebs_volume" {
  volume_id = "${data.aws_ebs_volume.ebs_volume.id}"
}

是否存在使用terraform中的任何类型的循环语句创建多个EBS卷快照的清晰方法？

Answer 1

您可以使用count meta parameter遍历列表，创建多个资源或数据源。

在您的情况下，您可以执行以下操作：

variable "ebs_volumes" {
  default = [
    "EBS1",
    "EBS2",
    "EBS3",
  ]
}

data "aws_ebs_volume" "ebs_volume" {
  count = "${length(var.ebs_volumes)}"

  filter {
    name   = "tag:Name"
    values = ["${var.ebs_volumes[count.index]}"]
  }
}

output "ebs_volume_ids" {
  value = ["${data.aws_ebs_volume.ebs_volume.*.id}"]
}

resource "aws_ebs_snapshot" "ebs_volume" {
  count     = "${length(var.ebs_volumes)}"
  volume_id = "${data.aws_ebs_volume.ebs_volume.*.id[count.index]}"
}

使用Terraform创建多个EBS卷的快照

1 个答案: