Question

我正在编写一个控制器函数，该函数将在出现json对象或错误对象（如果失败）之前检查条件（关键字有效）。

router.ex

scope "/api", DongNghiaWeb do
    pipe_through :api
    scope "/tim_kiem" do
      get "/tu/:word"   , APIWordController, :search_word
[...]

word_controller.ex

def search_word(conn, %{"word" => word}) do
  conn
  |> check_invalid_keyword(word)
  |> render("search.json", words: word |> String.trim |> Words.suggest)
end

defp check_invalid_keyword(conn, keyword) do
  unless Words.keyword_valid?(String.trim(keyword)) do
    conn
    |> put_status(400)
    |> json(%{
      error: "Invalid keyword"
    })
  end
  conn
end

word_controller_test.ex

test "response error when word is not valid", %{conn: conn} do
  response = get(conn,api_word_path(conn, :search_word, "a3d"))
    |> json_response(400)
  assert response["error"] == "Invalid keyword"
end

运行mix test时，结果将如下所示：

** (RuntimeError) expected response with status 400, got: 200, with body: {"data":[]}

但是当我尝试使用REST客户端（例如Insomnia）进行测试时，json将恢复为{ error : "Invalid keyword" }就可以了。

Answer 1

Words.keyword_valid?(String.trim(keyword))出错时，您的代码将响应写入两次。

第一次写发生在调用|> json(...)时，第二次写发生在调用render时。如果已经调用render，则您的代码不会阻止调用json。浏览器连接在第一次写入后结束，因此您会看到Insomnia的正确输出，但是测试设置将使用写入连接的最后响应。

解决此问题需要对代码进行一些重组。这是我的处理方式：

def search_word(conn, %{"word" => word}) do
  if Words.keyword_valid?(String.trim(word)) do
    conn
    |> render("search.json", words: word |> String.trim() |> Words.suggest())
  else
    conn
    |> put_status(400)
    |> json(%{
      error: "Invalid keyword"
    })
  end
end

编辑：这是完成您在以下评论中要求的一种方法：

def search_word(conn, %{"word" => word}) do
  with {:ok, conn} <- check_invalid_keyword(conn, word) do
    conn
    |> render("search.json", words: word |> String.trim() |> Words.suggest())
  end
end

def check_invalid_keyword(conn, keyword) do
  if Words.keyword_valid?(String.trim(keyword)) do
    {:ok, conn}
  else
    conn
    |> put_status(400)
    |> json(%{
      error: "Invalid keyword"
    })
  end
end

当关键字无效时，返回值与with子句不匹配，并按原样返回。如果有效，则执行do块。

使用ExUnit检查状态代码失败，但是实际REST测试成功

1 个答案: