Question

我正在看trezor的bootloader链接描述文件：

/* TREZORv2 bootloader linker script */

ENTRY(reset_handler)

MEMORY {
  FLASH  (rx)  : ORIGIN = 0x08020000, LENGTH = 128K
  CCMRAM (wal) : ORIGIN = 0x10000000, LENGTH = 64K
  SRAM   (wal) : ORIGIN = 0x20000000, LENGTH = 192K
}

main_stack_base = ORIGIN(CCMRAM) + LENGTH(CCMRAM); /* 8-byte aligned full descending stack */

/* used by the startup code to populate variables used by the C code */
data_lma = LOADADDR(.data);
data_vma = ADDR(.data);
data_size = SIZEOF(.data);

/* used by the startup code to wipe memory */
ccmram_start = ORIGIN(CCMRAM);
ccmram_end = ORIGIN(CCMRAM) + LENGTH(CCMRAM);

/* used by the startup code to wipe memory */
sram_start = ORIGIN(SRAM);
sram_end = ORIGIN(SRAM) + LENGTH(SRAM);

_codelen = SIZEOF(.flash) + SIZEOF(.data);

SECTIONS {
  .header : ALIGN(4) {
    KEEP(*(.header));
  } >FLASH AT>FLASH

  .flash : ALIGN(512) {
    KEEP(*(.vector_table));
    . = ALIGN(4);
    *(.text*);
    . = ALIGN(4);
    *(.rodata*);
    . = ALIGN(512);
  } >FLASH AT>FLASH

  .data : ALIGN(4) {
    *(.data*);
    . = ALIGN(512);
  } >CCMRAM AT>FLASH

  .bss : ALIGN(4) {
    *(.bss*);
    . = ALIGN(4);
  } >CCMRAM

  .stack : ALIGN(8) {
    . = 4K; /* this acts as a build time assertion that at least this much memory is available for stack use */
  } >CCMRAM
}

可以找到here。

我知道代码需要对齐32位（ALIGN（4）），因为ARM处理器如果尝试访问未对齐的地址可能会崩溃，但是我不明白为什么堆栈对齐为8个字节，并且为什么地狱，您是否需要浪费（？）512个字节来对齐Flash节？！

我想了解编写链接程序脚本时如何确定对齐方式。

预先感谢您的回答！

编辑：

我想我回答了我自己的问题：

1。 .flash部分：

它像这样对齐，因为它里面的向量表始终需要为"32-word aligned"。在Trezor's boardloader linker script中也可以看到这种情况。如您所见，向量表是512字节（4 x 32字）对齐的。

2。 .stack部分：

根据ARM's own documentation，堆栈部分必须始终保持8字节对齐。

P.S。当然，如果不是这种情况，请纠正我。

Answer 1

好的，既然cooperised证实了我的理论，我现在可以解决这个问题。

1。 .flash部分：

它像这样对齐，因为它里面的向量表始终需要“ 32字对齐”。在Trezor的boardloader链接器脚本中也可以看到这种情况。如您所见，向量表是512字节（4 x 32字）对齐的。

2。 .stack部分：

根据ARM自己的文档，堆栈部分必须始终保持8字节对齐。

谢谢您的确认！

链接描述文件中的对齐方式

1 个答案: