Question

编辑以回应评论*

您好，

我是一名XSLT菜鸟，需要一些帮助。我正在尝试使用XSLT 1.0进行过滤器/组合组合（不能将XSLT 2.0用于此应用程序）。

以下是xml

的示例

<entry>
  <item>
    <name>Widget 2</name>
    <rank>2</rank>
    <types>
       <type>Wood</type>
       <type>Fixed</type>
       <type>Old</type>
    </types>
  </item>
   <item>
    <name>Widget 1</name>
    <rank>2</rank>
    <types>
       <type>Metal</type>
       <type>Broken</type>
       <type>Old</type>
    </types>
  </item>
  <item>
    <name>Widget 3</name>
    <rank>1</rank>
    <types>
       <type>Metal</type>
       <type>New</type>
    </types>
  </item>
</entry>

现在我要做的是输出html，在那里我获得基于<type>的XML子集，然后按等级分组。例如，如果用户选择Metal类型的所有项目，则输出应为：


Rank 1
<li id="mylist">Widget 3</li>
<br\>


Rank 2
<li id="mylist">Widget 1</li>
<br\>

如果用户用户选择类型Old，则输出将是


Rank 2
<li id="mylist">Widget 1</li>
<li id="mylist">Widget 2</li>
<br\>

我可以轻松地使用排名上的键进行分组，但尝试两者都不起作用。以下是我尝试过的xslt示例：

<xsl:param name="typeParam"/>
<xsl:key name="byRank" use="rank" match="item"/>

<xsl:for-each select="item[count(.|key('byRank',rank)[1])=1]">
  <xsl:sort data-type="number" select="rank"/>
  <xsl:for-each select="key('byRank',rank)">
    <xsl:sort select="name"/>
    <xsl:if test="count(rank)&gt;0">
      <p class="nospace"><font color="#800000"><b>Rank<xsl:value-of select="rank"/></b></font></p>
      <xsl:for-each select="types[types=$typeParam]">
        <li id="mylist"><b><xsl:value-of select="../name"/></b></li>
      </xsl:for-each>
    <br/>
  </xsl:if>
</xsl:for-each>
</xsl:for-each>

我从中得到的结果是我确实得到了我想要的xml子集，但它也显示了所有不同的等级值。我想将它限制为$ typeParam中指定的类型的行列。

我已经尝试将for-each语句移动到代码中的早期语句，并修改if语句以选择$ typeParam，但两者都不起作用。我也尝试使用rank和type连接我的密钥，但这似乎也不起作用（只有在$ typeParam中的类型是类型下的第一个子类时才有效。）

由于

杰夫

Answer 1

此样式表：

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:key name="kItemByRank" match="item" use="rank"/>
    <xsl:param name="pType" select="'Old'"/>
    <xsl:template match="entry">
        <xsl:for-each select="item[count(.|key('kItemByRank',rank)[1])=1]">
            <xsl:sort select="rank" data-type="number"/>
            <xsl:variable name="vGroup" select="key('kItemByRank',rank)[
                                                   types/type = $pType
                                                ]"/>
            <xsl:if test="$vGroup">
                <p class="nospace">
                    <font color="#800000">
                        <b>
                            <xsl:value-of select="concat('Rank ',rank)"/>
                        </b>
                    </font>
                </p>
                <xsl:apply-templates select="$vGroup">
                    <xsl:sort select="name"/>
                </xsl:apply-templates>
                <br/>
            </xsl:if>
        </xsl:for-each>
    </xsl:template>
    <xsl:template match="item">
        <li id="mylist">
            <b>
                <xsl:value-of select="name"/>
            </b>
        </li>
    </xsl:template>
</xsl:stylesheet>

输出：

<p class="nospace">
    <font color="#800000">
        <b>Rank 1</b>
    </font>
</p>
<li id="mylist">
    <b>Widget 3</b>
</li>
<br />
<p class="nospace">
    <font color="#800000">
        <b>Rank 2</b>
    </font>
</p>
<li id="mylist">
    <b>Widget 1</b>
</li>
<br />

将pType param设置为'Old'，输出：

<p class="nospace">
    <font color="#800000">
        <b>Rank 2</b>
    </font>
</p>
<li id="mylist">
    <b>Widget 1</b>
</li>
<li id="mylist">
    <b>Widget 2</b>
</li>
<br />

XSLT 1.0在多个级别上对多个值进行分组

1 个答案: