Question

我简化了要解决的问题。假设我有三个表。包含数据和标识对象的特定代码的代码可以称为苹果。

+-------------+------------+-----------+
| Data picked | Color code | Size code |
+-------------+------------+-----------+
| 1-8-2018    |          1 |         1 |
| 1-8-2018    |          1 |         3 |
| 1-8-2018    |          2 |         2 |
| 1-8-2018    |          2 |         3 |
| 1-8-2018    |          2 |         2 |
| 1-8-2018    |          3 |         3 |
| 1-8-2018    |          4 |         1 |
| 1-8-2018    |          4 |         1 |
| 1-8-2018    |          5 |         3 |
| 1-8-2018    |          6 |         1 |
| 1-8-2018    |          6 |         2 |
| 1-8-2018    |          6 |         2 |
+-------------+------------+-----------+

我有两个相关的帮助表来帮助理解代码（由于与实际情况下的其他表存在歧义，因此它们在模型中的关系不活跃）。

+-----------+--------+
| Size code |  Size  |
+-----------+--------+
|         1 | Small  |
|         2 | Medium |
|         3 | Large  |
+-----------+--------+

和

+------------+----------------+-------+
| Color code | Color specific | Color |
+------------+----------------+-------+
|          1 | Light green    | Green |
|          2 | Green          | Green |
|          3 | Semi green     | Green |
|          4 | Red            | Red   |
|          5 | Dark           | Red   |
|          6 | Pink           | Red   |
+------------+----------------+-------+

让我们说，我想在原始表中创建一个额外的列，以确定哪个苹果是A类和B类，因为中等绿色苹果是A类，大红色苹果是B类，其他的苹果留为空白在下面。

+-------------+------------+-----------+-------+
| Data picked | Color code | Size code | Class |
+-------------+------------+-----------+-------+
| 1-8-2018    |          1 |         1 |       |
| 1-8-2018    |          1 |         3 |       |
| 1-8-2018    |          2 |         2 | A     |
| 1-8-2018    |          2 |         3 |       |
| 1-8-2018    |          2 |         2 | A     |
| 1-8-2018    |          3 |         3 |       |
| 1-8-2018    |          4 |         1 |       |
| 1-8-2018    |          4 |         1 |       |
| 1-8-2018    |          5 |         3 | B     |
| 1-8-2018    |          6 |         1 |       |
| 1-8-2018    |          6 |         2 |       |
| 1-8-2018    |          6 |         2 |       |
+-------------+------------+-----------+-------+

在最初处于非活动状态时，应使用什么适当的DAX。最好是可解决的，而不在任何表中创建任何其他附加列。我已经尝试过以下代码：

CALCULATE ( 
    "A" ; 
    FILTER ( 'Size Table' ; 'Size Table'[Size] = "Medium");
    FILTER ( 'Color Table' ; 'Color Table'[Color] = "Green")
)

在同一原理上还有很多变化

Answer 1

鉴于关系处于非活动状态，我建议使用LOOKUPVALUE来匹配其他表上的ID值。您应该能够创建一个计算列，如下所示：

Class = 
    VAR Size = LOOKUPVALUE('Size Table'[Size],
                   'Size Table'[Size code], 'Data Table'[Size code])
    VAR Color = LOOKUPVALUE('Color Table'[Color],
                   'Color Table'[Color code], 'Data Table'[Color code])
    RETURN SWITCH(TRUE(),
               (Size = "Medium") && (Color = "Green"), "A",
               (Size = "Large") && (Color = "Red"), "B", BLANK())

如果您的关系处于活动状态，则不需要查找：

Class = SWITCH(TRUE(),
            (RELATED('Size Table'[Size]) = "Medium") &&
            (RELATED('Color Table'[Color]) = "Green"),
            "A",
            (RELATED('Size Table'[Size]) = "Large") &&
            (RELATED('Color Table'[Color]) = "Red"),
            "B", 
            BLANK())

或者写得更好一些（尤其是针对更多的课程）：

Class = 
    VAR SizeColor = RELATED('Size Table'[Size]) & " " & RELATED('Color Table'[Color])
    RETURN SWITCH(TRUE(),
               SizeColor = "Medium Green", "A",
               SizeColor = "Large Red", "B",
               BLANK())

创建列以根据实际表对行进行分类DAX PowerBI

1 个答案: