Question

我有这个正则表达式。

$string =~ s/(?<!["\w])(\w+)(?=:)|(?<=:)([\w\d\\.+=\/]+)/"$1$2"/g;

正则表达式本身可以正常工作。

但是由于我正在替换（并在全球范围内）替换，所以我总是会警告$ 1或$ 2未初始化。这些警告使我的日志文件混乱。

如何更好地避免此类警告？还是我最好的选择只是关闭警告？我对此表示怀疑。

侧面问题：是否有更好的方法可以做到这一点，例如根本不使用正则表达式？我正在做的是修复JSON，其中某些key：value对在尝试解码时没有双引号，并且JSON模块不喜欢它。

Answer 1

有两种方法可以解决此问题。

如果您打算使用捕获组：

在捕获替换项的每个子句的全部时。
将捕获组合并为1，然后将其移出。

 (                             # (1 start)
      (?<! ["\w] )
      \w+ 
      (?= : )
   |  
      (?<= : )
      [\w\d\\.+=/]+ 
 )                             # (1 end)

s/((?<!["\w])\w+(?=:)|(?<=:)[\w\d\\.+=\/]+)/"$1"/g

使用分支重置构造(?| aaa )。
这将导致每个轮换中的捕获组开始为其组编号
从同一点来看。
```
 (?|
      (?<! ["\w] )
      ( \w+ )                       # (1)
      (?= : )
   |  
      (?<= : )
      ( [\w\d\\.+=/]+ )             # (1)
 )
```
s/(?|(?<!["\w])(\w+)(?=:)|(?<=:)([\w\d\\.+=\/]+))/"$1"/g
使用可重复使用的命名捕获组（类似于分支重置）。
在每个替换中，重复使用相同的名称。将不相关的组设为空组。
这是通过在替换中使用 name 而不是数字来实现的。
```
    (?<! ["\w] )
    (?<V1> \w+ )                  # (1)
    (?<V2> )                      # (2)
    (?= : )
 |  
    (?<= : )
    (?<V1> )                      # (3)
    (?<V2> [\w\d\\.+=/]+ )        # (4)
```
s/(?<!["\w])(?<V1>\w+)(?<V2>)(?=:)|(?<=:)(?<V1>)(?<V2>[\w\d\\.+=\/]+)/"$+{V1}$+{V2}"/g

命名替换和分支重置这两个概念可以组合在一起
如果一个替代项包含多个捕获组。
下面的示例使用捕获组编号。

理论上，您将每个替代中的 dummy 捕获组放入
“填充”分支，使其等于单个交替中的最大组数。

实际上，必须执行此以避免Perl正则表达式中可能导致崩溃的错误。

 (?|                    # Branch Reset
                             # ------ Br 1 --------
      ( )                    # (1)
      ( \d{4} )              # (2)
      ABC294
      ( [a-f]+ )             # (3)
   |  
                             # ------ Br 2 --------          
      ( :: )                 # (1)
      ( \d+ )                # (2)
      ABC555
      ( )                    # (3)
   |  
                             # ------ Br 3 --------
      ( == )                 # (1)
      ( )                    # (2)
      ABC18888
      ( )                    # (3)
 )

s/(?|()(\d{4})ABC294([a-f]+)|(::)(\d+)ABC555()|(==)()ABC18888())/"$1$2$3"/g

Answer 2

您可以尝试使用Cpanel::JSON::XS的relaxed mode或JSONY来解析几乎JSON，然后使用Cpanel :: JSON :: XS写出常规JSON。根据输入数据到底有什么问题，一个或另一个可能会更好地理解它。

use strict;
use warnings;
use Cpanel::JSON::XS 'encode_json';

# JSON is normally UTF-8 encoded; if you're reading it from a file, you will likely need to decode it from UTF-8
my $string = q<{foo: 1,bar:'baz',}>;

my $data = Cpanel::JSON::XS->new->relaxed->decode($string);
my $json = encode_json $data;
print "$json\n";

use JSONY;
my $data = JSONY->new->load($string);
my $json = encode_json $data;
print "$json\n";

如何避免用替代品替代Perl正则表达式中的警告？

2 个答案: