xslt sum串联而不是添加

Question

所以我试图写一些xslt 1.0并试图求和一些值，但是sum（）函数将数字（或字符串）连接起来而不是求和。我将在这里粘贴我的xslt。

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"  xmlns:exsl="http://exslt.org/common">

    <xsl:template match="/">
        <table id="carttable" align="center">
            <xsl:for-each select="cart/item">
                <tr>
                    <td id="itemnum"><xsl:value-of select="itemnumber" /></td>
                    <td id="itemprice"><xsl:value-of select="itemprice" /></td>
                    <td><xsl:value-of select="quantity" /></td>
                    <td id="itemadd"><input type="button" id="removeBtn" value="Remove One From Cart">
                        <xsl:attribute name="onclick">
                            <xsl:text>removeFromCart(</xsl:text>
                            <xsl:value-of select="itemnumber" />
                            <xsl:text>)</xsl:text>
                        </xsl:attribute>
                    </input></td>
                </tr>
            </xsl:for-each>
            <xsl:variable name="itemTotals">
                <xsl:for-each select="cart/item">
                    <total>
                        <xsl:value-of select="itemprice * quantity" />
                    </total>
                </xsl:for-each>
            </xsl:variable>

            <tr>
                <td align="right">Total</td>
                <td>
                    <xsl:value-of select="sum(exsl:node-set($itemTotals))" />
                </td>
            </tr>
        </table>
    </xsl:template>

</xsl:stylesheet>

已经查看了关于stackoverflow的其他问题，但是找不到适合我确切情况的问题。希望在这里找到一些答案:) TIA 附言我正在使用xslt 1.0并在PHP中使用它

Answer 1

使用<xsl:value-of select="sum(exsl:node-set($itemTotals)/total)"/>计算结果树片段中total元素的总和，该结果树片段转换为具有包含total元素的根节点的节点集。