Question

有没有办法强制vim使用制表符进行初始缩进，但是在运行retab时！命令NOT用标签替换内部字间距？

Answer 1

根据我的经验，最好的方法是使用自定义功能：

" Retab spaced file, but only indentation
command! RetabIndents call RetabIndents()

" Retab spaced file, but only indentation
func! RetabIndents()
    let saved_view = winsaveview()
    execute '%s@^\( \{'.&ts.'}\)\+@\=repeat("\t", len(submatch(0))/'.&ts.')@'
    call winrestview(saved_view)
endfunc

然后您可以使用：

:RetabIndents

将所有前导空格替换为制表符，但不影响其他字符后的制表符。它假定'ts'设置正确。通过这样做，您可以在很大程度上制作未对齐的文件：

:set ts=8     " Or whatever makes the file looks like right
:set et       " Switch to 'space mode'
:retab        " This makes everything spaces
:set noet     " Switch back to 'tab mode'
:RetabIndents " Change indentation (not alignment) to tabs
:set ts=4     " Or whatever your coding convention says it should be

你最终会得到一个文件，其中所有前导空格都是标签，这样人们就可以以他们想要的任何格式查看它，但所有尾随空格都是空格，以便所有行尾注释，表格等与任何标签宽度正确对齐。

修改

'exe'行的解释：

execute '%s@^\( \{'.&ts.'}\)\+@\=repeat("\t", len(submatch(0))/'.&ts.')@'

" Execute the result of joining a few strings together:

%s               " Search and replace over the whole file
@....@....@      " Delimiters for search and replace
^                " Start of line
\(...\)          " Match group
 \{...}          " Match a space the number of times in the curly braces
&ts              " The current value of 'tabstop' option, so:
                 " 'string'.&ts.'string' becomes 'string4string' if tabstop is 4
                 " Thus the bracket bit becomes \( \{4}\)
\+               " Match one or more of the groups of 'tabstop' spaces (so if
                 " tabstop is 4, match 4, 8, 12, 16 etc spaces
@                " The middle delimiter
\=               " Replace with the result of an expression:
repeat(s,c)      " Make a string that is c copies of s, so repeat('xy',4) is 'xyxyxyxy'
"\t"             " String consisting of a single tab character
submatch(0)      " String that was matched by the first part (a number of multiples 
                 " of tabstop spaces)
len(submatch(0)) " The length of the match
/'.&ts.'         " This adds the string "/4" onto the expression (if tabstop is 4),
                 " resulting in len(submatch(0))/4 which gives the number of tabs that
                 " the line has been indented by
)                " The end of the repeat() function call

@                " End delimiter

Answer 2

从我对其他（*）问题的回答：

为解决这个小问题，我建议搜索，而不是重新搜索。
:%s/^\(^I*\)␣␣␣␣/\1^I/g
此搜索将在整个文件中查找以。开头的所有行任意数量的选项卡，后跟4个空格，并替换它它找到的任何数量的标签加上一个。

您需要使用@:或10@:

重做搜索

在下面的链接中更好地解释了。

（*） How can I convert spaces to tabs in Vim or Linux?

强制Vi / Vim仅在retab上使用前导选项卡！

2 个答案: