Question

我有以下数据集：

* Example generated by -dataex-. To install: ssc install dataex
clear
input float(MA_234_AAF_US AL_87665_ACH_USA TX_3_GH_US LA_689_KLO_US KY_3435_Z_USA)
  9.96567 10.559998 12.935112 13.142867   9.35608
 9.758375     9.856 10.002945  8.090142 10.313352
11.594983  9.274136 12.486753  6.661111 10.529528
10.354564  9.893115 10.625778 13.265523  7.405652
  12.7978  10.76272 11.527348 10.112844  11.64973
 10.63846 11.040354  8.569465  8.781206 11.448466
 9.254233 13.808356 10.817062  9.545164  8.759109
  11.8417  10.15155  12.72436 11.102546 11.506034
 9.864883  9.864952  14.45111  10.12562  9.753519
 9.965327 11.517155  9.910269  8.988406 11.359774
end

我想像这样更改变量名称中文本的顺序：

US_MA_AAF_234   USA_AL_ACH_87665   US_TX_GH_3   US_LA_KLO_689   USA_KY_Z_3435

我已经尝试过此问题的答案中提供的代码：

Remove middle character from variable names

但是，我无法使其正常工作。

Answer 1

另一个问题的所有三种方法都可以起作用。

这里唯一具有挑战性的一点是变量名称的不同部分有不同的长度。

这样，最好的方法可能是使用内置命令rename：

clear

input float(MA_234_AAF_US AL_87665_ACH_USA TX_3_GH_US LA_689_KLO_US KY_3435_Z_USA)
  9.96567 10.559998 12.935112 13.142867   9.35608
end

rename (*_#_*_*) (*[4]_*[1]_*[3]_#[2])

list, abbreviate(20) noobs

  +-------------------------------------------------------------------------------+
  | US_MA_AAF_234   USA_AL_ACH_87665   US_TX_GH_3   US_LA_KLO_689   USA_KY_Z_3435 |
  |-------------------------------------------------------------------------------|
  |       9.96567              10.56     12.93511        13.14287         9.35608 |
  +-------------------------------------------------------------------------------+

您需要仔细研究help rename group中指定符的使用。

Answer 2

这是另一种方法。

不如在一行中使用rename，这很好地解决了这个目的。仔细检查将显示与该方法必要的对应。它取决于用下划线分隔的元素的名称，然后将其删除并重新插入。

clear
input float(MA_234_AAF_US AL_87665_ACH_USA TX_3_GH_US LA_689_KLO_US KY_3435_Z_USA)
  9.96567 10.559998 12.935112 13.142867   9.35608
end

foreach name of var * { 
    local new = subinstr("`name'", "_", " ", .) 
    tokenize `new' 
    rename `name' `4'_`1'_`3'_`2' 
}

describe, fullnames 

Contains data
  obs:             1                          
 vars:             5                          
 size:            20                          
-------------------------------------------------------------------------------------------
              storage   display    value
variable name   type    format     label      variable label
-------------------------------------------------------------------------------------------
US_MA_AAF_234   float   %9.0g                 
USA_AL_ACH_87665
                float   %9.0g                 
US_TX_GH_3      float   %9.0g                 
US_LA_KLO_689   float   %9.0g                 
USA_KY_Z_3435   float   %9.0g                 
-------------------------------------------------------------------------------------------

编辑：

正如@PearlySpencer指出的那样，循环中的语句

local new = subinstr("`name'", "_", " ", .) 
tokenize `new' 
rename `name' `4'_`1'_`3'_`2'

可以替换为

tokenize `name', parse(_)
rename `name' `7'_`1'_`5'_`3'

区别在于，下划线将放置在本地宏2，4，6中。

更改变量名称中文本的顺序

2 个答案: