Question

我一直在在线关注文档，并浏览其他堆栈溢出查询，但是还没有找到通过DDE将SAS数据集输出到excel的方法。

我正在运行的SAS版本是SAS9.4 我正在运行的Excel版本是Microsoft Office 2016-Excel 2016

我用来导出的代码是

/*Excel DDE interface options*/ /*TEST*/
options noxwait noxsync;

X '"C:\Users\user.name\Desktop\template_dde.xlsx"';

data _null_;
    rc=sleep(15);
run;

filename ddedata dde 'excel|SFA!r2c1:r4000c56';

data _null_;
    file ddedata notab;
    set work.Results_output_format end=eof;
put '"THIS IS A TEST"';
run;

%LET timestamp = %SYSFUNC(PUTN(%SYSFUNC(DATE()),yymmddn8.));
%LET hourstamp = %SYSFUNC(COMPRESS(%SYSFUNC(TIME(),time.),%STR( :)));

data _null_;
    length cmnd $150.;
    file ddedata;

    cmnd = '"[save.as("C:\Users\user.name\Desktop\&timestamp._&hourstamp._template_dde.xlsx")]"';
    put cmnd;
    put '[quit()]';
run;

它输出“这是一个测试”，然后输出save语句，但是没有导出我的数据，并且实际上没有保存文件。

我能俯瞰一切吗？

Answer 1

SET不会不隐式将数据集内容放置在Excel文件中。您需要使用PUT语句将数据添加到工作表中。您还需要使用单独的文件名将命令发送到Excel|system通道。

您的代码在尝试进行宏变量解析时使用单引号-这是不正确的。

此代码假定现有工作簿c:\temp\template_dde.xlsx

* open template in Excel;
X '"C:\Temp\template_dde.xlsx"';

* wait for app to start and file to load;
data _null_; rc=sleep(3); run;

* define filerefs for data transfer and command execution;
filename ddedata dde 'excel|Sheet1!r2c1:r4000c56';
filename ddecmnd dde 'excel|System';

* pump data into excel cells at location specified in ddedata;
data _null_;
  file ddedata ; * <--- removed your NOTAB option, so now I dont have to put '09x' between each variable;

  set sashelp.class;
  put name sex age height weight; 
run;

* Extended ISO timestamp as yyyy-mm-dd_hh-mm-ss;
%let timestamp = %sysfunc(translate(%sysfunc(datetime(),E8601DT),%str(_-),%str(T:)));

* send commands to save workbook and close Excel;
data _null_;
    file ddecmnd;

    put "[save.as(""C:\Temp\&timestamp._template_dde.xlsx"")]";
    put '[quit()]';
run;

关于DDE的大量会议论文，例如"SAS®-with-Excel Application Development: Tools and Techniques"，SUGI 31，LeRoy Bessler，Assurant Health

SAS to Excel DDE产生测试但不输出数据

1 个答案: