Question

我想将徽章应用于侧边栏构面中的数字。

来自此：

为此：

我似乎找不到正确的文件进行编辑。我试图在第248行和第260行中编辑SidebarFacetsTransformer.java：

if (i < shownFacets - 1) {
    String displayedValue = value.getDisplayedValue();
    String filterQuery = value.getAsFilterQuery();
    String filterType = value.getFilterType();
    if (fqs.contains(getSearchService().toFilterQuery(context, field.getIndexFieldName(), value.getFilterType(), value.getAsFilterQuery()).getFilterQuery())) {
        filterValsList.addItem(Math.random() + "", "selected").addContent(displayedValue + " <span class=\"badge\">" + value.getCount() + "</span>");
        } else {
            String paramsQuery = retrieveParameters(request);

            filterValsList.addItem().addXref(
                    contextPath +
                            (dso == null ? "" : "/handle/" + dso.getHandle()) +
                            "/discover?" +
                            paramsQuery +
                            "filtertype=" + field.getIndexFieldName() +
                                                "&filter_relational_operator="+ filterType  +
                            "&filter=" + encodeForURL(filterQuery),
                            displayedValue + " <span class=\"badge\">" + value.getCount() + "</span>"
                    );
            }
    }

但是在重建DSpace之后，还显示了标签<span class="badge">：

那我应该编辑哪个文件以将徽章应用于边栏计数？我已经看到一个使用Mirage2作为基本主题并在边栏计数中应用徽章的存储库：University of Waikato Research Commons。

谢谢！

更新

应用@schweerelos答案中的代码后，除了具有文件的侧边栏之外，我得到了所需的结果。代替数字，它只是显示否。

Answer 1

在这一点上，我认为您只需要设置span.badge元素的样式即可。

在怀卡托大学研究公共中心，我看到以下CSS。

if (next_item exist AND next_item Y = current_item Y) then add the separation

Answer 2

对于Research Commons徽章，我们修改了dspace-xmlui-mirage2/src/main/webapp/xsl/preprocess.xsl并拦截了相应元素的呈现，即

<!-- render frequency counts in sidebar facets as badges -->
<xsl:template match="dri:list[@id='aspect.discovery.Navigation.list.discovery']/dri:list/dri:item/dri:xref">
  <xref>
    <xsl:call-template name="copy-attributes"/>
    <xsl:choose>
      <xsl:when test="contains(text(), ' (') and contains(substring-after(text(), ' ('), ')')">
        <xsl:variable name="title">
          <xsl:call-template name="substring-before-last">
            <xsl:with-param name="string" select="text()"/>
            <xsl:with-param name="separator"><xsl:text> (</xsl:text></xsl:with-param>
          </xsl:call-template>
        </xsl:variable>
        <xsl:variable name="count">
          <xsl:call-template name="remove-parens">
            <xsl:with-param name="string" select="normalize-space(substring-after(text(), $title))"/>
          </xsl:call-template>
        </xsl:variable>
        <xsl:value-of select="$title"/>
        <xsl:text> </xsl:text>
        <hi rend="badge">
          <xsl:value-of select="$count"/>
        </hi>
      </xsl:when>
      <xsl:otherwise>
        <xsl:apply-templates/>
      </xsl:otherwise>
    </xsl:choose>
  </xref>
</xsl:template>

还有一个用于当前选择的构面值的类似模板（IIRC不是链接）：

<!-- better highlight active co-author/subject etc in facet list, incl show count as badge -->
<xsl:template match="dri:list[@id='aspect.discovery.Navigation.list.discovery']/dri:list/dri:item[@rend='selected']">
  <item>
    <xsl:call-template name="copy-attributes"/>
    <xsl:attribute name="rend"><xsl:value-of select="@rend"/> disabled</xsl:attribute>
    <xsl:choose>
      <xsl:when test="contains(text(), ' (') and contains(substring-after(text(), ' ('), ')')">
        <xsl:variable name="title">
          <xsl:call-template name="substring-before-last">
            <xsl:with-param name="string" select="text()"/>
            <xsl:with-param name="separator"><xsl:text> (</xsl:text></xsl:with-param>
          </xsl:call-template>
        </xsl:variable>
        <xsl:variable name="count">
          <xsl:call-template name="remove-parens">
            <xsl:with-param name="string" select="normalize-space(substring-after(text(), $title))"/>
          </xsl:call-template>
        </xsl:variable>
       <xsl:value-of select="$title"/>
        <xsl:text> </xsl:text>
        <hi rend="badge">
         <xsl:value-of select="$count"/>
        </hi>
      </xsl:when>
      <xsl:otherwise>
        <xsl:apply-templates/>
      </xsl:otherwise>
    </xsl:choose>
  </item>
</xsl:template>

您将看到涉及一些XSL / T技巧，以应对facet值本身包含括号的情况，以及一些实用程序模板：

<xsl:template name="substring-before-last">
  <xsl:param name="string" select="''" />
  <xsl:param name="separator" select="''" />

  <xsl:if test="$string != '' and $separator != ''">
    <xsl:variable name="head" select="substring-before($string, $separator)" />
    <xsl:variable name="tail" select="substring-after($string, $separator)" />
    <xsl:value-of select="$head" />
    <xsl:if test="contains($tail, $separator)">
      <xsl:value-of select="$separator" />
      <xsl:call-template name="substring-before-last">
        <xsl:with-param name="string" select="$tail" />
        <xsl:with-param name="separator" select="$separator" />
      </xsl:call-template>
    </xsl:if>
  </xsl:if>
</xsl:template>

<xsl:template name="remove-parens">
  <xsl:param name="string" select="''" />
  <xsl:if test="starts-with($string, '(') and substring($string, string-length($string))=')'">
    <xsl:value-of select="substring($string, 2, string-length($string) - 2)"/>
  </xsl:if>
</xsl:template>

仅需补充，我们在修改主题XSL文件而不是修改Java代码方面具有本地首选项。您可以选择使用Java代码来执行此操作，但是您需要在DRI API中工作，例如，将.addHighlight("badge")与addXref一起进行Java方法调用（DRI hi转换为HTML span）。请参阅https://wiki.duraspace.org/display/DSDOC5x/DRI+Schema+Reference上的DRI文档（对于5.x，但对于6.x不变）。

Cocoon管道是Java生成的DRI（XML）-> preprocess.xsl和相关文件修改了DRI，输出仍然是DRI-> theme.xsl和相关文件将DRI转换为HTML。您试图在管道中“太早”创建HTML。您的原始HTML会被移到更远的地方，这就是为什么您在屏幕上看到标签的原因。

Answer 3

感谢@schweerelos的回答，我设法对她的代码进行了一些修改，以解决DSpace 6.x版中引入的具有文件方面中的问题。 / p>

我在"stromy sunny"中未注释此代码：

utils.xsl

，然后我修改了Andrea的代码，以显示具有原始捆绑包的记录的否或是：

<xsl:template match="//dri:list[@id='aspect.discovery.SidebarFacetsTransformer.list.has_content_in_original_bundle']/dri:item//text()">
    <xsl:choose>
        <xsl:when test="contains(.,'true')">
            <i18n:text>xmlui.ArtifactBrowser.AdvancedSearch.value_has_content_in_original_bundle_true</i18n:text>
        </xsl:when>
        <xsl:otherwise>
            <i18n:text>xmlui.ArtifactBrowser.AdvancedSearch.value_has_content_in_original_bundle_false</i18n:text>
        </xsl:otherwise>
    </xsl:choose>
    <xsl:text> </xsl:text>
    <xsl:value-of select="substring-after(.,' ')"/>
</xsl:template>

现在它显示了我想要的输出：

如何以Mirage2为主题在边栏计数中应用徽章

3 个答案: