Question

使用Excel 2010，我试图使用来自几个不同表的部分数据在Sheet1上创建一个图表。在下面的示例中，我只是尝试从一个表中提取数据作为开始。我似乎很难在此表中设置此数据的范围。

我最终将遍历每个表中大约8个不同长度的数据列。 21张桌子。因此，将其自动化的任何帮助都将很棒

这是我到目前为止所拥有的...

Sub createChart()
    Dim rng As Range
    Dim chrt As Object

    'Table is named BMS_01_01_Module_01 and the column Name I want data from is Cell 1 Voltage
    Set chrt = Sheet1.Shapes.AddChart2
    chrt.ChartArea.SetSourceData Source:=activesheetlistobjects("BMS_01_01_Module_01").ListColumns("Cell 1 Voltage").Range
    chrt.ChartArea.ChartType = x1Line
End Sub

Answer 1

我认为上面的代码正在产生“ Object Required”错误。我建议将语句（ChartArea.SetSourceData）分为多个步骤，这将使您对代码和灵活性有更多的控制。

要引用表范围，只需创建一个ListObject变量和一个Range变量，其余内容将在下面通过示例进行解释。

Dim tbl As ListObject
Set tbl = ActiveSheet.ListObjects("BMS_01_01_Module_01")

使用这种方法，您将能够真正轻松地引用表的任何部分：

Dim rng As Range

'Reference the whole table, including headers:
Set rng = tbl.Range

'Reference just the table data (no headers):
Set rng = tbl.DataBodyRange

'Reference just the data in a single column:
Set rng = tbl.ListColumns("Cell 1 Voltage").DataBodyRange

'Reference the headers only
Set rng = tbl.HeaderRowRange

因此，您的代码应类似于以下内容：

chrt.ChartArea.SetSourceData Source:=tbl.ListColumns("Cell 1 Voltage").DataBodyRange

Answer 2

尝试一下。

Sub createChart()
    Dim rng As Range
    Dim obj As ChartObject
    Dim chrt As Chart
    Dim Lst As ListObject
    Dim cm  As ListColumn
    Dim Ws As Worksheet

    Set Ws = ActiveSheet
    Set Lst = Ws.ListObjects("BMS_01_01_Module_01")
    Set cm = Lst.ListColumns("Cell 1 Voltage")
    'Set cm = Lst.ListColumns(1)
    Set rng = cm.DataBodyRange

    'Table is named BMS_01_01_Module_01 and the column Name I want data from is Cell 1 Voltage
    Set obj = Sheet1.ChartObjects.Add(200, 200, 400, 400)
    With obj.Chart
    'chrt.ChartArea.SetSourceData Source:=ActiveSheet.ListObjects("BMS_01_01_Module_01").ListColumns("Cell 1 Voltage").Range
        .SetSourceData Source:=rng
        .ChartType = xlLine
    End With
End Sub

Answer 3

我最终对代码进行了一些更改。我只是希望有一种引用表的方法，而不必先激活表所在的表。注意：图表和表格不在同一张纸上。

这是最终在单个范围内起作用的原因：

Sub createChart()
Dim rng As Range
Dim cht As Object
Dim Ws As Worksheet

Set cht = Sheet1.Shapes.addChart

Worksheets("BMS_01_Module_01").Activate
Set Ws = ActiveSheet

Ws.ListObjects("BMS_01_Module_01").ListColumns("Cell 1 Voltage").Range.Select
cht.Chart.SetSourceData Source:=Selection
cht.Chart.ChartType = xlLine


End Sub

如何设置表数据范围以用于图表

3 个答案: