Question

我有一个问题。

我的输入XML看起来像

<?xml version="1.0" encoding="UTF-8"?>
<Text>
    <Message>this is line 1
    this is line 2
    this is line 3
    this is line 4
    this is line 5
    this is line 6
    this is line 7
    ....
    ....n
    </Message>
</Text>

Message中的内容由换行符或回车符分隔，行数不确定。

输出将是：

<?xml version="1.0" encoding="UTF-8" ?> 
<Text>
  <Line>this is line 1</Line> 
  <Line>this is line 2</Line> 
  <Line>this is line 3</Line> 
  <Line>this is line 4</Line> 
  <Line>this is line 5</Line> 
  <Line>this is line 6</Line> 
  <Line>this is line 7</Line> 
  <Line>this is line 8</Line> 
  <Line>this is line 9</Line> 
  <Line>this is line 10</Line> 
</Text>

我写了以下XSL：

<?xml version="1.0"?>
<xsl:stylesheet version="2.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:output method="xml" indent="yes" encoding="UTF-8"/>

    <xsl:variable name="lineFeed"><xsl:text>&#xA;</xsl:text></xsl:variable>
    <xsl:variable name="carriageReturn"><xsl:text>&#xD;</xsl:text></xsl:variable>
    <xsl:template match="/">
    <Text>
           <xsl:if test="Text/Message">
                <xsl:choose>
                    <xsl:when test="contains(Text/Message, $lineFeed)">
                        <xsl:call-template name="TextWithLineBreaks">
                            <xsl:with-param name="string" select="Text/Message"/>
                            <xsl:with-param name="delimiter" select="$lineFeed"/>
                        </xsl:call-template>
                    </xsl:when>
                    <xsl:when test="contains(Text/Message, $carriageReturn)">
                        <xsl:call-template name="TextWithLineBreaks">
                            <xsl:with-param name="string" select="Text/Message"/>
                            <xsl:with-param name="delimiter" select="$carriageReturn"/>
                        </xsl:call-template>
                    </xsl:when>
                    <xsl:otherwise>
                        <Line>
                            <xsl:value-of select="Text/Message"/>
                        </Line>
                    </xsl:otherwise>
                 </xsl:choose>
             </xsl:if>
    </Text>
    </xsl:template>

    <xsl:template name="TextWithLineBreaks">
        <xsl:param name="string"/>
        <xsl:param name="delimiter"/>
        <xsl:variable name="Result">
            <xsl:call-template name="extract-bodytext">
                <xsl:with-param name="GetString" select="$string"/>
                <xsl:with-param name="Separator" select="$delimiter"/>
            </xsl:call-template>
        </xsl:variable>
        <xsl:copy-of select="$Result"/>
    </xsl:template>

    <xsl:template name="extract-bodytext">
        <xsl:param name="GetString"/>
        <xsl:param name="Separator"/>
        <xsl:choose>
            <xsl:when test="contains($GetString, $Separator)">
                <xsl:variable name="firstline" select="substring-before($GetString, $Separator)"/>
                <xsl:if test="string-length($firstline) > 0">
                    <Line>
                        <xsl:value-of select="substring-before($GetString, $Separator)"/>
                    </Line>
                </xsl:if>
                <xsl:call-template name="extract-bodytext">
                    <xsl:with-param name="GetString">
                        <xsl:value-of select="substring-after($GetString,$Separator)"/>
                    </xsl:with-param>
                    <xsl:with-param name="Separator" select="$lineFeed"/>
                </xsl:call-template>
            </xsl:when>
            <xsl:otherwise>
                <xsl:value-of select="$GetString"/>
            </xsl:otherwise>
        </xsl:choose>
    </xsl:template>             
</xsl:stylesheet>

现在我的问题是，对于输出，我只能映射到最大数量10＆lt; Line＆gt;。使用上面的XSL，它将映射到输入中存在的任意数量的行。

有什么建议吗？

由于丁

Answer 1

这是一种方法：

<xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>
 <xsl:strip-space elements="*"/>

 <xsl:template match="/*">
  <Text>
    <xsl:apply-templates/>
  </Text>
 </xsl:template>

 <xsl:template match="text()" name="wrapLines">
  <xsl:param name="pText" select="."/>
  <xsl:param name="pNumLines" select="10"/>

  <xsl:if test=
   "string-length($pText) and $pNumLines > 0">
   <xsl:variable name="vLine" select=
   "substring-before(concat($pText,'&#xA;'), '&#xA;')"/>
   <Line>
    <xsl:value-of select="$vLine"/>
   </Line>

   <xsl:call-template name="wrapLines">
    <xsl:with-param name="pNumLines" select="$pNumLines -1"/>
    <xsl:with-param name="pText" select=
     "substring-after($pText, '&#xA;')"/>
   </xsl:call-template>
  </xsl:if>
 </xsl:template>
</xsl:stylesheet>

将此转换应用于以下XML文档（包含10行以上）时：

<Text>
    <Message>this is line 1
    this is line 2
    this is line 3
    this is line 4
    this is line 5
    this is line 6
    this is line 7
    this is line 8
    this is line 9
    this is line 10
    this is line 11
    </Message>
</Text>

产生了想要的正确结果：

<Text>
   <Line>this is line 1</Line>
   <Line>   this is line 2</Line>
   <Line>   this is line 3</Line>
   <Line>   this is line 4</Line>
   <Line>   this is line 5</Line>
   <Line>   this is line 6</Line>
   <Line>   this is line 7</Line>
   <Line>   this is line 8</Line>
   <Line>   this is line 9</Line>
   <Line>   this is line 10</Line>
</Text>

解决方案2 ：

使用FXSL的str-split-to-words模板/功能，可以简单地编写：

<xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
 xmlns:ext="http://exslt.org/common"
 exclude-result-prefixes="ext"
>
  <xsl:import href="strSplit-to-Words.xsl"/>
  <xsl:output indent="yes" omit-xml-declaration="yes"/>

   <xsl:strip-space elements="*"/>
   <xsl:output indent="yes" omit-xml-declaration="yes"/>

   <xsl:param name="pmaxLines" select="10"/>

    <xsl:template match="/">
     <Text>
      <xsl:variable name="vwordNodes">
        <xsl:call-template name="str-split-to-words">
          <xsl:with-param name="pStr" select="/"/>
          <xsl:with-param name="pDelimiters"
                          select="'&#10;&#13;'"/>
        </xsl:call-template>
      </xsl:variable>

      <xsl:apply-templates select=
       "ext:node-set($vwordNodes)/*[not(position() > $pmaxLines)]"/>
     </Text>
    </xsl:template>

    <xsl:template match="word">
      <Line><xsl:value-of select="."/></Line>
    </xsl:template>
</xsl:stylesheet>

当此转换应用于与上述相同的XML文档时，会生成所需的正确结果：

<Text>
   <Line>this is line 1</Line>
   <Line>   this is line 2</Line>
   <Line>   this is line 3</Line>
   <Line>   this is line 4</Line>
   <Line>   this is line 5</Line>
   <Line>   this is line 6</Line>
   <Line>   this is line 7</Line>
   <Line>   this is line 8</Line>
   <Line>   this is line 9</Line>
   <Line>   this is line 10</Line>
</Text>

Answer 2

您是否尝试使用position()或<xsl:number/>？其中任何一种都可能是你想做的事情。

<xsl:number/>将存储在变量中，然后检查以查看在该级别中已在文档中创建了多少个节点。我在<xsl:for-each>循环中使用它并假设它可以在这种情况下以类似的方式使用。

Answer 3

我将（）所有行结尾翻译成单个字符，这样你就不会同时调用$ lineFeed和$ carriageReturn变体，而只是调用一个$ newline调用模板。然后创建一个设置为10的计数器变量，并在每次调用递归模板时将其递减。根据您的原始条件进行测试或变量= 0因此，当您用完线或处理10时，将退出，以较小者为准。

Answer 4

我略微修改了你的XSL，我获得了前10行：

<?xml version="1.0"?>
<xsl:stylesheet version="2.0"
    xmlns:xsl="http://www.w3.org/1999/XSL/Transform">

    <xsl:template match="/">
    <xsl:variable name="all">
    <Text>
      unchanged generation of all the lines in the Text list
    </Text>
    </xsl:variable>
    <Text>
    <xsl:copy-of select="$all/Text/Line[position() le 10]"/>
    </Text>
    </xsl:template>

    rest unchanged

</xsl:stylesheet>

当然这是一个kludge，因为如果你有数千行，你只想要前十，那么这是浪费...... OTOH，如果你知道行数合理，那便宜。

此外，如果不使用exslt：node-set扩展名，则无法在XSLT 1.0 / Xpath 1.0中使用。

根据换行符拆分字符串并映射到有限数量的元素

4 个答案: