Question

我正在尝试编写一些代码，将数据复制并粘贴到单元格A3：A6到A8：A11中，然后再次运行时，它将粘贴在下面的行+1，因此下次运行数据时A8：A11将被复制并粘贴到A13：A16中，下一次运行后，它将把A13：16中的数据粘贴到A18：21中，依此类推。

以下是我尝试提出的内容，但我可能还有一段距离，任何指导将不胜感激：

Sub RollFile()

Dim UsdRows As Long

UsdRows = Cells(Rows.Count, 3).End(xlToUp).Row
With Range(Cells(1, UsdRows), Cells(UsdRows, 1))
  .Copy .Offset(, 1)
  .Value = .Value
  .Offset(-1, 1)(1).Select
End With

End Sub

非常感谢

Answer 1

我建议以下内容：

Option Explicit

Public Sub RollFile()
    Const RowsToCopy As Long = 4 'amount of rows that should be copied

    Dim LastCell As Range
    Set LastCell = Cells(Rows.Count, "A").End(xlUp) 'last cell in col A

    With LastCell.Offset(RowOffset:=-RowsToCopy + 1).Resize(RowSize:=RowsToCopy) '= last 4 cells (4 = RowsToCopy)
        .Copy LastCell.Offset(RowOffset:=2)
        .Value = .Value 'not needed I think
    End With
End Sub

它会在A列中查找最后使用的单元格。然后从那里选择前4个单元格，然后在下面复制2行。

请注意，我认为根本不需要.Value = .Value，因为只有复制了需要转换为值的公式后，这才有意义。

Answer 2

您可以尝试

Sub RollFile()

    With Cells(Rows.Count, 1).End(xlUp) ' reference column A last not empty cell
        With Range(.End(xlUp), .Cells) ' reference the range from referenced cell up to last adjacent one
            .Offset(.Rows.Count + 1).Value = .Value ' copy referenced range values to a range two row below its end
        End With
    End With

End Sub

VBA复制并粘贴到下面的第+1行

2 个答案: