Question

我有一个像这样的数据集：

DATA tmp;
    INPUT
        identifier $
        d0101 d0102 d0103 d0104 d0105 d0106
        d0107 d0108 d0109 d0110 d0111 d0112
    ;
    DATALINES;
    a 1 2 3 4 5 6 7 8 9 10 11 12
    b 4 5 7 4 5 6 7 6 9 10 3 12
    c 5 2 3 5 5 4 7 8 3 1 1 2
    ;
RUN;

我正在尝试创建一个像这样的数据集：

DATA tmp;
    INPUT
        identifier $ day value
    ;
    DATALINES;
    a '01JAN2018'd 1
    a '02JAN2018'd 2
    a '03JAN2018'd 3
    a '04JAN2018'd 4
    a '05JAN2018'd 5
    a '06JAN2018'd 6
    a '07JAN2018'd 7
    a '08JAN2018'd 8
    a '09JAN2018'd 9
    a '10JAN2018'd 10
    a '11JAN2018'd 11
    a '12JAN2018'd 12
    b '01JAN2018'd 4
    b '02JAN2018'd 5
    b '03JAN2018'd 7
    ...
    ;
RUN;

我知道“融化”这样的数据集的语法-我已经完成了用于表示一年中十二个月中的每个月中特定值的列的类似宏。

我正在努力的是如何从年初至今遍历整天（假设have数据集将年初至今的整天作为列）。

我已经习惯了Python，所以我可能会做些事情：

>>> import datetime
>>> 
>>> def dates_ytd():
...     end_date = datetime.date.today()
...     start_date = datetime.date(end_date.year, 1, 1)
...     diff = (end_date - start_date).days
...     for x in range(0, diff + 1):
...         yield end_date - datetime.timedelta(days=x)
... 
>>> def create_date_column(dt):
...     day, month = dt.day, dt.month
...     day_fmt = '{}{}'.format('0' if day < 10 else '', day)
...     month_fmt = '{}{}'.format('0' if month < 10 else '', month)
...     return 'd{}{}'.format(month_fmt, day_fmt)
... 
>>> result = [create_date_column(dt) for dt in dates_ytd()]
>>> 
>>> result[:5]
['d1031', 'd1030', 'd1029', 'd1028', 'd1027']
>>> result[-5:]
['d0105', 'd0104', 'd0103', 'd0102', 'd0101']

这是我的SAS尝试：

%MACRO ITER_DATES_YTD();
    DATA _NULL_;
        %DO v_date = '01012018'd %TO TODAY();
            %PUT d&v_date.;
            * Will do "melting" logic here";
        %END
%MEND ITER_DATES_YTD;

使用%ITER_DATES_YTD();运行此命令时，什至没有任何内容被打印到我的日志中。我在这里想念什么？我基本上想遍历“ YTD”列，例如d0101，d0102，d0103，...。

Answer 1

这比宏/数据步长问题更像是转置问题。

核心问题是元数据中有数据，这意味着列名中编码了“日期”。

示例1：

转置数据，然后使用d<yymm> _name_值计算实际日期。

proc transpose data=have out=have_t(rename=col1=value);
  by id;
run;

data want (keep=id date value);
  set have_t;

  * convert the variable name has day-in-year metadata into some regular data;
  date = input (cats(year(today()),substr(_name_,2)),yymmdd10.);

  format date yymmdd10.;
run;

示例2：

执行基于数组的转置。 D<mm><dd>变量以 value_at_date 的角色使用，并且由于一致的命名约定而易于排列。 VNAME函数从数组引用中提取原始变量名，并从<mm><dd>部分计算出日期值

data want;
  set have;
  array value_at_date d:;

  do index = 1 to dim(value_at_date);
    date = input(cats(year(today()),substr(VNAME(value_at_date(index)),2)), yymmdd10.);
    value = value_at_date(index);
    output;
  end;

  format date yymmdd10.;
  keep id date value;
run;

Answer 2

要遍历日期，必须先将其转换为数字，然后再从中提取日期部分。

%macro iterateDates();
    data _null_;
        %do i = %sysFunc(inputN(01012018,ddmmyy8.)) %to %sysFunc(today()) %by 1;
            %put d%sysFunc(putN(&i, ddmmyy4.));
        %end;
    run;
%mend iterateDates;

%iterateDates();

我认为'01012018'仅在数据步骤中处理，而不在宏代码中处理。请记住，首先执行宏代码，然后才执行数据步骤。您可以考虑一下它，例如使用SAS宏构建SAS代码然后运行它。

SAS：在宏中从开始日期到结束日期进行迭代

2 个答案: