Question

在如下所示的Wikidata SPARQL查询中，我希望能够为?placeOfBirthAltLabel的返回值使用自定义定界符。

问题是?placeOfBirthAltLabel下的某些值包含逗号

例如 “纽约”的同义词包括“美国纽约”作为单个条目。

但是，由于返回值以逗号分隔，因此该单个条目将被解析为两个单独的字符串。

所以换句话说，我需要返回的是[美国纽约；纽约市;美国纽约]相对于[美国纽约，纽约，美国纽约]

SELECT ?item ?itemLabel ?placeOfBirthLabel ?placeOfBirthAltLabel 
WHERE
{
  ?item wdt:P106 wd:Q10833314.
  OPTIONAL { ?item wdt:P19 ?placeOfBirth }

  SERVICE wikibase:label { bd:serviceParam wikibase:language "en" }
}

LIMIT 100

谢谢！

Answer 1

您不需要解析替代标签。它们的值由标签服务连接。只是不要将标签服务用于替代标签：

SELECT ?item ?itemLabel ?placeLabel ?place_alt_label WHERE { 
    ?item wdt:P106 wd:Q10833314. 
    OPTIONAL { 
        ?item wdt:P19 ?place .
        OPTIONAL {
            ?place skos:altLabel ?place_alt_label .
            FILTER (lang(?place_alt_label)='en')
            }
    }  
    SERVICE wikibase:label { bd:serviceParam wikibase:language "en" }
}

Try it!

如果您仍要解析...，逗号为hardcoded，请使用分组和GROUP_CONCAT和自定义分隔符：

SELECT ?item ?itemLabel ?placeLabel
    (GROUP_CONCAT(?place_alt_label; separator='; ') AS ?4) WHERE { 
    ?item wdt:P106 wd:Q10833314. 
    OPTIONAL { 
        ?item wdt:P19 ?place .
        OPTIONAL {
            ?place skos:altLabel ?place_alt_label .
            FILTER (lang(?place_alt_label)='en')
            }
    }  
    SERVICE wikibase:label { bd:serviceParam wikibase:language "en" }
}
GROUP BY ?item ?itemLabel ?placeLabel

Try it!

请小心标签服务投影的变量。例如，

SELECT ?item ?itemLabel ?placeLabel   {...}
GROUP BY ?item ?itemLabel ?placeLabel

应该可以，而

SELECT ?item ?itemLabel (SAMPLE(?placeLabel) AS ?3)   {...}
GROUP BY ?item ?itemLabel

不应该。

在SPARQL查询中解析AltLabel的返回

1 个答案: