为什么我的Visual Basic Excel代码在单元格中返回#value

Question

为什么我的Visual Basic Excel代码在单元格中返回#value？我正在寻找从单元格A1中提取电子邮件地址。下面是我的代码

Function ExtractEmailAddress(s As String) As String
    Dim AtSignLocation As Long
    Dim i As Long
    Dim TempStr As String
    Const CharList As String = "[A-Za-Z0-9._-]"

    'Get location of the @
    AtSignLocation = InStr(s, "@")
    If AtSignLocation = 0 Then
        ExtractEmailAddress = "" 'no email address is there
    Else
        TempStr = ""
        'Get 1st half of the email address
        For i = AtSignLocation - 1 To 1 Step -1
            If Mid(s, i, 1) Like CharList Then
                    TempStr = Mid(s, i, 1) & TempStr
            Else
                Exit For
            End If
        Next i
        If TempStr = "" Then Exit Function
        'get 2nd half of the email address
        TempStr = TempStr & "@"
        For i = AtSignLocation + 1 To Len(s)
            If Mid(s, i, 1) Like CharList Then
                TempStr = TempStr & Mid(s, i, 1)
            Else
                Exit For
            End If
        Next i
    End If
    'remove trailing period if there is any
    If Right(TempStr, 1) = "." Then TempStr = _
        Left(TempStr, Len(TempStr) - 1)
    ExtractEmailAddress = TempStr
End Function

我还提供了excel VBA的屏幕截图。

ScreenShot：

此外，这是其返回值的屏幕截图

返回值屏幕截图：

Answer 1

我在这里收到“无效的模式字符串”错误：

If Mid(s, i, 1) Like CharList Then

问题出在CharList常量上：

Const CharList As String = "[A-Za-Z0-9._-]"

将A-Za-Z替换为A-Za-z，该函数开始工作=）

Const CharList As String = "[A-Za-z0-9._-]"