Question

考虑：

#include "share/atspre_staload.hats"

%{^
#include <sys/types.h>
#include <sys/stat.h>
#include <unistd.h>
%}
typedef statbuf = $extype "struct stat"
extern fun cstat: (string, &statbuf? >> statbuf) -> int = "mac#stat"
extern fun S_ISDIR: int -> bool = "mac#"
extern fun stat_mode: statbuf -> int = "mac#stat_mode"
%{
#define stat_mode(x) x.st_mode
%}

datavtype statbuf_vt = STAT of statbuf

fun stat(path: string): Option_vt(statbuf_vt) =
    let
        val buf = STAT(_)
        val STAT(hole) = buf
        val res = cstat(path, hole)
        prval _ = fold@(buf)
    in
        if res = 0 then Some_vt(buf)
        else
            let
                val ~STAT(_) = buf
            in
                None_vt()
            end
    end

implement main0() =
    let
        val path = "/etc/passwd"
        val- ~Some_vt(~STAT(buf)) = stat(path)
    in
        println!(~S_ISDIR(stat_mode(buf)))
    end

buf的生存期最后是什么？似乎不需要释放它-valgrind看到3个分配和3个释放，并且没有问题。但是buf是不是由那个STAT线性对象管理的内存的一部分？

Answer 1

注意'buf'是一个平面结构。释放任何与〜STAT（buf）模式匹配的值；在释放它之前，该值中的某些内容被复制到位于堆栈中的“ buf”中。当调用“ main0”的帧展开时，“ buf”的生存时间结束。所提供的代码中没有泄漏。

从自由线性对象接收到的结构的寿命是多少？

1 个答案: