如何在asp中发送和处理Http Post？

Question

httpRequest.Open "POST", "www.example.com/handle.asp", False
httpRequest.setRequestHeader "Content-Type", "application/x-www-form-urlencoded"
httpRequest.send data
postResponse = httpRequest.response

我如何处理上述代码的帖子。在handle.asp中。在句柄中我想获取正在发送的数据并添加到它然后将某些内容发送回调用页面？

Answer 1

@Uzi：这是一个例子 -

somefile.asp调用handle.asp这是处理脚本：

Option Explicit

Dim data, httpRequest, postResponse

data = "var1=somevalue"
data = data & "&var2=someothervalue"
data = data & "&var3=someothervalue"

Set httpRequest = Server.CreateObject("MSXML2.ServerXMLHTTP")
httpRequest.Open "POST", "http://www.example.com/handle.asp", False
httpRequest.SetRequestHeader "Content-Type", "application/x-www-form-urlencoded"
httpRequest.Send data

postResponse = httpRequest.ResponseText

Response.Write postResponse ' or do something else with it

handle.asp的示例：

Option Explicit

Dim var1, var2, var3

var1 = Request.Form("var1")
var2 = Request.Form("var2")
var3 = Request.Form("var3")

' Silly example of a condition / test '
If var1 = "somecondition" Then
    var1 = var1 & " - extra text"
End If

' .. More processing of the other variables .. '

' Processing / validation done... '
Response.Write var1 & vbCrLf
Response.Write var2 & vbCrLf
Response.Write var3 & vbCrLf

Answer 2

正如您通过使用Request.Form("parameter")读取POSTed值并随意使用它们来处理通常在ASP中发布的数据一样。

您只需确保以处理POST请求的脚本可轻松解码/可用的格式从处理脚本返回数据。