Question

早上好

下面的代码显示了一个带有过程的名称空间，并且有一个名为ds_out的数组。

如果我运行此代码并按Enter键，则会收到错误消息：

“错误：无法读取” ds_out（0）!：没有这样的变量

如果我勾选复选框并按Enter，则显示以下消息：

“ KL15是：1”，如果我取消选中该框，它将显示为“ KL15是：0”

如果我注释掉了命名空间，只需要执行一下程序就可以了。

有人可以告诉我为什么吗？

namespace eval RELAY_SELECT {
tk::labelframe .rs -text "Relay Selection"
array set ds_out {
0   0
1   0 
}
proc create_RS_Labels {} {
tk::label .rs.kl15_lb -text "KL15" -justify center -width 5
}
proc create_RS_CBoxes {} {
tk::checkbutton .rs.kl15_cb -width 1 -height 1 -variable kl15_cb -command {if {$kl15_cb} {
set ds_out(0) 1
set ds_out(1) 1
} else {
set ds_out(0) 0
set ds_out(1) 0
} }
}
proc create_RS_enter_Button {} {
tk::button .rs.enter -borderwidth 1 -height 1 -text "Enter" -width 5 -command {if {$kl15_cb} {
set ds_out(0) 1
set ds_out(1) 1
puts "KL15 is: $ds_out(0)"
} else {
puts "KL15 is: $ds_out(0)"
set ds_out(0) 0
set ds_out(1) 0
}
}
}
proc create_RS_LabelFrame {} {

place .rs -x 10 -y 10
grid .rs.kl15_lb -row 0 -column 0 
grid .rs.kl15_cb -row 0 -column 1   
grid .rs.enter -row 12 -column 0 -columnspan 6
}
create_RS_Labels
create_RS_CBoxes
create_RS_enter_Button
create_RS_LabelFrame
}

Answer 1

您在变量范围设定方面遇到了问题。

Tk命令回调始终在全局范围内评估。您的数组在全局范围内是 not （尽管您可能并不期望它们是kl15_cb 等全局变量）。这会很快变得非常混乱。强烈建议您为所有回调创建帮助程序。这是为了理智起见，将您的代码重新编写为应如何处理；请特别注意其中的Note!注释。

namespace eval RELAY_SELECT {
    # Note! Declare variables in namespaces, always, to avoid an obscure misfeature!
    variable kl15_cb 0
    variable ds_out
    array set ds_out {
        0   0
        1   0 
    }

    proc create_RS_Labels {frame} {
        tk::label $frame.kl15_lb -text "KL15" -justify center -width 5
    }

    proc create_RS_CBoxes {frame} {
        # Note! Fully qualified variable name!
        # Note! [namespace code] to make callback script!
        tk::checkbutton $frame.kl15_cb -width 1 -height 1 -variable ::RELAY_SELECT::kl15_cb \
                -command [namespace code { RS_CBox_callback }]
    }

    proc RS_CBox_callback {} {
        # Note! [variable] with *ONE* argument to bring var into procedure scope
        variable kl15_cb
        variable ds_out
        if {$kl15_cb} {
            set ds_out(0) 1
            set ds_out(1) 1
        } else {
            set ds_out(0) 0
            set ds_out(1) 0
        }
    }

    proc create_RS_enter_Button {frame} {
        tk::button $frame.enter -borderwidth 1 -height 1 -text "Enter" -width 5 \
                -command [namespace code { RS_enter_callback }]
    }

    proc RS_enter_callback {} {
        variable kl15_cb
        variable ds_out
        if {$kl15_cb} {
             set ds_out(0) 1
             set ds_out(1) 1
             puts "KL15 is: $ds_out(0)"
        } else {
             puts "KL15 is: $ds_out(0)"
             set ds_out(0) 0
             set ds_out(1) 0
        }
    }

    proc create_RS_LabelFrame {frame} {
        place $frame -x 10 -y 10
        grid $frame.kl15_lb -row 0 -column 0 
        grid $frame.kl15_cb -row 0 -column 1   
        grid $frame.enter -row 12 -column 0 -columnspan 6
    }

    tk::labelframe .rs -text "Relay Selection"
    create_RS_Labels .rs
    create_RS_CBoxes .rs
    create_RS_enter_Button .rs
    create_RS_LabelFrame .rs
}

出于我自己的理智，我也按惯例缩进了所有内容。

在名称空间过程中看不到数组，但是在过程中没有命名空间

1 个答案: