Question

我尝试与SYS_REFCURSOR的集合结果进行比较：

declare
 v_RC sys_refcursor;
 v_RC_union sys_refcursor;
 v_REC userA.table1%rowtype;
 v_REC_union userB.table2%rowtype;
 i number := 0;
 j number := 0;
 z number := 0;
begin         
  open v_RC for select * from userA.table1;
   open v_RC_union for select * from userB.table2;
    loop fetch v_RC into v_REC;
     exit when v_RC%notfound;
     i := i+1;

      loop fetch v_RC_union into v_REC_union;--
       exit when v_RC_union%notfound;
       j := j+1;

            If v_REC_union.id= v_REC.id then                
             z :=z+1;                
            End if;

       end loop;

    end loop;
   close v_RC;
  close v_RC_union;

dbms_output.put_line(z);--too small
dbms_output.put_line('v_RC: '||i||', v_REC_union: '||j);
end;

我知道两个光标的行数都正确（i和j都可以），但是相等行（z）的结果是错误的（太小）。

Answer 1

在外循环的第一次迭代中，您正在消耗v_RC_union中的所有行。您似乎希望每次循环时都可以看到所有这些行，但是第二个ref光标不会重置为开始（并且不可能）。

如果将调试添加到代码中，则可以看到发生的情况；我创建了两个小的虚拟表，每个虚拟表中有三个匹配ID和一个不匹配ID：

create table table1 (id, dummy) as select level + 1, 'x' from dual connect by level <= 4;
create table table2 (id, dummy) as select level, 'x' from dual connect by level <= 4;

declare
...
begin
  open v_RC for select * from table1;
  open v_RC_union for select * from table2;
  loop
    fetch v_RC into v_REC;
    exit when v_RC%notfound;
    i := i+1;
    dbms_output.put_line('i: ' || i || ' table1 id ' || v_REC.id);
    loop
      fetch v_RC_union into v_REC_union;--
      exit when v_RC_union%notfound;
      j := j+1;
      dbms_output.put_line('i: ' || i || ' j: ' || j || ' table1 id ' || v_REC_union.id);
      If v_REC_union.id= v_REC.id then
        z :=z+1;
      end if;
    end loop;
  end loop;
  close v_RC;
  close v_RC_union;
  dbms_output.put_line('z: ' || z);--too small
  dbms_output.put_line('v_RC: '||i||', v_REC_union: '||j);
end;
/

输出是：

i: 1 table1 id 2
i: 1 j: 1 table1 id 1
i: 1 j: 2 table1 id 2
i: 1 j: 3 table1 id 3
i: 1 j: 4 table1 id 4
i: 2 table1 id 3
i: 3 table1 id 4
i: 4 table1 id 5
z: 1
v_RC: 4, v_REC_union: 4

在第一次迭代中，当i为1时，您将执行内部循环并从v_RC_union中获取所有行，仅在notfound时停止。假设其中一个与第一行v_RC的ID匹配，则z递增，因此在第一个外部循环之后为1或0。

在第二次迭代中，当i为2时，由于您已经用尽v_RC_union结果集，因此内部循环将在第一次获取后立即退出。您在第一次迭代中获取了所有行，因此没有任何可获取的内容。因此，没有第二行v_RC的ID不会与任何东西进行比较，并且z不会被触及，因为它没有那么远。

对于外部循环的所有其他迭代，依此类推。内部循环始终会立即退出，并且不会做任何有用的事情。

您可以在答案中每次显示时都重新查询table2以获得特定的ID，尽管如果仅对它们进行计数而不使用任何列值，则实际上并不需要打开/循环/ fetch并可以将该查询更改为一个标量变量。即使对于逐行处理，这似乎也不是很有效。

如果要坚持使用全表查询，可以使用集合：

declare
  type t_table1 is table of table1%rowtype;
  type t_table2 is table of table2%rowtype;
  v_table1 t_table1;
  v_table2 t_table2;
  i number := 0;
  j number := 0;
  z number := 0;
begin
  select * bulk collect into v_table1 from table1;
  select * bulk collect into v_table2 from table2;
  for r1 in v_table1.first..v_table1.last loop
    i := i+1;
    dbms_output.put_line('i: ' || i || ' table1 id ' || v_table1(r1).id);
    j := 0;
    for r2 in v_table2.first..v_table2.last loop
      j := j+1;
      dbms_output.put_line('i: ' || i || ' j: ' || j || ' table2 id ' || v_table2(r2).id);
      if v_table2(r2).id = v_table1(r1).id then
        z := z+1;
      end if;
    end loop;
  end loop;

  dbms_output.put_line('z: ' || z);
  dbms_output.put_line('v_RC: '||i||', v_REC_union: '||j);
end;
/

通过遍历两个集合，每次i迭代都会看到每个j行，并且可以比较ID。

i: 1 table1 id 2
i: 1 j: 1 table2 id 1
i: 1 j: 2 table2 id 2
i: 1 j: 3 table2 id 3
i: 1 j: 4 table2 id 4
i: 2 table1 id 3
i: 2 j: 1 table2 id 1
i: 2 j: 2 table2 id 2
i: 2 j: 3 table2 id 3
i: 2 j: 4 table2 id 4
i: 3 table1 id 4
i: 3 j: 1 table2 id 1
i: 3 j: 2 table2 id 2
i: 3 j: 3 table2 id 3
i: 3 j: 4 table2 id 4
i: 4 table1 id 5
i: 4 j: 1 table2 id 1
i: 4 j: 2 table2 id 2
i: 4 j: 3 table2 id 3
i: 4 j: 4 table2 id 4
z: 3
v_RC: 4, v_REC_union: 4

当您可以使用集合运算符直接在普通SQL中进行计数和比较时，这似乎仍然是很多工作，例如：

select 
  (select count(*) from table1) as i,
  (select count(*) from table2) as j,
  (select count(*) from (select id from table1 intersect select id from table2)) as z
from dual;

         I          J          Z
---------- ---------- ----------
         4          4          3

在这里使用PL / SQL似乎并没有太大的好处。 SQL版本可能会执行更多的工作，因为它两次查询两个表（尽管可能会命中缓存），但是无论如何，您都可以通过CTE避免这种情况，并且总体上可能比使用PL / SQL更快。

Answer 2

我更改了顺序，现在可以正常工作

open v_RC for select * from select * from userA.table1;  
 loop fetch v_RC into v_REC;    
  exit when v_RC%notfound;

       open v_RC_union for select * from select * from userB.table2 where id = v_REC.id;     
        loop fetch v_RC_union into v_REC_union;
         exit when v_RC_union%notfound;
          if  v_REC.id = v_REC_union.id then
           z :=z+1;
           dbms_output.put_line(v_REC.id ||'='|| v_REC_union.id);
          end if;
        end loop; 
       close v_RC_union;   

 end loop;
close v_RC;

但我仍然不知道出了什么问题？

比较来自SYS_REFCURSOR的结果

2 个答案: