Question

我一直在尝试使用指定eval函数的Component类型类在Purescript中开发组件系统。组件的每个子组件都可以通过组件递归调用for的eval函数，实质上是获取输入的值。

由于组件可能希望使用运行时值，因此还将一条记录传递到eval中。我的目标是要求顶级eval的Record参数中的行包括每个子组件的所有行。对于本身不使用任何行的组件而言，这并不困难，但是它们的单个子组件却可以使用，因为我们可以简单地将子组件行传递到组件的行。显示在evalIncrement中。

import Prelude ((+), one)
import Data.Symbol (class IsSymbol, SProxy(..))
import Record (get)
import Prim.Row (class Cons, class Union)

class Component a b c | a -> b where
  eval :: a -> Record c -> b

data Const a = Const a

instance evalConst :: Component (Const a) a r where
  eval (Const v) r = v

data Var (a::Symbol) (b::Type) = Var

instance evalVar :: 
  ( IsSymbol a
  , Cons a b r' r) => Component (Var a b) b r  where
  eval _ r = get (SProxy :: SProxy a) r

data Inc a = Inc a

instance evalInc :: 
  ( Component a Int r
  ) => Component (Inc a) Int r where
  eval (Inc a) r = (eval a r) + one

以上所有代码均正常运行。但是，一旦我尝试引入一个包含多个输入组件并合并它们的行的组件，我似乎无法使其正常工作。例如，当尝试使用class Union中的Prim.Row时：

data Add a b = Add a b

instance evalAdd :: 
  ( Component a Int r1
  , Component b Int r2
  , Union r1 r2 r3
  ) => Component (Add a b) Int r3 where
  eval (Add a b) r = (eval a r) + (eval b r)

产生以下错误：

  No type class instance was found for

    Processor.Component a3 
                        Int 
                        r35


while applying a function eval
  of type Component t0 t1 t2 => t0 -> { | t2 } -> t1
  to argument a
while inferring the type of eval a
in value declaration evalAdd

where a3 is a rigid type variable
      r35 is a rigid type variable
      t0 is an unknown type
      t1 is an unknown type
      t2 is an unknown type

实际上，即使修改evalInc实例以使用具有空行的虚拟Union也会产生类似的错误，如下所示：

instance evalInc :: (Component a Int r, Union r () r1) 
                       => Component (Increment a) Int r1 where

我使用联盟不正确吗？还是我的课程需要进一步的功能依赖-我不太了解它们。

我使用的是Purs版本0.12.0

Answer 1

r ∷ r3，但是在需要r1和r2的地方使用它，因此类型不匹配。无法在期望{a ∷ A, b ∷ B}或{a ∷ A}或{b ∷ B}的地方给出记录{}。但是，可以这样说：

f ∷ ∀ s r. Row.Cons "a" A s r ⇒ Record r → A
f {a} = a

换句话说，f是任何包含类型为"a"的标签A的记录上的函数多态。同样，您可以将eval更改为：

eval ∷ ∀ s r. Row.Union c s r ⇒ a → Record r → b

换句话说，eval在任何至少包含c字段的记录上都是多态的。这引入了类型歧义，您将必须使用代理来解决。

eval ∷ ∀ proxy s r. Row.Union c s r ⇒ proxy c → a → Record r → b

添加的评估实例变为：

instance evalAdd ∷
  ( Component a Int r1
  , Component b Int r2
  , Union r1 s1 r3
  , Union r2 s2 r3
  ) => Component (Add a b) Int r3 where
  eval _ (Add a b) r = eval (RProxy ∷ RProxy r1) a r + eval (RProxy ∷ RProxy r2) b r

从这里开始，r1和r2变得模棱两可，因为它们不是仅由r3来确定的。在给定的约束下，s1和s2也必须是已知的。可能有一个可以添加的功能依赖项。我不确定什么合适，因为我不确定您正在设计的程序的目标是什么。

Answer 2

由于使用Row.Cons，Var的实例已经是多态的（或者技术上是开放的？），即

eval (Var :: Var "a" Int) :: forall r. { "a" :: Int | r } -> Int

那么我们要做的就是使用相同的记录进行左右求值，并且类型系统可以推断出两者的组合而无需结合：

instance evalAdd :: 
  ( Component a Int r
  , Component b Int r
  ) => Component (Add a b) Int r where
  eval (Add a b) r = (eval a r) + (eval b r)

当不使用类型类时，这一点更加明显：

> f r = r.foo :: Int
> g r = r.bar :: Int
> :t f
forall r. { foo :: Int | r } -> Int
> :t g
forall r. { bar :: Int | r } -> Int
> fg r = (f r) + (g r)
> :t fg
forall r. { foo :: Int, bar :: Int | r } -> Int

我认为，与@erisco相比，此方法的缺点在于，开放行必须位于类似Var这样的实例的定义中，而不是位于eval的定义中？它也没有强制执行，因此，如果组件不使用开放行，则诸如Add之类的组合器将不再起作用。

好处是缺少RProx的要求，除非eriscos实施实际上不需要它们，否则我没有检查。

更新：

我想出了一种方法，要求关闭评估实例，但使用pick中的purescript-record-extra却很丑陋。

我不太确定为什么这会比上面的选项更好，感觉就像我只是在重新实现行多态性

import Record.Extra (pick, class Keys)

...

instance evalVar :: 
  ( IsSymbol a
  , Row.Cons a b () r
  ) => Component (Var a b) b r where
  eval _ r = R.get (SProxy :: SProxy a) r

data Add a b = Add a b

evalp :: forall c b r r_sub r_sub_rl trash
   . Component c b r_sub
  => Row.Union r_sub trash r
  => RL.RowToList r_sub r_sub_rl
  => Keys r_sub_rl
  => c -> Record r -> b
evalp c r = eval c (pick r)

instance evalAdd :: 
  ( Component a Int r_a
  , Component b Int r_b
  , Row.Union r_a r_b r
  , Row.Nub r r_nub
  , Row.Union r_a trash_a r_nub
  , Row.Union r_b trash_b r_nub
  , RL.RowToList r_a r_a_rl
  , RL.RowToList r_b r_b_rl
  , Keys r_a_rl
  , Keys r_b_rl
  ) => Component (Add a b) Int r_nub where
  eval (Add a b) r = (evalp a r) + (evalp b r)

eval (Add (Var :: Var "a" Int) (Var :: Var "b" Int) ) :: { a :: Int , b :: Int } -> Int  
eval (Add (Var :: Var "a" Int) (Var :: Var "a" Int) ) :: { a :: Int } -> Int

Purescript行联合体

2 个答案: