Question

当我在F＃REPL fsharpi中工作时，每当我输入新功能时，输入它们后便会打印出签名：

> let foo x = x;;
val foo : x:'a -> 'a

有没有办法将其检索为字符串？我问的原因是我正在使用IfSharp而不显示签名的Jupyter笔记本，但是我希望能够显示功能类型以供演示。

我已经弄乱了一点，但是找不到任何有用的东西，我已经尝试过：

let foo x = (x, x)
printfn "%A" (foo.GetType())
printfn "%A" foo

但这不是我所需要的：

FSI_0013+clo@3-1
<fun:it@5-2>

是否可以全部访问？

Answer 1

AFAIK，FSharp.Core中没有用于获取类型字符串表示形式的函数，就像在编译器中出现的一样（尽管FSharp.Compiler.Services中有某些功能，我没有检查）。这是一个适用于大多数简单用途的小功能：

open System

let (|TFunc|_|) (typ: Type) =
    if typ.IsGenericType && typ.GetGenericTypeDefinition () = typeof<int->int>.GetGenericTypeDefinition () then
        match typ.GetGenericArguments() with
        | [|targ1; targ2|] -> Some (targ1, targ2)
        | _ -> None
    else
        None

let rec typeStr (typ: Type) =
    match typ with
    | TFunc (TFunc(_, _) as tfunc, t) -> sprintf "(%s) -> %s" (typeStr tfunc) (typeStr t)
    | TFunc (t1, t2) -> sprintf "%s -> %s" (typeStr t1) (typeStr t2)
    | typ when typ = typeof<int> -> "int"
    | typ when typ = typeof<string> -> "string"
    | typ when typ.IsGenericParameter -> sprintf "'%s" (string typ)
    | typ -> string typ


typeStr typeof<(string -> (string -> int) -> int) -> int>
// val it: string = "string -> (string -> int) -> int"
typeStr (typeof<int->int>.GetGenericTypeDefinition())
// val it: string = "'T -> 'TResult"

您可以在此之上轻松编写一个函数，以在值的类型上使用typeStr：

let valTypeString x = typStr (x.GetType ())

Answer 2

您可以借助Microsoft.FSharp.Reflection名称空间来分析代表F＃函数的类型。需要注意的是，通用函数参数默认为System.Object，并且不包括可能形成不完整模式（例如，联合用例，记录）的其他F＃类型。

open Microsoft.FSharp.Reflection
let funString o =
    let rec loop nested t =
        if FSharpType.IsTuple t then
            FSharpType.GetTupleElements t
            |> Array.map (loop true)
            |> String.concat " * "
        elif FSharpType.IsFunction t then
            let fs = if nested then sprintf "(%s -> %s)" else sprintf "%s -> %s"
            let domain, range = FSharpType.GetFunctionElements t
            fs (loop true domain) (loop false range)
        else
            t.FullName
    loop false (o.GetType())

let foo x = x
funString foo
// val it : string = "System.Object -> System.Object"

F＃函数签名的字符串表示形式

2 个答案: