Question

这看起来像重复的，但是我无法解决遇到的问题。

我正在尝试从CSV / TSV文件中查找每列的平均值，数据如下所示：

input.tsv

ID  source  random  text val1 val2 val3 val4 val330
1   atttt   eeeee   test 0.9  0.5  0.2  0.54 0.89
2   afdg    adfgrg  tf   0.6  0.23 0.5  0.4  0.29

output.tsv

ID  source  random  text Avg
1   atttt   eeeee   test 0.606
2   afdg    adfgrg  tf   0.404

或至少

ID  Avg
1   0.606
2   0.404

我尝试了here的建议

awk 'NR==1{next}
{printf("%s\t", $1
printf("%.2f\n", ($5 + $6 + $7)/3}' input.tsv

抛出错误。

和

awk '{ s = 4; for (i = 5; i <= NF; i++) s += $i; print $1, (NF > 1) ? s / (NF - 1) : 0; }' input.tsv

下面的代码也引发了语法错误

for i in `cat input.tsv` do; VALUES=`echo $i | tr '\t' '\t'`;COUNT=0;SUM=0;typeset -i j;IFS=' ';for j in $VALUES; do;SUM=`expr $SUM + $j`;COUNT=`expr $COUNT + 1`;done;AVG=`expr $SUM / $COUNT`;echo $AVG;done

帮助我解决该问题以计算行的平均值

Answer 1

您可以使用以下awk脚本：

 awk 'NR>1{
        for(i=5;i<=NF;i++)
          sum+=$i
      }
      {
        print $1,$2,$3,$4,(NF>4&&sum!=""?sum/(NF-4):(NR==1?"Avg":""))
        sum=0
      }' file | column -t

第一个块从第5个元素开始获取所有ID的总和。

第二个块，打印标题行和平均值。

column -t在列中显示结果。

Answer 2

从您的代码参考中：

awk 'NR==1{next}
   {
   # missing the last ). This print the 1st column
   #printf("%s\t", $1
    printf("%s\t", $1 )

   # missing the last ) and average of 3 colum only
   #printf("%.2f\n", ($5 + $6 + $7)/3
    printf("%.2f\n", ($5 + $6 + $7 + $8 + $9) / 5 )
   }' input.tsv

您的第二个代码不易使用，有许多子shell（backtic）和shell循环，但最重要的是，我认为它是为整数值和整行值（不是5> 9）而设计的。除非在这种情况下不要awk，否则就算了。

好玩

awk 'NR==1{
        # Header
        print $0 OFS "Avg"
        Count = NF - 5
        next
        }
        {
        # print each element of the line + sum after col 4
        for( i=Avg=0;i<=NF;i++) {
           if( i >=5 ) Avg+= $i
           printf( "%s ", $i)
           }
        # print average
         printf( "%.2f\n", Avg/Count )
        }
   ' input.tsv

假设这里始终是按全部值计算，如果行中的值较少而空值不计算，我们可以将(NF - 4)的值更改为

Answer 3

这将按预期工作：

ILicenseManager

或者只是为了好玩，如果您想使for循环变得模糊：

awk 'BEGIN{OFS="\t"}
     (NR==1){ print $1,$2,$3,$4,"Avg:"; next }
     { s=0; for(i=5;i<=NF;++i) s+=$i }
     { print $1,$2,$3,$4, (NF>4 ? s/(NF-4) : s) }' input.tsv

Answer 4

$ cat tst.awk
NR == 1 { avg = "Avg" }
NR > 1 {
    sum = cnt = 0
    for (i=5; i<=NF; i++) {
        sum += $i
        cnt++
    }
    avg = (cnt ? sum / cnt : 0)
}
{ print $1, $2, $3, $4, avg }

$ awk -f tst.awk file
ID source random text Avg
1 atttt eeeee test 0.606
2 afdg adfgrg tf 0.404

Answer 5

使用Perl单线版

> perl -lane '{ $s=0;foreach(@F[4..8]){$s+=$_} $F[4]=$s==0?"Avg":$s/5;print "$F[0]\t$F[1]\t$F[2]\t$F[3]\t$F[4]" } ' input.tsv 
ID      source  random  text    Avg
1       atttt   eeeee   test    0.606
2       afdg    adfgrg  tf      0.404
>

如何从第n列的csv文件计算行的平均值？

5 个答案: