Question

使用Indy的TIdTCPServer组件，可以分两部分接收一个程序包，但是客户端发送了一个64 KB的程序包。

如何在服务器OnExecute事件中收到完整的软件包？

现在，我放置了一个原型（服务器和客户端）代码来重新创建这种情况。

服务器代码

procedure TFrmServer.IdTCPServer1Execute(AContext: TIdContext);
Var
  ReceivedBytesTCP : Integer;
  IBuf : TIdBytes;
begin
  if Not AContext.Connection.IOHandler.InputBufferIsEmpty then Begin
    Try
      ReceivedBytesTCP := AContext.Connection.IOHandler.InputBuffer.Size;
      SetLength(IBuf,ReceivedBytesTCP);
      AContext.Connection.IOHandler.ReadBytes(IBuf,ReceivedBytesTCP,False);
      AContext.Connection.IOHandler.Write(IBuf,Length(IBuf),0);
    Except
      On E : Exception Do Begin
        Memo1.Lines.Add('Except Server TCP: ' + E.Message);
      End;
    End;
  End Else Begin
    Sleep(1);
  End;
end;

客户代码

procedure TFrm_TCP_Client.BtnSendClick(Sender: TObject);
Var
  IBuf,RBuf : TIdBytes;
  I         : Integer;
  LenPacket : Integer;
begin
  LenPacket := StrToInt(EdtLength.Text);
  if IdTCPClient1.Connected then Begin
    SetLength(IBuf,LenPacket);
    for I := 1 to LenPacket do
      IBuf[I] := 1;
    IdTCPClient1.IOHandler.Write(IBuf,Length(IBuf),0);
    I := 0;
    Repeat
      IdTCPClient1.IOHandler.CheckForDataOnSource(50);
      Inc(I);
    Until Not IdTCPClient1.IOHandler.InputBufferIsEmpty or (I >= 10);
    If Not IdTCPClient1.IOHandler.InputBufferIsEmpty Then Begin
      SetLength(RBuf,IdTCPClient1.IOHandler.InputBuffer.Size);
      IdTCPClient1.IOHandler.ReadBytes(RBuf,IdTCPClient1.IOHandler.InputBuffer.Size,False);
      if Length(RBuf) = Length(IBuf) then
        Memo1.Lines.Add('Response Received OK: '+IntToStr(Length(RBuf)))
      Else
        Memo1.Lines.Add('Response Received With Different Length: '+IntToStr(Length(RBuf)));
      if Not IdTCPClient1.IOHandler.InputBufferIsEmpty then
        Memo1.Lines.Add('Llego otro Mensaje');
    End Else Begin
      Memo1.Lines.Add('NO Response Received');
    End;
  End;
end;

如何知道消息是第一个还是第二个片段？如何强制接收第二个片段？

Answer 1

TCP中的发送和读取之间没有一对一的关系。可以自由分割数据，但是它希望优化网络传输。 TCP仅保证数据已发送，并且发送顺序相同，但是在传输过程中，HOW数据不会有任何碎片。 TCP将在接收端重建片段。这只是TCP的工作方式，并非Indy独有。无论使用哪种TCP框架，每个TCP应用程序都必须处理此问题。

如果您期望64KB的数据，那么只需读取64KB的数据，然后让OS和Indy内部为您处理这些碎片。 TCP的这种碎片正是为什么Indy的IOHandler在将数据拼接在一起时使用InputBuffer收集碎片的原因。

更新：停止关注片段。这是您不在其上操作的TCP层的实现细节。您无需处理代码中的片段。让Indy为您处理。只需关注您的应用程序级别协议即可。

仅供参考，您实际上已经实现了ECHO客户端/服务器解决方案。 Indy具有实际的ECHO客户/服务器组件TIdECHO和TIdECHOServer，您应该看看它们。

无论如何，您的服务器端异常处理都非常有问题。它未与主UI线程同步（在工作线程中调用OnExecute）。但是，更重要的是，这就像在客户端连接丢失/断开时阻止TIdTCPServer处理Indy本身发出的任何通知一样，因此客户端线程将保持运行状态，直到您停用服务器后才会停止。请勿吞下Indy自身的异常（这些异常源自EIdException）。如果需要在代码中捕获它们，则应在完成后重新引发它们，让TIdTCPServer处理它们。但是，在您的示例中，完全删除try..except并使用服务器的OnException事件会更容易。

此外，您的客户端阅读循环对于您尝试使用的循环是错误的。您没有正确初始化IBuf。但是，更重要的是，您使用的超时时间非常短（TCP连接可能会有延迟），并且一旦任何数据到达或经过了500ms（即使有更多数据仍在继续。您应该一直在阅读，直到没有东西可供阅读为止。

请尝试以下类似操作：

服务器：

procedure TFrmServer.IdTCPServer1Execute(AContext: TIdContext);
var
  IBuf : TIdBytes;
begin
  AContext.Connection.IOHandler.ReadBytes(IBuf, -1);
  AContext.Connection.IOHandler.Write(IBuf);
end;

procedure TFrmServer.IdTCPServer1Exception(AContext: TIdContext, AException: Exception);
var
  Msg: string;
begin
  if AException <> nil then
    Msg := AException.Message
  else
    Msg := 'Unknown';

  TThread.Queue(nil,
    procedure
    begin
      Memo1.Lines.Add('Except Server TCP: ' + Msg);
    end
  );
end;

客户：

procedure TFrm_TCP_Client.BtnSendClick(Sender: TObject);
Var
  IBuf,RBuf : TIdBytes;
  LenPacket : Integer;
begin
  if not IdTCPClient1.Connected then Exit;
  LenPacket := StrToInt(EdtLength.Text);
  if LenPacket < 1 then Exit;
  SetLength(IBuf, LenPacket);
  FillBytes(IBuf, LenPacket, $1);
  try
    IdTCPClient1.IOHandler.InputBuffer.Clear;
    IdTCPClient1.IOHandler.Write(IBuf);
  except
    Memo1.Lines.Add('Request Send Error');
    Exit;
  end;
  try
    while IdTCPClient1.IOHandler.CheckForDataOnSource(500) do;
    if not IdTCPClient1.IOHandler.InputBufferIsEmpty then
    begin
      IdTCPClient1.IOHandler.ReadBytes(RBuf, IdTCPClient1.IOHandler.InputBuffer.Size, True);
      if Length(RBuf) = Length(IBuf) then
        Memo1.Lines.Add('Response Received OK: ' + IntToStr(Length(RBuf)))
      else
        Memo1.Lines.Add('Response Received With Different Length. Expected: ' + IntToStr(Length(IBuf)) + ', Got: ' + IntToStr(Length(RBuf)));
    end
    else
      Memo1.Lines.Add('NO Response Received');
  except
    Memo1.Lines.Add('Response Receive Error');
  end;
end;

更好的解决方案是完全不依赖此类逻辑，更明确地说明数据协议的结构，例如<length><data>，例如：

服务器：

procedure TFrmServer.IdTCPServer1Execute(AContext: TIdContext);
var
  IBuf : TIdBytes;
  LenPacket : Int32;
begin
  LenPacket := AContext.Connection.IOHandler.ReadInt32;
  AContext.Connection.IOHandler.ReadBytes(IBuf, LenPacket, True);
  AContext.Connection.IOHandler.Write(LenPacket);
  AContext.Connection.IOHandler.Write(IBuf);
end;

procedure TFrmServer.IdTCPServer1Exception(AContext: TIdContext, AException: Exception);
var
  Msg: string;
begin
  if AException <> nil then
    Msg := AException.Message
  else
    Msg := 'Unknown';

  TThread.Queue(nil,
    procedure
    begin
      Memo1.Lines.Add('Except Server TCP: ' + Msg);
    end
  );
end;

客户：

procedure TFrm_TCP_Client.BtnSendClick(Sender: TObject);
Var
  IBuf,RBuf : TIdBytes;
  LenPacket : Int32;
begin
  if not IdTCPClient1.Connected then Exit;
  LenPacket := StrToInt(EdtLength.Text);
  if LenPacket < 1 then Exit;
  SetLength(IBuf, LenPacket);
  FillBytes(IBuf, LenPacket, $1);
  try
    IdTCPClient1.IOHandler.InputBuffer.Clear;
    IdTCPClient1.IOHandler.Write(LenPacket);
    IdTCPClient1.IOHandler.Write(IBuf);
  except
    Memo1.Lines.Add('Request Send Error');
    Exit;
  end;
  try
    IdTCPClient1.IOHandler.ReadTimeout := 5000;
    LenPacket := IdTCPClient1.IOHandler.ReadInt32;
    IdTCPClient1.IOHandler.ReadBytes(RBuf, LenPacket, True);
  except
    Memo1.Lines.Add('Response Receive Error');
    Exit;
  end;
  Memo1.Lines.Add('Response Received OK');
end;

Delphi Indy客户端发送64 KB程序包，而服务器接收2个程序包，总计64 KB

1 个答案: