Question

我正在尝试替换一些节点值。想法是在其他结构中搜索具有相同名称的节点，然后替换该值。

在这里，我正在使用Rule / A更改来自Body / A的值，并使用Rule / D更改来自Body / C / D的值。

这样的事情。

<Message>
<XMLNSC>
    <MaXML>
        <Rule>
            <A>RuleA</A>
            <D>RuleD</D>
            <E>RuleE</E>
        </Rule>
        <Body>
            <A>valA</A>
            <B>valB</B>
            <C>
                <D>valD</D>
            </C>
        </Body>
    </MaXML>
</XMLNSC>

对此。

<Message>
<XMLNSC>
    <MaXML>
        <Rule>
            <A>RuleA</A>
            <D>RuleD</D>
            <E>RuleE</E>
        </Rule>
        <Body>
            <A>RuleA</A>
            <B>valB</B>
            <C>
                <D>RuleD</D>
            </C>
        </Body>
    </MaXML>
</XMLNSC>

当前，我正在遍历所有子级，以寻找节点名称之间的匹配项，但是我应该如何保持相同的结构并只是更改其值？

<?xml version="1.0" encoding="utf-8"?>

<xsl:output method="xml" indent="yes"/>

<!-- copy all -->
<xsl:template match="@* | node()">
    <xsl:copy>
        <xsl:apply-templates select="@* | node()"/>
    </xsl:copy>
</xsl:template>

<!-- match Body -->
<xsl:template match="Body">
    <Body>
        <!-- all children from body -->
        <xsl:for-each select="descendant::*">
            <xsl:variable name="maNode" select="."/>
            <xsl:variable name="nodeName" select="name()"/>
            <!-- all rules -->
            <xsl:for-each select="//Rule/*">
                <xsl:variable name="varRuleName" select="name()"/>  
                <xsl:choose>
                    <!-- match rule -->
                    <xsl:when test="$nodeName = $varRuleName">
                        <element name="match"/>
                        <xsl:copy>
                            <xsl:apply-templates select="@* | node()"/>
                        </xsl:copy>
                    </xsl:when>
                    <xsl:otherwise>
                        <element name="unmatch"/>
                        <xsl:copy>
                            <xsl:apply-templates select="@* | node()"/>
                        </xsl:copy>
                    </xsl:otherwise>
                </xsl:choose>
            </xsl:for-each>
        </xsl:for-each>
    </Body>
</xsl:template>

Answer 1

使用身份模板的方法

  <xsl:template match="@* | node()">
    <xsl:copy>
      <xsl:apply-templates select="@* | node()"/>
    </xsl:copy>
  </xsl:template>

很好，现在使用时，您只需要为要更改的元素添加模板即可。

  <xsl:template match="Body/A">
      <xsl:copy>
          <xsl:value-of select="ancestor::MaXML/Rule/A"/>
      </xsl:copy>
  </xsl:template>

https://xsltfiddle.liberty-development.net/pPqsHTK

很明显，我希望如何添加与Body/C/D匹配的第三个模板，并根据需要从相应的Rule中选择值。

如果您需要通用方法，则在XSLT 2或3中使用子树中的键和键函数调用很容易：

  <xsl:key name="ref" match="MaXML/Rule/*" use="node-name()"/>

  <xsl:template match="Body//*[key('ref', node-name(), ancestor::MaXML)]">
      <xsl:copy>
          <xsl:value-of select="key('ref', node-name(), ancestor::MaXML)"/>
      </xsl:copy>
  </xsl:template>

然后是https://xsltfiddle.liberty-development.net/pPqsHTK/3的完整XSLT 3

<xsl:stylesheet
    xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
    version="3.0">

  <xsl:mode on-no-match="shallow-copy"/>

  <xsl:key name="ref" match="MaXML/Rule/*" use="node-name()"/>

  <xsl:template match="Body//*[key('ref', node-name(), ancestor::MaXML)]">
      <xsl:copy>
          <xsl:value-of select="key('ref', node-name(), ancestor::MaXML)"/>
      </xsl:copy>
  </xsl:template>

</xsl:stylesheet>

不幸的是，XSLT 1没有key函数的第三个参数，因此要实现带有密钥的通用方法，您需要在密钥值中包含generate-id(ancestor::MaXML)：

  <xsl:key name="ref" match="MaXML/Rule/*" use="concat(generate-id(ancestor::MaXML), '|', name())"/>

  <xsl:template match="Body//*[key('ref', concat(generate-id(ancestor::MaXML), '|', name()))]">
      <xsl:copy>
          <xsl:value-of select="key('ref', concat(generate-id(ancestor::MaXML), '|', name()))"/>
      </xsl:copy>
  </xsl:template>

示例https://xsltfiddle.liberty-development.net/pPqsHTK/4。

XSL-用其他名称替换其他结构中的节点值

1 个答案: