Question

Delphi Tokyo-我想通过Windows消息在表单之间发送记录结构。具体来说，我有一个“显示运行状态”窗口。当我的应用程序中其他地方发生行为时，我需要发送“更新状态窗口”类型的消息。我发现了一个示例，该示例通过Windows消息传递记录（但仅在同一过程中），但是使它无法正常工作。具体来说，在接收方，我在编译Windows消息处理程序代码时遇到麻烦。我有一个“不兼容的类型”错误，但我不知道如何打字以使其正常工作。这是适用的代码段。

在globals.pas单元中，所有表单都可以访问。

// Define my message
  const WM_BATCHDISPLAY_MESSAGE = WM_USER + $0001;
...
// Define the record which is basically the message payload
type
 TWMUCommand = record
    Min: Integer;
    Max: Integer;
    Avg: Integer;
    bOverBudget: Boolean;
    Param1: Integer;
    Param2: String;
  end;

...
// define a global variable
PWMUCommand : ^TWMUCommand;

现在用于发送消息。目前，这只是一个按钮，可以进行测试。

procedure TMainForm.BitBtn1Click(Sender: TObject);
var
  msg_prm: ^TWMUCommand;
begin
  New(msg_prm);
  msg_prm.Min := 5;
  msg_prm.Max := 10;
  msg_prm.Avg := 7;
  msg_prm.bOverBudget := True;
  msg_prm.Param1 := 0;
  msg_prm.Param2 := 'some string';
  PostMessage(Handle, WM_BATCHDISPLAY_MESSAGE, 0, Integer(msg_prm));
end;

在接收表单上，也就是我的状态表单...声明我的消息侦听器

procedure MessageHandler(var Msg: TMessage); message WM_BATCHDISPLAY_MESSAGE;

现在定义消息处理程序。

procedure TBatchForm.MessageHandler(var Msg: TMessage);
var
   msg_prm: ^TWMUCommand;
begin
  try

    // Next line fails with Incompatible types
    msg_prm := ^TWMUCommand(Msg.LParam);
    ShowMessage(Format('min: %d; max: %d; avg: %d; ovrbdgt: %s; p1: %d; p2: %s',
                [msg_prm.Min, msg_prm.Max, msg_prm.Avg, BoolToStr(msg_prm.bOverBudget, True),
                 msg_prm.Param1, msg_prm.Param2]));
  finally
    Dispose(msg_prm);
  end;
end;

如何将Msg.LParam放回记录结构中？

Answer 1

首先，为记录声明指针类型会更容易：

type
  PWMUCommand = ^TWMUCommand;
  TWMUCommand = record
    ...
  end;

然后在发布消息的方法中，将指针声明为PWMUCommand。

您的Integer强制转换采用32位代码。最好强制转换为该参数的真实类型为LPARAM。

PostMessage(..., LPARAM(msg_prm));

在函数中接收消息，使用指针类型声明局部变量：

var
  msg_prm: PWMUCommand;

按如下所示进行投射：

msg_prm := PWMUCommand(Msg.LParam);

请注意，当调用PostMessage时，应检查返回值，以防失败。如果失败，那么您需要处置内存。

if not PostMessage(..., LPARAM(msg_prm)) then
begin
  Dispose(msg_prm);
  // handle error
end;

最后，据我所知，这种方法仅在发送方和接收方处于同一进程中时才有效。

Delphi-将记录作为窗口消息发送

1 个答案: