Question

我正在编写一个批处理脚本，该脚本通过“查询用户”命令返回已登录的用户。但是，我遇到了一个困难，这里的其他线程无法帮助我。这是我的（几乎）整个脚本，为简洁起见，最后只缺少了一些回声：

@ECHO OFF
SETLOCAL ENABLEEXTENSIONS ENABLEDELAYEDEXPANSION
SET me=%~n0
SET parent=%~dp0
SET count=1

FOR /F "skip=1 tokens=* USEBACKQ" %%F IN (`query user`) DO (
    ::obtain line of output
    SET var!count!=%%F 
    ::obtain first character from line
    CALL SET ^faf=^%%var!count!:~0,1%%
    ::testing purposes
    CALL ECHO count:^!count! faf1:^!faf!
     ::remove the '>' character, if present
     IF ^!faf! == ^> ( 
     SET var!count!=!var%count%:~1! && ECHO success )
    SET /a count=!count!+1
)

它应该做的是获取几行输出中的一个，创建一个临时变量“ faf”，该变量存储该行中的第一个字符，然后将其与“>”字符（总是由“查询用户”添加）进行比较在当前用户名之前-如果检测到该字符，则该变量将被覆盖，并省略第一个字符。在含义中，echo显示循环计数器的当前值和temp变量。
问题出在CALL SET命令上：它似乎忽略了包含“>”字符的行，而其他行则按预期工作。因此，永远不会使用IF，并且echo会打印计数器，但不会打印第一个字符-“>”行。
请注意，这些行仍存储在var1-6中，并用“ ^”打印出来表明即使是带有“>”的行也可以正常打印。唯一的问题是检测并忽略该死的尖括号。有人可以帮我吗？我想念什么？

Answer 1

使用>命令的DELIMS选项从输出中删除FOR /F。

@ECHO OFF
SETLOCAL ENABLEEXTENSIONS ENABLEDELAYEDEXPANSION
SET me=%~n0
SET parent=%~dp0
SET count=1

FOR /F "skip=1 tokens=* USEBACKQ delims=>" %%F IN (`query user`) DO (
    SET var!count!=%%F
    SET /a count+=1
)

Answer 2

我不确定您为什么要按照自己的方式进行操作，因为您可以使用>选项简单地删除delims。

所以我认为您的意图是获取当前登录用户的列表，然后使用>来识别其中的当前用户。

如果是这种情况，那么您可以使用下面的代码来实现自己的目标

此外，您永远不要在带括号的块中使用::注释样式。有关更多信息，请参见Which comment style should I use in batch files?。

@ECHO OFF
SETLOCAL ENABLEEXTENSIONS ENABLEDELAYEDEXPANSION
SET "me=%~n0"
SET "parent=%~dp0"
SET "count=0"

FOR /F "skip=1 tokens=* USEBACKQ" %%F IN (`query user`) DO (

    REM Never use this(::) commenting style inside a parenthesized block
    REM Use REM or use %= This commenting style =% instead
    %= Variable names can not start with equal sign(=) so this can be safely used as a comment =%

    SET /a "count+=1"

    REM obtain line of output
    SET "var!count!=%%F"

    REM obtain first character from line
    FOR %%A IN (!count!) DO SET "faf=!var%%A:~0,1!"

    REM testing purposes
    ECHO count:!count! faf1:!faf!

    REM remove the '>' character, if present
    IF "!faf!"==">" FOR %%A IN (!count!) DO (
        SET "var!count!=!var%%A:~1!"
        ECHO Success

        SET "CurrentUserInfo=!var%%A!"
        SET /a "CurrentUserIndex=count"
        ECHO Current User Info [Inside Loop - By Index]: !var%%A!
        REM Prints a new line
        ECHO, 
    )
)
ECHO,
ECHO Current User Info [Outside Loop - By Index]:   !var%CurrentUserIndex%!
ECHO Current User Info [Outside Loop - By VarName]: %CurrentUserInfo%

ECHO,
ECHO Printing list of all users by index...
FOR /L %%A IN (1,1,!count!) DO ECHO var%%A: !var%%A!
ECHO,
ECHO Current User is stored in var%CurrentUserIndex%


PAUSE

Windows Batch-延迟扩展索引

2 个答案: