Question

我已经使用以下内容定义了一个.dir-locals.el文件：

((python-mode . ((cr/virtualenv-name . "saas"))))

在我的.emacs中，我有以下函数来检索此值并提供virtualenv路径：

(defun cr/virtualenv ()
  (cond (cr/virtualenv-name (format "%s/%s" virtualenv-base cr/virtualenv-name))
        ((getenv "EMACS_VIRTUAL_ENV") (getenv "EMACS_VIRTUAL_ENV"))
        (t "~/.emacs.d/python")))

最后，在我的python-mode-hook列表中，我有这个钩子函数：

(add-hook 'python-mode-hook 'cr/python-mode-shell-setup)

(defun cr/python-mode-shell-setup ()
  (message "virtualenv-name is %s" cr/virtualenv-name)
  (let ((python-base (cr/virtualenv)))
    (cond ((and (fboundp 'ipython-shell-hook) (file-executable-p (concat python-base "/bin/ipython")))
           (setq python-python-command (concat python-base "/bin/ipython"))
           (setq py-python-command (concat python-base "/bin/ipython"))
           (setq py-python-command-args '( "-colors" "NoColor")))
          (t
           (setq python-python-command (concat python-base "/bin/python"))
           (setq py-python-command (concat python-base "/bin/python"))
           (setq py-python-command-args nil)))))

当我打开一个新的python文件时，cr/python-mode-shell-setup记录的消息表明cr/virtualenv-name是nil。但是，当我给这个名字命名时，我会得到“saas”。

显然这里有一个加载订单问题;有没有办法让我的模式钩子语句响应目录本地变量？

Answer 1

这是因为normal-mode按此顺序调用(set-auto-mode)和(hack-local-variables)。

但是，在处理局部变量之后运行hack-local-variables-hook，这将启用一些解决方案：

第一个是让Emacs为每个主要模式运行一个新的“局部变量挂钩”：

(add-hook 'hack-local-variables-hook 'run-local-vars-mode-hook)
(defun run-local-vars-mode-hook ()
  "Run a hook for the major-mode after the local variables have been processed."
  (run-hooks (intern (concat (symbol-name major-mode) "-local-vars-hook"))))

(add-hook 'python-mode-local-vars-hook 'cr/python-mode-shell-setup)

（您的原始功能可以不经修改地使用，使用该方法。）

第二个选项是利用LOCAL的可选add-hook参数使得指定的函数缓冲区为本地。使用这种方法，您可以按如下方式编写钩子：

(add-hook 'python-mode-hook 'cr/python-mode-shell-setup)

(defun cr/python-mode-shell-setup ()
  (add-hook 'hack-local-variables-hook
            (lambda () (message "virtualenv-name is %s" cr/virtualenv-name)
              (let ((python-base (cr/virtualenv)))
                (cond ((and (fboundp 'ipython-shell-hook) (file-executable-p (concat python-base "/bin/ipython")))
                       (setq python-python-command (concat python-base "/bin/ipython"))
                       (setq py-python-command (concat python-base "/bin/ipython"))
                       (setq py-python-command-args '( "-colors" "NoColor")))
                      (t
                       (setq python-python-command (concat python-base "/bin/python"))
                       (setq py-python-command (concat python-base "/bin/python"))
                       (setq py-python-command-args nil)))))
            nil t)) ; buffer-local hack-local-variables-hook

即。 python-mode-hook首先运行并仅为当前缓冲区注册匿名函数hack-local-variables-hook;然后在处理局部变量后调用该函数。

Lindydancer的评论提示第三种方法。它不像其他两个一样干净，但无论如何都证明它很有趣。我不喜欢导致(hack-local-variables)被调用两次的想法，但我看到如果你在本地设置local-enable-local-variables缓冲区，它会阻止(hack-local-variables)做任何事情，所以你< em>可以这样做：
```
(defun cr/python-mode-shell-setup ()
  (report-errors "File local-variables error: %s"
    (hack-local-variables)))
  (set (make-local-variable 'local-enable-local-variables) nil)
  (let ((python-base (cr/virtualenv)))
    ...))
```
显然，稍微修改了正常的执行顺序，因此副作用可能是可能的。我担心如果文件中的局部变量 comment 设置了相同的主要模式，这可能会导致无限递归，但实际上这似乎不是问题。

本地变量标题注释（例如-*- mode: foo -*-）由(set-auto-mode)处理，所以这些很好;但是mode: foo Local Variables:注释似乎是一个问题，因为它由(hack-local-variables)处理，因此如果模式设置为这样，我认为它会导致递归。

在实践中，我能够通过使用一个简单的函数作为'模式'来触发问题，它只是尝试运行它的钩子;然而，使用“正确”模式进行测试并没有出现问题，因此实际上它可能是安全的。我没有进一步研究（因为其他两个解决方案比这更清晰），但我猜想延迟模式挂钩机制可能解释了它？

如何在主模式挂钩中访问目录本地变量？

1 个答案: