Question

我的调查结果格式正好excel。然后，我需要在一个可呈现的单词doc或wewb页面上单独显示这些结果吗？有什么可以做的。

例如：

第一栏 - 第2栏

结果1 - 结果1

结果2 - 结果2

到

comlumn 1

结果一

第2栏

结果一

第1栏

结果2

comlumn 2

结果2

对不起，如果没有意义的话。

由于

Answer 1

听起来你需要在单词中使用“邮件合并”，然后将excel电子表格作为数据源。

Answer 2

您的问题中没有太多信息，但似乎您可以使用宏来转换数据。我写了一个快速宏，它以您提供的格式获取数据并按照您指定的方式输出。

我会使用下面的宏在Excel中创建一个新的工作表，然后根据需要对其进行操作或粘贴到Word中。没有更多信息，没有更多的话要说。

**Input**
Column A      Column B
Result A1     Result B1
Result A2     Result B2
**Output**
Column A
Result A1
Column B
Result B1
Column A
Result A2
Column B
Result B2

这是宏：

' Transforms the current sheet
' This method takes columns and rows and outputs a
' single This is not a transpose method, but similar.
Public Sub TransformSheet()
    Dim SourceSheet As Worksheet
    Dim ResultSheet As Worksheet
    Dim iSourceColumn As Long, iSourceRow As Long
    Dim iResultColumn As Long, iResultRow As Long
    Dim iHeaderRow As Long
    Dim UseCopyPaste As Boolean
    ' Change source and result sheets as necessary
    Set SourceSheet = ActiveSheet
    Set ResultSheet = ActiveWorkbook.Sheets("Sheet2")
    ' Options
    UseCopyPaste = True
    iHeaderRow = 1
    iResultColumn = 1
    iResultRow = 1
    ' Main Loop
    For iSourceRow = 2 To SourceSheet.UsedRange.Rows.Count
        For iSourceColumn = 1 To SourceSheet.UsedRange.Columns.Count
            If UseCopyPaste Then
                ' Header Column
                SourceSheet.Cells(iHeaderRow, iSourceColumn).Copy
                ResultSheet.Cells(iResultRow, iResultColumn).PasteSpecial xlPasteAll
                iResultRow = iResultRow + 1
                ' Result  Column
                SourceSheet.Cells(iSourceRow, iSourceColumn).Copy
                ResultSheet.Cells(iResultRow, iResultColumn).PasteSpecial xlPasteAll
                iResultRow = iResultRow + 1
            Else
                ' Header Column
                ResultSheet.Cells(iResultRow, iResultColumn) = _
                    SourceSheet.Cells(iHeaderRow, iSourceColumn).Value
                iResultRow = iResultRow + 1
                ' Result Column
                ResultSheet.Cells(iResultRow, iResultColumn) = _
                    SourceSheet.Cells(iSourceRow, iSourceColumn).Value
                iResultRow = iResultRow + 1
            End If
        Next iSourceColumn
    Next iSourceRow
End Sub

我需要在可呈现的网页或文字doc上显示excel数据？

2 个答案: