Question

我正在收集两列（col和val）。进入第二选择列的是其他列的参数，而val是该列的值。

declare
  TYPE t_my_list is record(id varchar2(1000), col VARCHAR2(4000),val VARCHAR2(4000));
  TYPE list_3STR is table of t_my_list;    
  v_stmt    VARCHAR2(32000) := 'SELECT id, col, val FROM userA.tableA';
  v_lstmt   VARCHAR2(32000);
  v_ret     list_3STR := list_3STR();
  cDel   number;

begin
 EXECUTE IMMEDIATE v_stmt BULK COLLECT INTO v_ret;

  for i in v_ret.first..v_ret.last loop
   v_lstmt := 'SELECT count(*) FROM userB.tableB 
      WHERE NVL('||v_ret (i).col||', ''<null>'') in ('''||v_ret (i).val||''', ''<null>'') and idB = '''||v_ret (i).id||'''';

   EXECUTE IMMEDIATE v_lstmt INTO cDel;
    If cDel > 0 Then
    --some code
    cDel = 0;   
    end if;
  end loop;
end;

但是在我的select语句中，我可以为null，因此我正在使用NVL。另外，因为我可以有数字，所以我需要使用convert to_char('||v_ret (i).col||')。另外，列的类型是数字，RAW，日期等。

我的问题：

除了NVL之外还有其他可能性吗？
如果不是，是否具有oracle默认转换器？（所有类型都必须为Varchar2）

Answer 1

您可以更改代码以执行以下操作：

   v_lstmt := 'SELECT count(*) FROM userB.tableB WHERE id = '''||v_ret (i).id||''''
     || ' and ('||v_ret (i).col||' is null or '||v_ret (i).col||' = :val)';

   EXECUTE IMMEDIATE v_lstmt INTO cDel using v_ret (i).val;

检查列是否为空或与提供的val匹配，并使用绑定变量提供值以检查以减少解析位。

但是，这仍然依赖于隐式转换，因此，例如，如果表中具有日期值，则将依靠NLS设置将其转换为与目标表列类型匹配的值。

您可以使用all_tab_columns视图查找目标列的数据类型，并在绑定之前将val显式转换为该类型。一种更复杂但可能更强大的方法是对内部动态SQL使用dbms_sql而不是execute immediate。

外部查询似乎不需要动态，您可以这样做：

declare
  v_lstmt   VARCHAR2(32000);
  cDel   number;
begin
  for rec in (SELECT id, col, val FROM tableA) loop
    v_lstmt := 'SELECT count(*) FROM tableB WHERE id = '''||rec.id||''''
      || ' and ('||rec.col||' is null or '||rec.col||' = :val)';


    dbms_output.put_line(v_lstmt);
    EXECUTE IMMEDIATE v_lstmt INTO cDel using rec.val;
    If cDel > 0 Then
      --some code
      cDel := 0;   
    end if;
  end loop;
end;
/

Answer 2

如果我正确理解了您的问题，则希望包含v_ret（i）.col为NULL的情况。

如果是这样，您可以尝试在select语句中使用以下代码：

WHERE ('||v_ret (i).col||' is null OR '||v_ret (i).col||' = '||v_ret (i).val||')

代替：

WHERE NVL('||v_ret (i).col||', ''<null>'') in ('''||v_ret (i).val||''', ''<null>'')

作为默认转换器，您可以尝试使用 CAST 函数：https://docs.oracle.com/en/database/oracle/oracle-database/12.2/sqlrf/CAST.html

寻找不同Oracle类型的空值

2 个答案: