Question

我的项目中有一个Window子类，并且在运行时创建了实例并将其完全显示在QML端。我知道我可以通过在WindowMinimizeButtonHint中不包含flags:来防止窗口被最小化，但是实际上我需要显示并启用最小化按钮，但是要拦截最小化按钮的点击，取消实际的最小化，然后执行其他操作（仅供参考，我的客户要求这种非标准的窗口行为，而不是我）。

到目前为止，我唯一能实现的就是处理onWindowStateChanged:事件，检查是否windowState === Qt.WindowStateMinimized并从计时器调用show()（在事件内部调用它）处理程序直接不执行任何操作）。这导致窗口向下移动到系统托盘，然后突然恢复正常。

有没有办法做到这一点，例如可以取消的OnMinimized事件？

编辑：基于本杰明T的回答，我至少是OSX解决方案的一部分：

#import <AppKit/AppKit.h>

bool NativeFilter::nativeEventFilter(const QByteArray &eventType, 
    void *message, long *result)
{
    if (eventType == "mac_generic_NSEvent") {
        NSEvent *event = static_cast<NSEvent *>(message);
        if ([event type] == NSKeyDown) {
            return true;
        }
    }
    return false;
}

在此示例中，我能够拦截并取消所有NSKeyDown事件（同时保持鼠标单击等其他事件仍然有效）。剩下的问题是我仍然不知道拦截最小事件-NSEvent.h似乎没有任何内容可以解决。也许我需要进行其他类型的活动？

编辑2-有效的解决方案：

我无法找到适当的方法来拦截最小事件并将其取消，所以我的解决方法是改为拦截窗口上的点击，确定点击是否在最小化按钮（或关闭或缩放按钮）上）并取消该事件（并向我的qml窗口发送发生点击的通知）。我还处理了双击标题栏以放大窗口，并使用Command-M键最小化窗口的情况。

第一步是实现QAbstractNativeEventFilter。在标题中：

#include <QAbstractNativeEventFilter>

class NativeFilter : public QAbstractNativeEventFilter {
public:
    bool nativeEventFilter(const QByteArray &eventType, void *message, 
        long *result);
};

实现：

#import <AppKit/AppKit.h>
#import <AppKit/NSWindow.h>
#import <AppKit/NSButton.h>

bool NativeFilter::nativeEventFilter(const QByteArray &eventType, void 
    *message, long *result)
{
    if (eventType == "mac_generic_NSEvent") {

        NSEvent *event = static_cast<NSEvent *>(message);
        NSWindow *win = [event window];

        // TODO: determine whether or not this is a window whose
        // events you want to intercept. I did this by checking
        // [win title] but you may want to find and use the 
        // window's id instead.

        // Detect a double-click on the titlebar. If the zoom button 
        // is enabled, send the full-screen message to the window
        if ([event type] == NSLeftMouseUp) {
            if ([event clickCount] > 1) {
                NSPoint pt = [event locationInWindow];
                CGRect rect = [win frame];
                // event coordinates have y going in the opposite direction from frame coordinates, very annoying
                CGFloat yInverted = rect.size.height - pt.y;
                if (yInverted <= 20) {
                    // TODO: need the proper metrics for the height of the title bar

                    NSButton *btn = [win standardWindowButton:NSWindowZoomButton];
                    if (btn.enabled) {

                        // notify qml of zoom button click

                    }

                    return true;
                }
            }
        }

        if ([event type] == NSKeyDown) {

            // detect command-M (for minimize app)
            if ([event modifierFlags] & NSCommandKeyMask) {

                // M key
                if ([event keyCode] == 46) {
                    // notify qml of miniaturize button click
                    return true;
                }

            }

            // TODO: we may be requested to handle keyboard actions for close and zoom buttons. e.g. ctrl-cmd-F is zoom, I think,
            // and Command-H is hide.

        }


        if ([event type] == NSLeftMouseDown) {

            NSPoint pt = [event locationInWindow];
            CGRect rect = [win frame];

            // event coordinates have y going in the opposite direction from frame coordinates, very annoying
            CGFloat yInverted = rect.size.height - pt.y;

            NSButton *btn = [win standardWindowButton:NSWindowMiniaturizeButton];
            CGRect rectButton = [btn frame];
            if ((yInverted >= rectButton.origin.y) && (yInverted <= (rectButton.origin.y + rectButton.size.height))) {
                if ((pt.x >= rectButton.origin.x) && (pt.x <= (rectButton.origin.x + rectButton.size.width))) {

                    // notify .qml of miniaturize button click

                    return true;
                }
            }

            btn = [win standardWindowButton:NSWindowZoomButton];
            rectButton = [btn frame];

            if (btn.enabled) {
                if ((yInverted >= rectButton.origin.y) && (yInverted <= (rectButton.origin.y + rectButton.size.height))) {
                    if ((pt.x >= rectButton.origin.x) && (pt.x <= (rectButton.origin.x + rectButton.size.width))) {

                        // notify qml of zoom button click

                        return true;
                    }
                }
            }

            btn = [win standardWindowButton:NSWindowCloseButton];
            rectButton = [btn frame];
            if ((yInverted >= rectButton.origin.y) && (yInverted <= (rectButton.origin.y + rectButton.size.height))) {
                if ((pt.x >= rectButton.origin.x) && (pt.x <= (rectButton.origin.x + rectButton.size.width))) {

                    // notify qml of close button click

                    return true;
                }
            }

        }

        return false;

    }

    return false;
}

然后在main.cpp中：

Application app(argc, argv);
app.installNativeEventFilter(new NativeFilter());

Answer 1

通常来说，应该使用事件系统而不是信号/插槽来拦截事件和更改。

最简单的方法是子类化您使用的对象并重新实现适当的事件处理程序，或者使用事件过滤器。

由于您使用的是QML，子类化可能很困难，因为您无法访问所有Qt内部类。

这是使用事件过滤时代码的样子。

int main(int argc, char *argv[])
{
    QCoreApplication::setAttribute(Qt::AA_EnableHighDpiScaling);

    QGuiApplication app(argc, argv);


    QQmlApplicationEngine engine;
    engine.load(QUrl(QStringLiteral("qrc:/main.qml")));

    if (engine.rootObjects().isEmpty())
        return -1;

    auto root = engine.rootObjects().first();
    root->installEventFilter(new EventFilter());

    return app.exec();
}

class EventFilter : public QObject
{
    Q_OBJECT
public:
    explicit EventFilter(QObject *parent = nullptr);
    bool eventFilter(QObject *watched, QEvent *event) override;
};

bool EventFilter::eventFilter(QObject *watched, QEvent *event)
{
    if (event->type() == QEvent::WindowStateChange) {
        auto e = static_cast<QWindowStateChangeEvent *>(event);
        auto window = static_cast<QWindow *>(watched);

        if (window->windowStates().testFlag(Qt::WindowMinimized)
                && ! e->oldState().testFlag(Qt::WindowMinimized))
        {
            // Restore old state
            window->setWindowStates(e->oldState());
            return true;
        }
    }

    // Do not filter event
    return false;
}

但是，您将很快遇到与使用信号/插槽机制时相同的问题：Qt仅在窗口已最小化时通知您。意味着此时还原窗口将产生隐藏/显示效果。

因此，您需要更深入一些，并且需要一个本机事件过滤器。

以下代码在Windows上有效，您应该将其适配于macOS：

class NativeFilter : public QAbstractNativeEventFilter {
public:
    bool nativeEventFilter(const QByteArray &eventType, void *message, long *result);
};

bool NativeFilter::nativeEventFilter(const QByteArray &eventType, void *message, long *result)
{
/* On Windows we interceot the click in the title bar. */
/* If we wait for the minimize event, it is already too late. */
#ifdef Q_OS_WIN
    auto msg = static_cast<MSG *>(message);
    // Filter out the event when the minimize button is pressed.
    if (msg->message == WM_NCLBUTTONDOWN && msg->wParam == HTREDUCE)
        return true;
#endif

/* Example macOS code from Qt doc, adapt to your need */
#ifdef Q_OS_MACOS
    if (eventType == "mac_generic_NSEvent") {
        NSEvent *event = static_cast<NSEvent *>(message);
        if ([event type] == NSKeyDown) {
            // Handle key event
            qDebug() << QString::fromNSString([event characters]);
        }
}
#endif

    return false;
}

在您的main（）中：

QGuiApplication app(argc, argv);
app.installNativeEventFilter(new NativeFilter());

有关更多信息，您可以阅读有关QAbstractNativeEventFilter的Qt文档。

您可能需要使用QWindow::winId()来检查本地事件的目标窗口。

由于我不是macOS开发人员，所以我不知道您可以使用NSEvent做些什么。同样，NSWindowDelegate类可能对您有用：https://developer.apple.com/documentation/appkit/nswindowdelegate 如果您可以从NSWindow中检索QWindow::winId()，则应该可以使用它。

如何截取和取消最小化窗口？

1 个答案: