Question

我创建一个新模块并插入以下代码：

Sub test()
   Set wsData = ThisWorkbook.Worksheets("Data")
   sCount = wsData.Columns(14).SpecialCells(xlCellTypeBlanks).Count
   msgbox sCount
End Sub

在工作表“数据”中，我有以下代码：

Private Sub Worksheet_SelectionChange(ByVal Target As Range)
    If Selection.CountLarge = 1 Then
        If Not Intersect(Target, Range("K:M")) Is Nothing And Target.Value <> "" Then
            'code
        End if
    End if
End Sub

运行test()子项时，在If Not Intersect(Target, Range("K:M")) Is Nothing上收到类型不匹配错误，作为目标错误类型。

为什么会这样？

为什么测试触发变更事件？如果手动过滤数据表的第14列以仅保留空白单元格，我不会出现相同的错误！

Answer 1

类型不匹配的问题是Target.Cells不止一个单元格。因此，Target.Value <> ""引发类型不匹配，因为无法将多个像元与""进行比较。请参阅MsgbBox以及单元格的数量：

Private Sub Worksheet_SelectionChange(ByVal Target As Range)
    If Selection.CountLarge = 1 Then
        If Target.Cells.CountLarge > 1 Then MsgBox Target.Cells.CountLarge
        If Not Intersect(Target, Range("K:M")) Is Nothing And Target.Value <> "" Then
            'code
        End If
    End If
End Sub

根据业务逻辑，可能有几种解决方案。

最简单的是写 If Target.Cells.CountLarge > 1 Then Exit Sub事件中的_SelectionChange。
另一种方法是禁用

sCount = wsData.Columns(14).SpecialCells(xlCellTypeBlanks).Count像这样：

Sub TestMe()
   Set wsData = ThisWorkbook.Worksheets("Data")
   Application.EnableEvents = False
   sCount = wsData.Columns(14).SpecialCells(xlCellTypeBlanks).Count
   Application.EnableEvents = True
   msgbox sCount
End Sub

Answer 2

我几乎以重复题的形式结束了这个问题。

我将按照相反的顺序回答您的两个问题，以便您更好地理解它。

为什么测试触发变更事件？

我已经在SpecialCells causing SheetSelectionChange event in Excel 2010

中对此进行了解释

当我运行test（）子对象时，如果If Not Intersect（Target，Range（“ K：M”））Nothing，我收到类型不匹配错误，因为Target错误类型。为什么会这样？

当过程Test触发Worksheet_SelectionChange事件时，您的代码将在线上失败

If Not Intersect(Target, Range("K:M")) Is Nothing And Target.Value <> "" Then

这是因为Target.Value <> ""是元凶，因为SpecialCells(xlCellTypeBlanks).Count可能返回多个单元格。

如果您将上述行分成两行，则不会出现错误

Private Sub Worksheet_SelectionChange(ByVal Target As Range)
    If Target.Cells.CountLarge > 1 Then Exit Sub
    If Not Intersect(Target, Range("K:M")) Is Nothing Then
        If Target.Value <> "" Then
             'code
        End If
    End If
End Sub

为什么这里会出现类型不匹配错误？

2 个答案: