Question

基于此结构，我最多有4个文件（注意前缀是日期）

0830filename.txt
0907filename.txt
0914filename.txt
0921filename.txt

我想打开最近的一个（0921filename.txt）。我怎么能在批处理文件中这样做？

感谢。

Answer 1

此方法使用实际的文件修改日期，以确定哪一个是最新文件：

@echo off
for /F %%i in ('dir /B /O:-D *.txt') do (
    call :open "%%i"
    exit /B 0
)
:open
    start "dummy" "%~1"
exit /B 0

然而，这种方法按字母顺序选择最后一个文件（或者按反向字母顺序选择第一个文件），所以如果文件名是一致的 - 它将起作用：

@echo off
for /F %%i in ('dir /B *.txt^|sort /R') do (
    call :open "%%i"
    exit /B 0
)
:open
    start "dummy" "%~1"
exit /B 0

您实际上必须选择哪种方法更适合您。

Answer 2

很抱歉，发送此问题的垃圾邮件，但我真的想发布真实答案。如果您希望BATCH脚本解析并比较文件名中的日期，那么您可以使用以下内容：

@echo off

rem Enter the ending of the filenames.
rem Basically, you must specify everything that comes after the date.
set fn_end=filename.txt

rem Do not touch anything bellow this line.
set max_month=00
set max_day=00

for /F %%i in ('dir /B *%fn_end%') do call :check "%%i"
call :open %max_month% %max_day%
exit /B 0

:check
    set name=%~1
    set date=%name:~0,4%
    set month=%date:~0,2%
    set day=%date:~2,2%
    if /I %month% GTR %max_month% (
        set max_month=%month%
        set max_day=%day%
    ) else if /I %month% EQU %max_month% (
        set max_month=%month%
        if /I %day% GTR %max_day% (
            set max_day=%day%
        )
    )
exit /B 0

:open
    set date=%~1
    set month=%~2
    set name=%date%%month%%fn_end%
    start "dummy" "%name%"
exit /B 0

Answer 3

一个班轮，使用EXIT技巧：

FOR /F %%I IN ('DIR *.TXT /B /O:-D') DO NOTEPAD %%I & EXIT

修改

@pam：你是对的，我假设文件是按日期顺序排列的，但你可以将命令更改为：

FOR /F %%I IN ('DIR *.TXT /B /O:-N') DO NOTEPAD %%I & EXIT

然后你按照相反的顺序排序文件列表。

Answer 4

在这里你去...（希望没有人打败我...）（你需要将文件保存为lasttext.bat或其他东西）这将打开/运行最早的.txt文件

dir *.txt /b /od > systext.bak 
FOR /F %%i in (systext.bak) do set sysRunCommand=%%i 
call %sysRunCommand%
del systext.bak /Y

可能只是XP。 BEHOLD DOS的强大力量虽然这按日期采用最新的文件名 - 不是通过文件名..

如果您想获取最新的文件名，请将/ od更改为/ on 如果要对其他内容进行排序，请在第二行添加“sort”命令。

Answer 5

使用正则表达式解析相关的整数并比较它们。

使用批处理文件打开一系列文件之一

5 个答案: