Question

我对使用Lisp还是很陌生，我正在尝试构建一种简单但至少有效的插入排序-我想将元素切换到适当的位置，但仍然可以附加到我的容器中然后。我采用了旧的C ++实现：

template<typename Iter>
void insertionSort(Iter begin, Iter end){
    for (auto i = begin; i != end; ++i){
        for (auto j = i; j != begin && *(std::prev(j)) > *(j); j--){
            std::iter_swap(j, std::prev(j));
        }
    }
}

并创建以下代码（考虑到aref和rotatef具有相当的复杂性），但是它似乎对输入没有任何影响（UPD：现在，它只是工作不正常），我的解决方案可能有什么问题？我出于测试目的返回，是否应该创建一个宏以避免通过值传递？

(defparameter testa (make-array 4 :initial-contents '(2 3 1 5)))
(defun insertion-sort (vect)
    (loop for i from 0 to (1- (length vect)) do
        (loop for j from i downto 0
            until (or (= (1- j) -1) (> (aref vect (1- j)) (aref vect j)))
            do (rotatef (aref vect i) (aref vect (1- j))))
    )
    vect
)
(format t "~a~%" (insertion-sort testa))

UPD：根据@jkiiski和@RainerJoswig的评论更新了代码，输出仍然错误。

Answer 1

程序中存在几个问题。

首先，由于该行，排序不起作用：

do (rotatef (aref vect i) (aref vect (1- j))))

应为：

do (rotatef (aref vect j) (aref vect (1- j))))

也就是说，您已经写了变量i而不是j

如果进行此更正，您会发现订单在减少（我假设您要增加订单）。这取决于使用until而不是while。

最后，有冗余代码。下面是一个更简单有效的版本：

(defparameter testa (make-array 4 :initial-contents '(2 3 1 5)))
(defun insertion-sort (vect)
   (loop for i from 1 below (length vect) 
     do (loop for j from i above 0
          while (> (aref vect (1- j)) (aref vect j))
          do (rotatef (aref vect j) (aref vect (1- j)))))
   vect)
(format t "~a~%" (insertion-sort testa))

这与Insertion sort的维基百科页面中的伪代码并行。

如果您想对排序谓词进行参数化，以及在函数中添加可选的基于关键字的“ key”参数，则可以采用以下解决方案：

(defun insertion-sort (vect predicate &key (key #'identity))
  (loop for i from 1 below (length vect) 
        do (loop for j from i above 0
                 while (funcall predicate 
                                (funcall key (aref vect (1- j)))
                                (funcall key (aref vect j)))
                 do (rotatef (aref vect j) (aref vect (1- j)))))
         vect)

CL-USER> (insertion-sort testa #'>)
#(1 2 3 5)
CL-USER> (insertion-sort testa #'<)
#(5 3 2 1)

CL-USER> (defparameter testa (make-array 4 :initial-contents '((c 3) (d 2) (b 1) (a 4))))
TESTA
CL-USER> (insertion-sort testa #'string> :key #'car)
#((A 4) (B 1) (C 3) (D 2))

插入到位LISP

1 个答案: