Question

我知道GroupBox标题中可能有单选按钮（或其他任何项目），但是这些行为并没有链接。

这是我的界面图片

现在，用户可以通过单击“创建病变”按钮或单击列表中的现有病变来进行确认。我想让用户选择一个groupBox或另一个，并禁用相关信息，以便有一个确认按钮。

Answer 1

使用label属性添加RadioButton，并附加ButtonGroup的{{3}}属性，使组框彼此互斥：

import QtQuick 2.10
import QtQuick.Controls 2.3
import QtQuick.Layouts 1.3

ApplicationWindow {
    width: 640
    height: 480
    visible: true

    ButtonGroup {
        id: checkGroup
    }

    RowLayout {
        GroupBox {
            id: newLesionGroupBox
            title: "New lesion"

            label: RowLayout {
                RadioButton {
                    id: newLesionRadioButton
                    checked: true

                    ButtonGroup.group: checkGroup
                }
                Label {
                    text: newLesionGroupBox.title
                    font: newLesionGroupBox.font
                }
            }

            Column {
                enabled: newLesionRadioButton.checked

                Label {
                    text: "Some stuff"
                }
                Button {
                    text: "Blah"
                }
            }
        }
        GroupBox {
            id: existingLesionGroupBox
            title: "Existing lesion"

            label: RowLayout {
                RadioButton {
                    id: existingLesionRadioButton

                    ButtonGroup.group: checkGroup
                }
                Label {
                    text: existingLesionGroupBox.title
                    font: existingLesionGroupBox.font
                }
            }

            Column {
                enabled: existingLesionRadioButton.checked

                Label {
                    text: "Some stuff"
                }
                Button {
                    text: "Blah"
                }
            }
        }
    }
}

您可以通过在组框中创建可重复使用的组件来对此进行大量整理。

可以自定义的控件的每个可视部分都有一个指向自定义文档的链接。在这种情况下，它链接到这里：

group

表现为单选按钮的组框

1 个答案: