我想知道是否可以在另一个C文件中访问诸如.directive之类的汇编指令或诸如%macro my_macro之类的宏
文件：macroasm.S
%macro my_macro 1
mov rsp, 1
%endmacro
是否有任何可能的方法来调用和执行C文件中的my_macro宏，并使用nasm和gcc对其进行编译？
答案 0 :(得分：2)
与运行时函数调用不同，宏是编译时替换。 asm和C是不同的语言，因此，这个问题唯一有意义的方法是可以在inline-asm中使用的asm宏。
gcc的asm输出必须由GAS或理解GAS指令的兼容汇编程序进行汇编。 （https://sourceware.org/binutils/docs/as/）。内联asm允许您将手写内容直接发送到该asm编译器输出中，成为编译器馈入汇编器的一个完整汇编器源文件的一部分。
使用%macro这样的NASM语法不能在GNU C内联汇编中使用，因为可以汇编常规gcc输出的汇编器将无法理解NASM指令。
但是您可以根据需要使用GAS .macro。（https://sourceware.org/binutils/docs/as/Macro.html）。我不推荐它。 GAS宏不是很好用。与NASM相比，语法有点笨拙。但是，既然您问过了，这就是您的做法。
asm(".include \"macro-defs.S\"");将允许您稍后在该编译单元中使用内联asm中的那些宏。 （假设gcc不会在输出的asm中重新排序。）
但是，您当然必须知道宏的作用，以便能够为inline-asm语句编写正确的约束，因此它实际上并没有太多用处。
macro-defs.S （GAS语法，而不是NASM）。也许我应该将其命名为.s，因为我们只能使用asm指令来.include，而不能使用C预处理器来#include。 （这对于C语言来说是有问题的：您不能#include在 中用双引号引起来的字符串。）因此，无论如何，我们在这里不能使用CPP宏，只能使用asm宏。 / p>
#.altmacro # needed for some things, makes other things harder
# https://stackoverflow.com/questions/19776992/gas-altmacro-macro-with-a-percent-sign-in-a-default-parameter-fails-with-oper
# clobbers RDX and RAX
.macro fenced_rdtsc64 dst
lfence # make sure earlier stuff is done
rdtsc
lfence # don't allow later stuff to start before time is read
shl $32, %rdx # allow OoO exec of these with the timed interval
lea (%rax, %rdx), \dst
.endm
# repeats pause n times. Probably not useful, just a silly example.
# for exponential backoff in a spinloop, you want a *runtime* repeat count.
.macro pause_n count
pause # the machine instruction, not a macro
.if \count-1
pause_n "(\count-1)" # recursion is GAS equivalent of NASM %rep
.endif
.endm
这些宏可从foo.S 使用：
.include "macro-defs.S"
# inefficient: the subtraction really only needs to use the low 32 bits of the count
# so using a macro that merges the high half is a waste
.globl foo
foo:
fenced_rdtsc64 %rcx # start
pause_n 4
fenced_rdtsc64 %rax # end
sub %rcx, %rax
ret
并通过main.c 中的内联汇编（通常也称为foo()）。
#include <stdio.h>
asm(".include \"macro-defs.S\"");
long long foo(void);
int main(void) {
long long start, end;
asm volatile("fenced_rdtsc64 %[dst]"
: [dst]"=r" (start)
:
: "rax", "rdx" // forces it to avoid these as output regs, unfortunately
);
printf("foo rdtsc ticks: call1 %lld call2 %lld\n", foo(), foo());
asm volatile("fenced_rdtsc64 %[dst]"
: [dst]"=r" (end)
:
: "rax", "rdx");
printf("printf rdtsc ticks: %lld\n", end-start);
}
使用gcc -O3 -Wall main.c foo.S进行编译（我使用gcc7.3，默认为-fpie）。
使用for i in {1..50};do ./a.out;done运行它可以得到这样的输出（在我的i7-6700k上，其中pause需要约100个核心时钟周期，并且在负载时硬件P状态会迅速提高速度）：
... (variable number of lines before the frequency shift)
foo rdtsc ticks: call1 3006 call2 3014
printf rdtsc ticks: 727810
foo rdtsc ticks: call1 3006 call2 3022
printf rdtsc ticks: 707376
foo rdtsc ticks: call1 3006 call2 3017
printf rdtsc ticks: 746375
foo rdtsc ticks: call1 3006 call2 3029
printf rdtsc ticks: 684239
foo rdtsc ticks: call1 3006 call2 3010
printf rdtsc ticks: 652724
foo rdtsc ticks: call1 616 call2 620 # gcc chose to evalute from right to left
printf rdtsc ticks: 133282
foo rdtsc ticks: call1 618 call2 618 # so call1 is with it hot in uop cache
printf rdtsc ticks: 133984
foo rdtsc ticks: call1 616 call2 618
printf rdtsc ticks: 133284
foo rdtsc ticks: call1 614 call2 618
foo的汇编，如果我们用objdump -drwC -Mintel a.out进行反汇编以查看宏如何展开：
# I maybe should have used AT&T syntax disassembly like the source
# You can do that if you want, on your own desktop, leaving out -Mintel
00000000000006ba <foo>:
6ba: 0f ae e8 lfence
6bd: 0f 31 rdtsc
6bf: 0f ae e8 lfence
6c2: 48 c1 e2 20 shl rdx,0x20
6c6: 48 8d 0c 10 lea rcx,[rax+rdx*1] # macro expanded with RCX
6ca: f3 90 pause # pause_n 4 expanded to 4 pause instructions
6cc: f3 90 pause
6ce: f3 90 pause
6d0: f3 90 pause
6d2: 0f ae e8 lfence
6d5: 0f 31 rdtsc
6d7: 0f ae e8 lfence
6da: 48 c1 e2 20 shl rdx,0x20
6de: 48 8d 04 10 lea rax,[rax+rdx*1] # macro expanded with RAX
6e2: 48 29 c8 sub rax,rcx
6e5: c3 ret
由编译器生成的asm（包括我们的嵌入式asm）为：
0000000000000540 <main>:
540: 55 push rbp
541: 53 push rbx
542: 48 83 ec 08 sub rsp,0x8
546: 0f ae e8 lfence # first inline asm
549: 0f 31 rdtsc
54b: 0f ae e8 lfence
54e: 48 c1 e2 20 shl rdx,0x20
552: 48 8d 1c 10 lea rbx,[rax+rdx*1] # The compiler picked RBX for the output operand
# and substituted fenced_rdtsc64 %rbx into the asm template
556: e8 5f 01 00 00 call 6ba <foo>
55b: 48 89 c5 mov rbp,rax # save the return value, not a macro so it couldn't ask for a more convenient register
55e: e8 57 01 00 00 call 6ba <foo>
563: 48 89 ea mov rdx,rbp
566: 48 8d 3d 0b 02 00 00 lea rdi,[rip+0x20b] # 778 <_IO_stdin_used+0x8> # the string literal
56d: 48 89 c6 mov rsi,rax
570: 31 c0 xor eax,eax
572: e8 b9 ff ff ff call 530 <printf@plt>
577: 0f ae e8 lfence # 2nd inline asm
57a: 0f 31 rdtsc
57c: 0f ae e8 lfence
57f: 48 c1 e2 20 shl rdx,0x20
583: 48 8d 34 10 lea rsi,[rax+rdx*1] # compiler picked RSI this time
587: 48 8d 3d 1a 02 00 00 lea rdi,[rip+0x21a] # 7a8 <_IO_stdin_used+0x38>
58e: 48 29 de sub rsi,rbx # where it wanted it as the 2nd arg to printf(.., end-start)
591: 31 c0 xor eax,eax
593: e8 98 ff ff ff call 530 <printf@plt>
598: 48 83 c4 08 add rsp,0x8
59c: 31 c0 xor eax,eax
59e: 5b pop rbx
59f: 5d pop rbp
5a0: c3 ret