Question

我需要能够在VBA中使用多种语言（英语，中文和日语）的字符串。仅当使用一种语言时，才能更改计算机的区域/地区设置。有人可以帮忙吗？

示例代码

dim x as string
dim y as string
dim z as string
x = "English text"
y = "尊敬的"
z = "こんにちは"

Answer 1

ashleedawg的建议有一个简单的替代方法：

使用字节数组而不是字符串来声明字符串。这样，VBA IDE可以存储与语言环境设置无关的数据。

我使用以下函数在VBA中声明字节数组（注意：如果传递的不是字节，则错误）：

Public Function ByteArray(ParamArray bytes() As Variant) As Byte()
    Dim output() As Byte
    ReDim output(LBound(bytes) To UBound(bytes))
    Dim l As Long
    For l = LBound(bytes) To UBound(bytes)
        output(l) = bytes(l)
    Next
    ByteArray = output
End Function

如果有这个，可以执行以下操作：

dim x as string
dim y as string
dim z as string
x = "English text" 
'Or: x = ByteArray(&H45,&H0,&H6E,&H0,&H67,&H0,&H6C,&H0,&H69,&H0,&H73,&H0,&H68,&H0,&H20,&H0,&H74,&H0,&H65,&H0,&H78,&H0,&H74,&H0)
y = ByteArray(&HA,&H5C,&H6C,&H65,&H84,&H76)
z = ByteArray(&H53,&H30,&H93,&H30,&H6B,&H30,&H61,&H30,&H6F,&H30)

要获取这些字节数组，请使用以下工作表函数：

Public Function UnicodeToByteArray(str As String) As String
    If Len(str) = 0 Then Exit Function
    Dim bytes() As Byte
    bytes = str
    Dim l As Long
    For l = 0 To UBound(bytes) - 1
        UnicodeToByteArray = UnicodeToByteArray & "&H" & Hex(bytes(l)) & ","
    Next
    UnicodeToByteArray = UnicodeToByteArray & "&H" & Hex(bytes(UBound(bytes)))
End Function

您可以在工作表中使用它（例如=UnicodeToByteArray(A1)，其中A1包含字符串），然后将结果复制粘贴到VBA。

您可以直接将字符串分配给字节数组，然后反转。

请注意，Unicode支持在整个VBA中有所不同。例如。 MsgBox z将产生问号，而Cells(1,1).Value = z将A1设置为所需的字符串。

在VBA中使用多种语言（英语，中文，日语）

1 个答案: