Question

我正试图在ColdFusion中编写一个mixin。

ExampleMixin.cfc：

component {
    remote void function mixin(component, methodName) {
        var original = component[methodName];
        component[methodName] = function() {
            writeOutput("Mixin!");
            return original(arguments);
        };
    }
}

test.cfc：

component {
    new ExampleMixin().mixin(this, 'foo');

    remote string function foo() {
        return getOutput();
    }

    private string function getOutput() {
        return "Hello, World!";
    }
}

运行foo会产生错误Variable GETOUTPUT is undefined.。如果我将new ExampleMixin().mixin(this, 'foo');注释掉，它将运行正常。

当foo从包装程序运行时，它似乎不在正确的上下文中运行。在JavaScript中，可以编写foo.call(component, ...arguments)来纠正这一问题。在ColdFusion中有等同功能吗？

Answer 1

ColdFusion使用this和variables范围来存储函数参考。使用的引用取决于函数的调用方式。如果该函数从同级调用，使用variables引用。如果该函数在外部被调用，然后使用this引用。

以下代码使用基类提供mixin功能。的 $mixin函数采用一个组件实例并注入其所有函数。如果发生名称冲突，包装器将首先调用mixin，然后原始功能。我正在为原始和新生成函数名称 mixin函数，因此可以在两个范围内设置引用。

这已在Lucee 5.2.8.50上进行了测试。

mixable.cfc

component {
    function $mixin(obj) {
        var meta = getComponentMetadata(obj);

        for(var func in meta.functions) {
            if(structKeyExists(this, func.name)) {
                var orig = func.name & replace(createUUID(), '-', '', 'all');
                var injected = func.name & replace(createUUID(), '-', '', 'all');

                this[orig] = this[func.name];
                variables[orig] = this[func.name];

                this[injected] = obj[func.name];
                variables[injected] = obj[func.name];

                var wrapper = function() {
                    this[injected](argumentCollection=arguments);
                    return this[orig](argumentCollection=arguments);
                };
                this[func.name] = wrapper;
                variables[func.name] = wrapper;
            } else {
                this[func.name] = obj[func.name];
                return variables[func.name] = obj[func.name];
            }
        }
    }
}

test.cfc

component extends="mixable" {
    remote function foo() {
        writeOutput("foo(), calling bar()<br>");
        bar();
    }

    private function bar() {
        writeOutput("bar()<br>");
    }
}

mixin.cfc

component {
    function foo() {
        writeOutput("foo mixin, calling bar()<br>");
        bar();
    }

    function myfunc() {
        writeOutput("myfunc()<br>");
    }
}

index.cfm

<cfscript>
t = new test();
t.$mixin(new mixin());
t.myfunc();
t.foo();
</cfscript>

输出

myfunc()
foo mixin, calling bar()
bar()
foo(), calling bar()
bar()

用显式接收者调用ColdFusion方法

1 个答案: