好的，我已经尝试过三次重写该Bison语法，并不断遇到移位/减少和减少/减少冲突。我尝试解析的语法如下。 {...}中的项目用于一个或另一个。在[...]中的项目是可选的。
CONSTANT constant-name constant-class
constant-class = { EQUALS expression numeric-options }
{ EQUALS STRING string string-options }
numeric-options = [ PREFIX prefix-string ]
[ TAG tag-string ]
[ COUNTER #local-name ]
[ TYPENAME type-name ] ;
string-options = [ PREFIX prefix-string ]
[ TAG tag-string ] ;
CONSTANT (constant-name,...) EQUALS expression
[ INCREMENT expression ]
[ PREFIX prefix-string ]
[ TAG tag-string ]
[ COUNTER #local-name ]
[ TYPENAME type-name ];
CONSTANT constant-name EQUALS expression,
.
.
.
;
CONSTANT (constant-name,...) EQUALS expression,
.
.
.
;
我在使最后三个全部工作时遇到问题。我可以让他们任何一个工作，但不能让他们全部四个工作。我现在有一个转移/减少和一个减少/减少冲突。我的语法如下：
constant
: SDL_K_CONSTANT constant_style ';'
;
constant_style
: constant_name constant_class
| constant_list
| constant_set
;
constant_name
: sdl_name
;
constant_class
: SDL_K_EQUALS sdl_decimal
| SDL_K_EQUALS SDL_K_STRING sdl_string
;
constant_names
: constant_name
| constant_names ',' constant_name
| '(' constant_names ')'
;
names_equal
: constant_names SDL_K_EQUALS sdl_decimal
;
constant_list
: names_equal
;
constant_set
: names_equal
| constant_set ',' names_equal
;
我认为这些名称是自我记录的（至少您应该能够理解这些类型）。任何帮助将不胜感激。我感觉自己要么简化得太多，要么不够。
注意：我弄清楚了如何编辑帖子并删除了选项，并将SDL_K_COMMA和SDL_K_SEMI分别更改为“，”和“;”。
谢谢。
以下是一些应解析的示例：
CONSTANT block_node_size EQUALS 24;
CONSTANT Strcon EQUALS STRING "This is a string constant" PREFIX Jg$
#block_size = 24;
CONSTANT block_node_size EQUALS #block_size;
CONSTANT
xyz EQUALS 10,
alpha EQUALS 0,
noname EQUALS 63;
CONSTANT
(zyx, nameless) EQUALS 10,
(beta) EQUALS 1,
gamma EQUALS 42;
CONSTANT (
bits,
bytes,
words,
longs,
quads,
octas
) EQUALS 0 INCREMENT 1 PREFIX ctx$;
CONSTANT
(bad_block,bad_data,,,,
overlay,rewrite) EQUALS 0 INCREMENT 4;
CONSTANT (pli,c,bliss,macro)
EQUALS 4 INCREMENT 4 PREFIX lang$
COUNTER #lang;
CONSTANT (basic,pascal,fortran)
EQUALS #lang + 4 INCREMENT 4 PREFIX lang$;
我希望这会有所帮助。
顺便说一句：这是EBNF（某种）：
/*
* Define the CONSTANT construct (Left out Expression).
*/
Str ::= "\"" Printable* "\""
Name ::= "$" | "_" | [A-Za-z] ("$" | "_" | [A-Z0-9a-z])*
Names ::= Name | ("(" Name ("," Name )* ")")
Constant_class ::= "EQUALS" (Expression Numeric_options | "STRING" Str
String_options)
String_options ::= Prefix? Tag?
Numeric_options ::= String_options Counter? Typename? Radix?
Increment_options ::= Increment? Numeric_options
Constant_list ::= Names "EQUALS" Expression Increment_options
Constant_set ::= Names Equals Expression
("," Names "EQUALS" Expression)*
Constant ::= "CONSTANT" (Name Constant_class | Constant_list |
Constant_set) ";"?
Prefix ::= "PREFIX" Str
Tag ::= "TAG" Str
Radix ::= "RADIX" ("DEC" | "OCT" | "HEX")
Counter ::= "COUNTER" Variable
Increment ::= "INCREMENT" Expression
Typename ::= "TYPENAME" Name
我想就是这样。
答案 0 :(得分：1)
对于我来说，要理解您的实际意图有点困难，因此我做出了一些假设并在下面提供了一些选择。我希望它接近。
基本问题是语法规范中的歧义。其中一个可能只是一个错误：根据您的模板，EQUAL的左侧似乎是单个name或以逗号分隔的name列表用括号括起来。但是，您的语法允许以逗号分隔的name列表，并且列表中的第一个（或唯一一个）项可能是带括号的名称列表：
constant_names
: constant_name
| constant_names ',' constant_name
| '(' constant_names ')
这将匹配a，a, b，(a, b)，(a, b), c和(a, b), c, d。但是我认为只有第一个和第三个确实是想要的。
无论如何，您都有两个作品：
constant_style
: constant_name constant_class
| constant_list
对于第一个，我们有：
constant_class
: SDL_K_EQUALS sdl_decimal
第二次，我们有：
constant_list: names_equal
names_equal
: constant_names SDL_K_EQUALS sdl_decimal
由于constant_name可以匹配单个name，因此有两种不同的匹配answer = 42的方式，这不可避免地导致解析冲突。
但是answer = 42还有另外一种可能的解析方式：
constant_set
: names_equal
因此，让我们从简化所有内容开始，然后我们也许可以回到原来的目标（可能是）。这个想法是要把语法上相似的所有内容都考虑在内：
constant-stmt : "CONSTANT" clause-list ';'
clause-list : clause | clause-list ',' clause
clause : left-hand-side "EQUALS" right-hand-side
left-hand-side : name | '(' name-list ')'
name-list : name | name-list ',' name
right-hand-side: expression /* See below */
我希望这一切都足够简单易懂。
但是从原始文档中我们可以看到（至少在某些情况下），right-hand-side的选项比上面的代码段多。仅将其他语法添加到right-hand-side中将是微不足道的。但是，似乎意图是这些额外选项仅在存在单个子句的情况下可用。在这种情况下，我们可以这样做：
constant-stmt : "CONSTANT" constant-body ';'
constant-body : complex-clause | clause-list
clause-list : clause | clause-list ',' clause
clause : left-hand-side "EQUALS" right-hand-side
right-hand-side: expression
complex-clause : left-hand-side "EQUALS" complex-rhs
complex-rhs : expression numeric-options
| "STRING" string-literal string-options
但不幸的是，这又变得模棱两可，因为numeric-options可能为空，因此expression将同时匹配right-hand-side和complex-right-hand-side。
在实践中，这种模糊性并不重要。声明name EQUALS expression作为CONSTANT声明中的唯一声明或此类声明的列表之一在语义上没有区别。因此，一种可能的方法是，仅通过将%expect 1放入文件中而忽略由此产生的减少/减少冲突。但这确实不是很愉快。因此，我们将尝试消除该问题。
一种方法是坚持要求第一个complex-rhs至少有一个numeric-option。但这真是令人讨厌。首先，我们必须创建另一种子句类型-first-complex-clause或类似的子句类型-其次，我们必须写出至少存在一个选项的要求。
作为一种更简单的选择，我们可以仅要求clause-list至少具有两个clause，而不是只有一个。由于每个clause也可以匹配complex-clause，因此对clause-list的限制将不会拒绝任何有效的clause。这样就给了我们很小的变化：
constant-body : complex-clause | clause-list
clause-list : clause ',' clause | clause-list ',' clause
通过对预期语法的更精确描述（尽管仍然缺少一些细节），我修改了上面的语法以尝试解析完整的语言。基本原理保持不变：定义由单个complex-clause（包括简单子句大小写）或至少两个简单clause组成的列表组成。唯一的区别是两种子句类型的定义方式。
我还修复了名称列表的产生方式，以便可以省略单个名称（例如(bad_block,bad_data,,,,overlay,rewrite)）。如指南中所述，列表必须至少包含一个名称，这会使语法稍微复杂一些。
我添加了指南中的选项（但未添加EBNF中的其他选项）。我没有尝试处理省略的分号，尽管有一个没有尾随分号的声明示例，但指南中似乎不允许这样做。 （这可能是一个错字。）据我所知，我添加了expression的定义。
我还添加了本地名称赋值语句，因为它位于测试文件中并且很容易。
这是语法：
definition : %empty
| definition constant-defn
| definition local-assign
local-assign : LOCAL_NAME '=' expression ';'
constant-defn : "CONSTANT" constant-body ';'
constant-body : complex-clause | clause-list
clause-list : clause ',' clause | clause-list ',' clause
clause : name "EQUALS" expression
| name-list "EQUALS" expression
complex-clause : name "EQUALS" expression numeric-options
| name-list "EQUALS" expression list-options
| name "EQUALS" "STRING" string-literal string-options
| name-list "EQUALS" "STRING" string-literal string-options
name-list : '(' names ')'
names : optional-commas name | names ',' name | names ','
optional-commas : %empty | optional-commas ','
string-options : prefix-option tag-option
numeric-options : string-options counter-option typename-option
list-options : increment-option numeric-options
increment-option: %empty | "INCREMENT" expression
prefix-option : %empty | "PREFIX" prefix-name
tag-option : %empty | "TAG" tag-name
counter-option : %empty | "COUNTER" LOCAL_NAME
typename-option : %empty | "TYPENAME" name
expression : '-' expression %prec UNOP
| expression '*' expression
| expression '/' expression
| expression '+' expression
| expression '-' expression
| expression '@' expression
| expression '&' expression
| expression '!' expression
| '(' expression ')'
| INTEGER
| IDENT
| LOCAL_NAME
name : IDENT | QUOTED_IDENT
prefix-name : IDENT | QUOTED_NULL | QUOTED_IDENT
tag-name : IDENT | QUOTED_NULL | QUOTED_IDENT | QUOTED_TAG
string-literal : QUOTED_NULL | QUOTED_IDENT | QUOTED_TAG | QUOTED_STRING
您将看到我添加了对各种类型的带引号的字符串的区分，以便可以处理（大多数）可能出现带引号的字符串的不同上下文。如本指南所述，我没有将最多4个字符的带引号的字符串用作整数常量，因为我没有及时注意到它，也因为我无法通过简短的阅读来弄清楚是否目的是允许表达式中的常量必须使用名称加引号（因为名称与关键字冲突）；在这种情况下，在我看来，报价名称中含四个或更少字符的模棱两可。
如果尚不清楚区分的工作原理（可能不是），请参阅随附的flex定义：
id [[:alpha:]$_][[:alnum:]$_]*
%%
[[:space:]]+ ;
CONSTANT { return K_CONSTANT; }
COUNTER { return K_COUNTER; }
EQUALS { return K_EQUALS; }
INCREMENT { return K_INCREMENT; }
PREFIX { return K_PREFIX; }
STRING { return K_STRING; }
TAG { return K_TAG; }
TYPENAME { return K_TYPENAME; }
[#]{id} { yylval.str = strndup(yytext, yyleng); return LOCAL_NAME; }
{id} { yylval.str = strndup(yytext, yyleng); return IDENT; }
["]{id}["] { yylval.str = strndup(yytext+1, yyleng-2); return QUOTED_IDENT; }
["]["] { yylval.str = strndup(yytext+1, yyleng-2); return QUOTED_NULL; }
["][[:alnum:]$_]+["] { yylval.str = strndup(yytext+1, yyleng-2); return QUOTED_TAG; }
["][[:print:]]+["] { yylval.str = strndup(yytext+1, yyleng-2); return QUOTED_STRING; }
[[:digit:]]+ { yylval.dec = strtoul(yytext, 0, 0); return INTEGER; }
. { return *yytext; }
通过在OP的末尾运行定义来进行测试（尽管我在第二行中添加了尾随;），因此我做的测试还不够充分。我实际上并没有检查解析树是否正确，但是肯定可以通过解析器。