Question

我知道当我使用它时会创建一组生成的子代。我创建了一个名为grid的模块，如下所示：

module grid(x0,y0,dx,dy,nx,ny) {
    for (x=[0:1:nx-1]) {
        for(y=[0:1:ny-1]) {
            i=x*nx+y;
            echo(i);
            translate([x0+x*dx,y0+y*dy,0]) children(i);
        }
    }
}

按以下方式使用时：

grid(-50,-50,25,25,5,5) {
    cube([10,10,10],center=true);
    cube([10,10,10],center=true);
    cube([10,10,10],center=true);    
    cube([10,10,10],center=true);
    //.. continue to create 25 cubes total    
}

将多维数据集排列在一个漂亮的网格中。

但是我最初的希望和意图是像这样使用它：

grid(-50,-50,25,25,5,5) {
    for(i=[0:1:24]) {
        cube([10,10,10],center=true);
    } 
}

哪个失败，因为for运算符返回一个组而不是一组子代。

为什么for要添加一个组？（也导致需要 intersection_for ）

并且我的Grid运算符模块有办法处理该组的子级吗？

Answer 1

我个人希望for（）中元素的分组/联合在某个时候成为可选。

如果您不介意从源代码编译OpenSCAD，今天就可以尝试。存在一个持续存在的问题Lazy union (aka. no implicit union) 还有一个补丁Make for() UNION optional

Answer 2

我想你想要这个：

for(x=[...], y=[...]) {
    translate([x,y,0]) children();
}

请注意，您只需要一个for语句即可遍历x和y值。

我从您的评论中了解到，您希望网格节点中的对象是参数化的，而参数取决于索引。原始问题未提及此要求。我猜在这种情况下，解决方案取决于您的问题背景。我看到的两种可能性是：

module grid_of_parametric_modules(other_param)
{
    for(i=[0:24])
    {
        x=_x(i);
        y=_y(i);
        translate([x,y,0]) parametric_module(i_param(i), other_param);
    }
}

但是，这可能不合适，尤其是如果将来您要向网格中添加新形状时。然后，您可能可以这样做：

function grid_pos(i) = [_x(i), _y(i), 0];

....

for(i=[0:24])
    translate(grid_pos(i)) parametric_module(i);

Answer 3

仅更新了我对OpenSCAD的了解，还有一个更好的解决方案：

module nice_cube()
{
    translate([0,0,$height/2]) cube([9,9,$height], center = true);
}

module nice_cylinder()
{
    translate([0,0,$height/2]) cylinder(d=10,h=$height, center = true);
}

module nice_text()
{
    linear_extrude(height=$height, center=false) text(str($height), size=5);
}

module nice_grid()
{
    for(i=[0:9], j=[0:9])
    {
        $height=(i+1)*(j+1);
        x=10*i;
        y=10*j;
        translate([x,y,0]) children();
        /* let($height=(i+1)*(j+1)) {children();} */
    }
}

nice_grid() nice_cube();
translate([0,-110,0]) nice_grid() nice_text();
translate([-110,0,0]) nice_grid() nice_cylinder();

这里的技巧是通过特殊变量（以$开头）控制模块产生的形状，这些变量可以像示例中一样使用，使用let（）的注释行需要openscad的开发版本。

openscad深入研究由

3 个答案: